[gentoo-commits] gentoo-x86 commit in media-video/nvclock: ChangeLog nvclock-9999.ebuild

[Jeroen Roovers (jer)]

jer         09/07/28 17:14:17

  Modified:             ChangeLog
  Added:                nvclock-9999.ebuild
  Log:
  Add a live ebuild (based on the one by Peter Fern attached to bug #204428).
  (Portage version: 2.2_rc33/cvs/Linux i686)

Revision  Changes    Path
1.35                 media-video/nvclock/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvclock/ChangeLog?rev=1.35&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvclock/ChangeLog?rev=1.35&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvclock/ChangeLog?r1=1.34&r2=1.35

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/nvclock/ChangeLog,v
retrieving revision 1.34
retrieving revision 1.35
diff -u -r1.34 -r1.35
--- ChangeLog	28 Jul 2009 15:20:52 -0000	1.34
+++ ChangeLog	28 Jul 2009 17:14:17 -0000	1.35
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/nvclock
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvclock/ChangeLog,v 1.34 2009/07/28 15:20:52 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvclock/ChangeLog,v 1.35 2009/07/28 17:14:17 jer Exp $
+
+*nvclock-9999 (28 Jul 2009)
+
+  28 Jul 2009; Jeroen Roovers <jer@g.o> +nvclock-9999.ebuild:
+  Add a live ebuild (based on the one by Peter Fern attached to bug #204428).
 
   28 Jul 2009; Jeroen Roovers <jer@g.o> metadata.xml:
   Pick up maintainership.



1.1                  media-video/nvclock/nvclock-9999.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvclock/nvclock-9999.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvclock/nvclock-9999.ebuild?rev=1.1&content-type=text/plain

Index: nvclock-9999.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/nvclock/nvclock-9999.ebuild,v 1.1 2009/07/28 17:14:17 jer Exp $

EAPI="2"

inherit eutils autotools cvs

ECVS_SERVER="nvclock.cvs.sourceforge.net:/cvsroot/nvclock"
ECVS_MODULE="nvclock"
ECVS_USER="anonymous"
ECVS_PASS=""

DESCRIPTION="NVIDIA Overclocking Utility"
HOMEPAGE="http://www.linuxhardware.org/nvclock/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="gtk qt3"

RDEPEND="
	gtk? ( x11-libs/gtk+:2 )
	qt3? ( x11-libs/qt:3 )
"
DEPEND="${RDEPEND}"

S="${WORKDIR}/${PN}"

src_prepare() {
	eautoreconf
}

src_configure() {
	# Needed to ensure it compiles against Qt3 rather than Qt4
	export QTDIR=/usr/qt/3
	export MOC=${QTDIR}/bin/moc

	econf $(use_enable qt3 qt) $(use_enable gtk) || die "econf failed"
}

src_compile() {
	# The build fails with -j[N>1]
	emake -j1 || die "emake failed"
}

src_install() {
	dodir /usr/bin
	einstall || die "einstall failed"
	dodoc AUTHORS README

	newinitd "${FILESDIR}"/nvclock_initd nvclock
	newconfd "${FILESDIR}"/nvclock_confd nvclock
}

pkg_postinst() {
	elog "To enable card overclocking at startup, edit your /etc/conf.d/nvclock"
	elog "accordingly and then run: rc-update add nvclock default"
}