Gentoo Archives: gentoo-commits

From: "Julian Ospald (hasufell)" <hasufell@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] gentoo-x86 commit in sys-apps/etckeeper: ChangeLog etckeeper-1.3.ebuild
Date: Fri, 31 May 2013 19:35:08
Message-Id: 20130531193502.7CCBE2171D@flycatcher.gentoo.org
hasufell    13/05/31 19:35:02

  Modified:             ChangeLog
  Added:                etckeeper-1.3.ebuild
  Log:
  version bump wrt #469370 by Manuel Rüger
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.17                 sys-apps/etckeeper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	29 May 2013 13:37:22 -0000	1.16
+++ ChangeLog	31 May 2013 19:35:02 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/etckeeper
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.16 2013/05/29 13:37:22 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/ChangeLog,v 1.17 2013/05/31 19:35:02 hasufell Exp $
+
+*etckeeper-1.3 (31 May 2013)
+
+  31 May 2013; Julian Ospald <hasufell@g.o> +etckeeper-1.3.ebuild,
+  +files/etckeeper-1.3-gentoo.patch:
+  version bump wrt #469370 by Manuel Rüger
 
   29 May 2013; Julian Ospald <hasufell@g.o> etckeeper-0.63-r1.ebuild:
   update REQUIRED_USE to include PYTHON_REQUIRED_USE



1.1                  sys-apps/etckeeper/etckeeper-1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/etckeeper/etckeeper-1.3.ebuild?rev=1.1&content-type=text/plain

Index: etckeeper-1.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/etckeeper/etckeeper-1.3.ebuild,v 1.1 2013/05/31 19:35:02 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )

inherit eutils bash-completion-r1 prefix python-r1

DESCRIPTION="A collection of tools to let /etc be stored in a repository"
HOMEPAGE="http://kitenet.net/~joey/code/etckeeper/"
SRC_URI="https://github.com/joeyh/etckeeper/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-2"
IUSE="bazaar cron"
KEYWORDS="~amd64 ~x86"
SLOT="0"

VCS_DEPEND="
	dev-vcs/git
	dev-vcs/mercurial
	dev-vcs/darcs"
DEPEND="bazaar? ( dev-vcs/bzr )"
RDEPEND="${DEPEND}
	app-portage/portage-utils
	cron? ( virtual/cron )
	bazaar? ( ${PYTHON_DEPS} )
	!bazaar? ( || ( ${VCS_DEPEND} ) )"

src_prepare(){
	epatch "${FILESDIR}"/${P}-gentoo.patch
}

src_compile() {
	:
}

src_install(){
	emake DESTDIR="${ED}" install

	bzr_install() {
		${PYTHON} ./${PN}-bzr/__init__.py install --root="${ED}" ||
			die "bzr support installation failed!"
	}
	use bazaar && python_foreach_impl bzr_install

	if use prefix; then
		doenvd "${FILESDIR}"/99${PN}
		eprefixify "${ED%/}"/etc/env.d/99${PN}
	fi

	newbashcomp bash_completion ${PN}
	dodoc README TODO
	docinto examples
	dodoc "${FILESDIR}"/bashrc

	if use cron ; then
		exeinto /etc/cron.daily
		newexe debian/cron.daily etckeeper
	fi
}

pkg_postinst(){
	elog "${PN} supports the following VCS: ${VCS_DEPEND}"
	elog "	dev-vcs/bzr"
	elog "This ebuild just ensures at least one is installed!"
	elog "For dev-vcs/bzr you need to enable 'bazaar' useflag."
	elog
	elog "You may want to adjust your /etc/portage/bashrc"
	elog "see the example file in /usr/share/doc/${P}/examples"
	elog
	elog "To initialise your etc-dir as a repository run:"
	elog "${PN} init -d /etc"
}