[gentoo-commits] gentoo-x86 commit in net-misc/spice-gtk: spice-gtk-0.5.ebuild ChangeLog metadata.xml

[Tiziano Mueller (dev-zero)]

dev-zero    11/02/24 13:46:09

  Added:                spice-gtk-0.5.ebuild ChangeLog metadata.xml
  Log:
  Initial commit, ebuild written by me (bug #353780).
  
  (Portage version: 2.1.9.39/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  net-misc/spice-gtk/spice-gtk-0.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.5.ebuild?rev=1.1&content-type=text/plain

Index: spice-gtk-0.5.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.5.ebuild,v 1.1 2011/02/24 13:46:09 dev-zero Exp $

EAPI=3

inherit python gnome2-utils

PYTHON_DEPEND="python? 2"

DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI."
HOMEPAGE="http://spice-space.org http://gitorious.org/spice-gtk"
SRC_URI="http://spice-space.org/download/gtk/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+cairo doc gnome gstreamer introspection kde +pulseaudio python static-libs"

RDEPEND="pulseaudio? ( !gstreamer? ( media-sound/pulseaudio ) )
	gstreamer? ( media-libs/gstreamer )
	>=app-emulation/spice-protocol-0.6.3
	>=x11-libs/pixman-0.17.7
	>=media-libs/celt-0.5.1.1:0.5.1
	dev-libs/openssl
	x11-libs/gtk+:2
	dev-libs/glib:2
	>=x11-libs/cairo-1.2
	virtual/jpeg
	sys-libs/zlib
	introspection? ( dev-libs/gobject-introspection )
	python? ( dev-python/pygtk:2 )
	gnome? ( gnome-base/gconf )"
DEPEND="${RDEPEND}
	dev-lang/python
	dev-lang/perl
	dev-perl/Text-CSV
	dev-python/pyparsing
	dev-util/pkgconfig"

pkg_setup() {
	if use gstreamer && use pulseaudio ; then
		ewarn "spice-gtk can use only one audio backend: gstreamer will be used since you enabled both."
	fi
}

src_configure() {
	local audio="no"
	use pulseaudio && audio="pulse"
	use gstreamer && audio="gstreamer"

	econf \
		$(use_enable static-libs static) \
		$(use_enable introspection) \
		--with-audio="${audio}" \
		$(use_with !cairo x11) \
		$(use_with python)

}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	use static-libs || rm -rf "${D}"/usr/lib*/*.la
	use python && rm -rf "${D}"/usr/lib*/python*/site-packages/*.la
	use doc || rm -rf "${D}/usr/share/gtk-doc"

	dodoc AUTHORS NEWS README TODO

	if use gnome ; then
		insinto /etc/gconf/schemas
		doins "${FILESDIR}/spice.schemas"
	fi
	if use kde ; then
		insinto /usr/share/kde4/services
		doins "${FILESDIR}/spice.protocol"
	fi

}

pkg_preinst() {
	use gnome && gnome2_gconf_savelist
}

pkg_postinst() {
	use gnome && gnome2_gconf_install
}

pkg_prerm() {
	use gnome && gnome2_gconf_uninstall
}



1.1                  net-misc/spice-gtk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for net-misc/spice-gtk
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/ChangeLog,v 1.1 2011/02/24 13:46:09 dev-zero Exp $

*spice-gtk-0.5 (24 Feb 2011)

  24 Feb 2011; Tiziano Müller <dev-zero@g.o> +spice-gtk-0.5.ebuild,
  +files/spice.protocol, +files/spice.schemas, +metadata.xml:
  Initial commit, ebuild written by me (bug #353780).




1.1                  net-misc/spice-gtk/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>no-herd</herd>
	<maintainer>
		<email>dev-zero@g.o</email>
		<name>Tiziano Müller</name>
	</maintainer>
	<use>
		<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
	</use>
</pkgmetadata>