[gentoo-commits] gentoo-x86 commit in net-ftp/vsftpd: vsftpd-3.0.2-r4.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    15/01/31 13:07:47

  Modified:             ChangeLog
  Added:                vsftpd-3.0.2-r4.ebuild
  Log:
  Make sure child processes are killed properly. Bug #537290 by rhumbliner
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

Revision  Changes    Path
1.181                net-ftp/vsftpd/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/vsftpd/ChangeLog?rev=1.181&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/vsftpd/ChangeLog?rev=1.181&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/vsftpd/ChangeLog?r1=1.180&r2=1.181

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/vsftpd/ChangeLog,v
retrieving revision 1.180
retrieving revision 1.181
diff -u -r1.180 -r1.181
--- ChangeLog	14 Sep 2014 11:04:49 -0000	1.180
+++ ChangeLog	31 Jan 2015 13:07:47 -0000	1.181
@@ -1,6 +1,12 @@
 # ChangeLog for net-ftp/vsftpd
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/vsftpd/ChangeLog,v 1.180 2014/09/14 11:04:49 hwoarang Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/vsftpd/ChangeLog,v 1.181 2015/01/31 13:07:47 hwoarang Exp $
+
+*vsftpd-3.0.2-r4 (31 Jan 2015)
+
+  31 Jan 2015; Markos Chandras <hwoarang@g.o> +vsftpd-3.0.2-r4.ebuild,
+  files/vsftpd.init:
+  Make sure child processes are killed properly. Bug #537290 by rhumbliner
 
 *vsftpd-3.0.2-r3 (14 Sep 2014)
 



1.1                  net-ftp/vsftpd/vsftpd-3.0.2-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/vsftpd/vsftpd-3.0.2-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/vsftpd/vsftpd-3.0.2-r4.ebuild?rev=1.1&content-type=text/plain

Index: vsftpd-3.0.2-r4.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/vsftpd/vsftpd-3.0.2-r4.ebuild,v 1.1 2015/01/31 13:07:47 hwoarang Exp $

EAPI="4"

inherit eutils systemd toolchain-funcs

DESCRIPTION="Very Secure FTP Daemon written with speed, size and security in mind"
HOMEPAGE="http://vsftpd.beasts.org/"
SRC_URI="http://security.appspot.com/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="caps pam tcpd ssl selinux xinetd"

DEPEND="caps? ( >=sys-libs/libcap-2 )
	pam? ( virtual/pam )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	ssl? ( >=dev-libs/openssl-0.9.7d )"
RDEPEND="${DEPEND}
	net-ftp/ftpbase
	selinux? ( sec-policy/selinux-ftp )
	xinetd? ( sys-apps/xinetd )"

src_prepare() {
	# kerberos patch. bug #335980
	epatch "${FILESDIR}/${PN}-2.3.2-kerberos.patch"

	# Patch the source, config and the manpage to use /etc/vsftpd/
	epatch "${FILESDIR}/${PN}-2.3.5-gentoo.patch"

	# Fix building without the libcap
	epatch "${FILESDIR}/${PN}-2.1.0-caps.patch"

	# Fix building on alpha. Bug #405829
	epatch "${FILESDIR}/${PN}-3.0.2-alpha.patch"

	# Increase AS_LIMIT. Bug #522412
	epatch "${FILESDIR}/${P}-aslim.patch"

	# Configure vsftpd build defaults
	use tcpd && echo "#define VSF_BUILD_TCPWRAPPERS" >> builddefs.h
	use ssl && echo "#define VSF_BUILD_SSL" >> builddefs.h
	use pam || echo "#undef VSF_BUILD_PAM" >> builddefs.h

	# Ensure that we don't link against libcap unless asked
	if ! use caps ; then
		sed -i '/^#define VSF_SYSDEP_HAVE_LIBCAP$/ d' sysdeputil.c || die
		epatch "${FILESDIR}"/${PN}-2.2.0-dont-link-caps.patch
	fi

	# Let portage control stripping
	sed -i '/^LINK[[:space:]]*=[[:space:]]*/ s/-Wl,-s//' Makefile || die

	#Bug #335977
	epatch "${FILESDIR}"/${PN}-3.0.0-Makefile.patch

	#Bug #450536
	epatch "${FILESDIR}"/${P}-remove-legacy-cap.patch

	epatch_user
}

src_compile() {
	# Override LIBS variable. Bug #508192
	LIBS=
	use caps && LIBS+=" -lcap"
	use pam && LIBS+=" -lpam"
	use tcpd && LIBS+=" -lwrap"
	use ssl && LIBS+=" -lssl -lcrypto"

	CFLAGS="${CFLAGS}" \
	CC="$(tc-getCC)" \
	emake LIBS="${LIBS}"
}

src_install() {
	into /usr
	doman ${PN}.conf.5 ${PN}.8
	dosbin ${PN} || die "disbin failed"

	dodoc AUDIT BENCHMARKS BUGS Changelog FAQ \
		README README.security REWARD SIZE \
		SPEED TODO TUNING || die "dodoc failed"
	newdoc ${PN}.conf ${PN}.conf.example

	docinto security
	dodoc SECURITY/* || die "dodoc failed"

	insinto "/usr/share/doc/${PF}/examples"
	doins -r EXAMPLE/* || die "doins faileD"

	insinto /etc/${PN}
	newins ${PN}.conf{,.example}

	insinto /etc/logrotate.d
	newins "${FILESDIR}/${PN}.logrotate" ${PN}

	if use xinetd ; then
		insinto /etc/xinetd.d
		newins "${FILESDIR}/${PN}.xinetd" ${PN}
	fi

	newinitd "${FILESDIR}/${PN}.init" ${PN}

	keepdir /usr/share/${PN}/empty

	exeinto /usr/libexec
	doexe "${FILESDIR}/vsftpd-checkconfig.sh"
	systemd_dounit "${FILESDIR}/${PN}.service"
	systemd_newunit "${FILESDIR}/${PN}_at.service" "${PN}@.service"
	systemd_dounit "${FILESDIR}/${PN}.socket"
}

pkg_preinst() {
	# If we use xinetd, then we set listen=NO
	# so that our default config works under xinetd - fixes #78347
	if use xinetd ; then
		sed -i 's/listen=YES/listen=NO/g' "${D}"/etc/${PN}/${PN}.conf.example
	fi
}

pkg_postinst() {
	einfo "vsftpd openRC init script can now be multiplexed."
	einfo "The default init script forces /etc/vsftpd/vsftpd.conf to exist."
	einfo "If you symlink the init script to another one, say vsftpd.foo"
	einfo "then that uses /etc/vsftpd/foo.conf instead."
	einfo
	einfo "Example:"
	einfo "   cd /etc/init.d"
	einfo "   ln -s vsftpd vsftpd.foo"
	einfo "You can now treat vsftpd.foo like any other service"
}