[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

[Thomas Deutschmann]

commit:     9a4f9483eda06daa0db5313282ba45abc14e4ce2
Author:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
AuthorDate: Mon Jun 14 23:43:26 2021 +0000
Commit:     Thomas Deutschmann <whissi <AT> gentoo <DOT> org>
CommitDate: Mon Jun 14 23:43:36 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9a4f9483

sys-apps/fwupd: bump to v1.6.1

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Thomas Deutschmann <whissi <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.6.1.ebuild | 170 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 171 insertions(+)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 6f398a24c1c..5d6d529b44d 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,2 +1,3 @@
 DIST fwupd-1.5.9.tar.gz 3712637 BLAKE2B 17429bdc3073a92b94de9bc67ce1955e928e8d6aeefa5f0ad39a9d15457f96c562ce5cfbc47e1fc450c31c2b9334ca3902ed63ef809e8d2cb5b5459cc54dec28 SHA512 ccd1246ab5b3c876251924a14d1c2c553b2df5702c6673978b1d627ea1028c3950241f73dd54e2fecb5cc204a1dc77e6597f7514eff6467beb50be7874352d78
 DIST fwupd-1.6.0.tar.gz 3747361 BLAKE2B 6368089db78a512048268ef3cb0333c75bb95b0f62d023e3db7c854c3362b88db1b1676cc24b9a4a5fe854e7dea6c727ec3d645476ee323a0dae16caf7028478 SHA512 0f2342fba95d635348c4b153887f2ea27e4bf49972558716143051ba79c39948487eb6cc15f938738d83aa3ea3eef5ae2854c9756a60f59f52ac859d35e2a669
+DIST fwupd-1.6.1.tar.gz 3786336 BLAKE2B 429e41cad3acdcd9b245532a38126a8e3d366081aba16b9f3e04a2029980b8d6e3f4ac3f8c6d6cd1332c344526a7901c976d6fa0bc1c4011e54d5dc96a427d2d SHA512 6d795e9898de6097d0f1185fbc3a6864566f90fc504e5d9cf192e5dca50c659d39f43f1922c7506151bd1538a23db507e95893436de733b1335bd69dc56f3b1c

diff --git a/sys-apps/fwupd/fwupd-1.6.1.ebuild b/sys-apps/fwupd/fwupd-1.6.1.ebuild
new file mode 100644
index 00000000000..e0f4a52cfe5
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.6.1.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..10} )
+
+inherit linux-info meson python-single-r1 vala xdg toolchain-funcs
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="agent amt archive bluetooth dell gnutls gtk-doc gusb elogind flashrom lzma minimal introspection +man nvme policykit spi synaptics systemd test thunderbolt tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	dell? ( uefi )
+	minimal? ( !introspection )
+	spi? ( lzma )
+	synaptics? ( gnutls )
+	uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	dev-libs/libgudev:=
+	>=dev-libs/libjcat-0.1.0[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.1.13:=
+	$(python_gen_cond_dep '
+		dev-python/pillow[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_MULTI_USEDEP}]
+	')
+	>=net-libs/libsoup-2.51.92:2.4[introspection?]
+	net-misc/curl
+	virtual/libelf:0=
+	virtual/udev
+	archive? ( app-arch/libarchive:= )
+	dell? ( >=sys-libs/libsmbios-2.4.0 )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( net-libs/gnutls )
+	gusb? ( >=dev-libs/libgusb-0.3.5[introspection?] )
+	lzma? ( app-arch/xz-utils )
+	policykit? ( >=sys-auth/polkit-0.103 )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss )
+	uefi? (
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+# Block sci-chemistry/chemical-mime-data for bug #701900
+RDEPEND="
+	!<sci-chemistry/chemical-mime-data-0.1.94-r4
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.5.7-logind_plugin.patch"
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	if use nvme ; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	sed '/platform-integrity/d' \
+		-i plugins/meson.build || die #753521
+	vala_src_prepare
+}
+
+src_configure() {
+	local plugins=(
+		$(meson_use amt plugin_amt)
+		$(meson_use dell plugin_dell)
+		$(meson_use flashrom plugin_flashrom)
+		$(meson_use gusb plugin_altos)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use spi plugin_intel_spi)
+		$(meson_use synaptics plugin_synaptics_mst)
+		$(meson_use synaptics plugin_synaptics_rmi)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use tpm plugin_tpm)
+		$(meson_use uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+		$(meson_use uefi plugin_uefi_pk)
+
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+	)
+	use ppc64 && plugins+=( -Dplugin_msr="false" )
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Dconsolekit="false"
+		-Dcurl="true"
+		-Ddocs="$(usex gtk-doc gtkdoc none)"
+		-Defi_binary="false"
+		-Dsupported_build="true"
+		$(meson_use agent)
+		$(meson_use archive libarchive)
+		$(meson_use bluetooth bluez)
+		$(meson_use elogind)
+		$(meson_use gnutls)
+		$(meson_use gusb)
+		$(meson_use lzma)
+		$(meson_use man)
+		$(meson_use introspection)
+		$(meson_use policykit polkit)
+		$(meson_use systemd)
+		$(meson_use test tests)
+
+		${plugins[@]}
+	)
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+
+		if ! use systemd ; then
+			# Don't timeout when fwupd is running (#673140)
+			sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+				-i "${ED}"/etc/${PN}/daemon.conf || die
+		fi
+	fi
+}