[gentoo-commits] gentoo-x86 commit in dev-lang/gdl: gdl-0.9.4.ebuild metadata.xml gdl-0.9.3-r2.ebuild ChangeLog

[Sebastien Fabbro (bicatali)]

bicatali    13/11/20 22:35:13

  Modified:             metadata.xml gdl-0.9.3-r2.ebuild ChangeLog
  Added:                gdl-0.9.4.ebuild
  Log:
  Version bump, and backport fix to newer plplot (bug #491024) for older version
  
  (Portage version: 2.2.7-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

Revision  Changes    Path
1.9                  dev-lang/gdl/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/metadata.xml?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/metadata.xml?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/metadata.xml?r1=1.8&r2=1.9

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/metadata.xml,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- metadata.xml	16 Jun 2012 16:48:40 -0000	1.8
+++ metadata.xml	20 Nov 2013 22:35:13 -0000	1.9
@@ -8,6 +8,7 @@
   Information Solutions.
 </longdescription>
 <use>
+  <flag name='hdf'>Build matrix manipulation with <pkg>dev-cpp/eigen</pkg></flag>
   <flag name='hdf'>Add support for the Hierarchical Data Format v.4</flag>
   <flag name='gshhs'>Add support for projection adn continent maps with <pkg>sci-geosciences/gshhs-data</pkg></flag>
 



1.3                  dev-lang/gdl/gdl-0.9.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild?r1=1.2&r2=1.3

Index: gdl-0.9.3-r2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- gdl-0.9.3-r2.ebuild	16 Nov 2013 09:00:03 -0000	1.2
+++ gdl-0.9.3-r2.ebuild	20 Nov 2013 22:35:13 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild,v 1.2 2013/11/16 09:00:03 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9.3-r2.ebuild,v 1.3 2013/11/20 22:35:13 bicatali Exp $
 
 EAPI=4
 
@@ -26,7 +26,7 @@
 
 RDEPEND="
 	sci-libs/gsl
-	sci-libs/plplot
+	<sci-libs/plplot-5.9.10
 	sys-libs/ncurses
 	sys-libs/readline
 	sys-libs/zlib
@@ -58,7 +58,7 @@
 	use hdf5 && has_version sci-libs/hdf5[mpi] && export CXX=mpicxx
 
 	epatch "${FILESDIR}"/0.9.2-{antlr,proj4,include,tests,semaphore}.patch
-	epatch "${FILESDIR}"/0.9.3-{sstream,netcdf-cxx}.patch
+	epatch "${FILESDIR}"/0.9.3-{sstream,netcdf-cxx,plwidth}.patch
 	# make sure antlr includes are from system and rebuild the sources with it
 	# https://sourceforge.net/tracker/?func=detail&atid=618685&aid=3465878&group_id=97659
 



1.43                 dev-lang/gdl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	16 Nov 2013 09:00:03 -0000	1.42
+++ ChangeLog	20 Nov 2013 22:35:13 -0000	1.43
@@ -1,6 +1,14 @@
 # ChangeLog for dev-lang/gdl
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.42 2013/11/16 09:00:03 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.43 2013/11/20 22:35:13 bicatali Exp $
+
+*gdl-0.9.4 (20 Nov 2013)
+
+  20 Nov 2013; Sébastien Fabbro <bicatali@g.o>
+  +files/0.9.3-plwidth.patch, +files/0.9.4-gsl.patch, +files/0.9.4-python.patch,
+  +files/0.9.4-reorder.patch, +gdl-0.9.4.ebuild, gdl-0.9.3-r2.ebuild,
+  metadata.xml:
+  Version bump, and backport fix to newer plplot (bug #491024) for older version
 
   16 Nov 2013; Ryan Hill <dirtyepic@g.o> gdl-0.9.2-r2.ebuild,
   gdl-0.9.3-r2.ebuild:



1.1                  dev-lang/gdl/gdl-0.9.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/gdl-0.9.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/gdl/gdl-0.9.4.ebuild?rev=1.1&content-type=text/plain

Index: gdl-0.9.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9.4.ebuild,v 1.1 2013/11/20 22:35:13 bicatali Exp $

EAPI=5

WX_GTK_VER="2.8"
PYTHON_COMPAT=( python{2_6,2_7} )

inherit cmake-utils eutils python-r1 wxwidgets toolchain-funcs virtualx

DESCRIPTION="Interactive Data Language compatible incremental compiler"
HOMEPAGE="http://gnudatalanguage.sourceforge.net/"
SRC_URI="mirror://sourceforge/gnudatalanguage/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+eigen fftw grib gshhs hdf hdf5 imagemagick netcdf openmp
	proj postscript	python static-libs udunits wxwidgets"

RDEPEND="
	sci-libs/gsl
	sci-libs/plplot:=
	sys-libs/ncurses
	sys-libs/readline
	sys-libs/zlib
	x11-libs/libX11
	fftw? ( >=sci-libs/fftw-3 )
	grib? ( sci-libs/grib_api )
	gshhs? ( sci-geosciences/gshhs-data sci-geosciences/gshhs )
	hdf? ( sci-libs/hdf )
	hdf5? ( sci-libs/hdf5 )
	imagemagick? ( || (
			media-gfx/graphicsmagick[cxx]
			media-gfx/imagemagick[cxx] ) )
	netcdf? ( sci-libs/netcdf )
	proj? ( sci-libs/proj )
	postscript? ( dev-libs/pslib )
	python? ( dev-python/numpy[${PYTHON_USEDEP}] )
	udunits? ( sci-libs/udunits )
	wxwidgets? ( x11-libs/wxGTK:2.8[X,-odbc] )"

DEPEND="${RDEPEND}
	>=dev-java/antlr-2.7.7-r5:0[cxx,java,script]
	virtual/pkgconfig
	eigen? ( dev-cpp/eigen:3 )"

REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"

PATCHES=(
		"${FILESDIR}"/0.9.2-antlr.patch
		"${FILESDIR}"/0.9.2-include.patch
		"${FILESDIR}"/0.9.2-proj4.patch
		"${FILESDIR}"/0.9.2-semaphore.patch
		"${FILESDIR}"/0.9.3-plwidth.patch
		"${FILESDIR}"/0.9.4-gsl.patch
		"${FILESDIR}"/0.9.4-python.patch
		"${FILESDIR}"/0.9.4-reorder.patch
)

pkg_setup() {
	use openmp && [[ $(tc-getCXX)$ == *g++* ]] && ! tc-has-openmp && \
		die "You have openmp enabled but your current g++ does not support it"
}

src_prepare() {
	cmake-utils_src_prepare

	use hdf5 && has_version sci-libs/hdf5[mpi] && export CXX=mpicxx

	# make sure antlr includes are from system and rebuild the sources with it
	# https://sourceforge.net/tracker/?func=detail&atid=618685&aid=3465878&group_id=97659
	rm -r src/antlr || die
	einfo "Regenerating grammar"
	pushd src > /dev/null
	local i
	for i in *.g; do antlr ${i} || die ; done
	popd > /dev/null

	# gentoo: use proj instead of libproj4 (libproj4 last update: 2004)
	sed -i \
		-e 's:proj4:proj:' \
		-e 's:lib_proj\.h:proj_api\.h:g' \
		CMakeModules/FindLibproj4.cmake src/math_utl.hpp || die

	# gentoo: avoid install files in datadir directory
	sed -i \
		-e '/AUTHORS/d' \
		CMakeLists.txt || die
}

src_configure() {
	# MPI is still very buggy
	# x11=off does not compile
	local mycmakeargs=(
		-Wno-dev
		-DMPICH=OFF
		-DBUNDLED_ANTLR=OFF
		-DX11=ON
		$(cmake-utils_use fftw)
		$(cmake-utils_use eigen EIGEN3)
		$(cmake-utils_use grib)
		$(cmake-utils_use gshhs)
		$(cmake-utils_use hdf)
		$(cmake-utils_use hdf5)
		$(cmake-utils_use netcdf)
		$(cmake-utils_use openmp)
		$(cmake-utils_use proj LIBPROJ4)
		$(cmake-utils_use postscript PSLIB)
		$(cmake-utils_use udunits)
		$(cmake-utils_use wxwidgets)
	)
	if use imagemagick; then
		if has_version media-gfx/graphicsmagick[cxx]; then
			mycmakeargs+=( -DGRAPHICSMAGICK=ON -DMAGICK=OFF )
		else
			mycmakeargs+=( -DGRAPHICSMAGICK=OFF -DMAGICK=ON )
		fi
	else
		mycmakeargs+=( "-DGRAPHICSMAGICK=OFF -DMAGICK=OFF" )
	fi
	configuration() {
		mycmakeargs+=( $@ )
		cmake-utils_src_configure
	}
	configuration -DPYTHON_MODULE=OFF -DPYTHON=OFF
	use python && python_foreach_impl configuration -DPYTHON_MODULE=ON -DPYTHON=ON
}

src_compile() {
	cmake-utils_src_compile
	use python && python_foreach_impl cmake-utils_src_make
}

src_test() {
	# there is check target instead of the ctest to define some LDPATH
	Xemake -C "${BUILD_DIR}" check
}

src_install() {
	cmake-utils_src_install
	if use python; then
		installation() {
			python_export PYTHON_SITEDIR
			exeinto "${PYTHON_SITEDIR#${EPREFIX}}"
			newexe src/libgdl.so GDL.so
		}
		python_foreach_impl run_in_build_dir installation
		dodoc PYTHON.txt
	fi

	echo "GDL_PATH=\"+${EROOT%/}/usr/share/gnudatalanguage\"" > 50gdl
	doenvd 50gdl
}