[gentoo-commits] gentoo-x86 commit in x11-plugins/purple-plugin_pack: ChangeLog purple-plugin_pack-2.6.3.ebuild purple-plugin_pack-2.6.2.ebuild

[Peter Volkov (pva)]

pva         10/04/23 10:38:01

  Modified:             ChangeLog
  Added:                purple-plugin_pack-2.6.3.ebuild
  Removed:              purple-plugin_pack-2.6.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 x11-plugins/purple-plugin_pack/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	18 Apr 2010 16:51:01 -0000	1.30
+++ ChangeLog	23 Apr 2010 10:38:01 -0000	1.31
@@ -1,6 +1,12 @@
 # ChangeLog for x11-plugins/purple-plugin_pack
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog,v 1.30 2010/04/18 16:51:01 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/ChangeLog,v 1.31 2010/04/23 10:38:01 pva Exp $
+
+*purple-plugin_pack-2.6.3 (23 Apr 2010)
+
+  23 Apr 2010; Peter Volkov <pva@g.o>
+  -purple-plugin_pack-2.6.2.ebuild, +purple-plugin_pack-2.6.3.ebuild:
+  Version bump.
 
   18 Apr 2010; <nixnut@g.o> purple-plugin_pack-2.6.2-r1.ebuild:
   ppc stable #310021



1.1                  x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.3.ebuild?rev=1.1&content-type=text/plain

Index: purple-plugin_pack-2.6.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-plugins/purple-plugin_pack/purple-plugin_pack-2.6.3.ebuild,v 1.1 2010/04/23 10:38:01 pva Exp $

EAPI="2"

inherit eutils

DESCRIPTION="A package with many different plugins for pidgin and libpurple"
HOMEPAGE="http://plugins.guifications.org"
SRC_URI="mirror://gentoo/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~x86"
IUSE="debug gtk ncurses spell talkfilters"

RDEPEND="net-im/pidgin[gtk?,ncurses?]
	talkfilters? ( app-text/talkfilters )
	spell? ( app-text/gtkspell )"
DEPEND="${RDEPEND}
	dev-lang/python"

list_plugins_dep() {
	local dependency=${1}
	grep -EH "depends.*$dependency" */plugins.cfg | sed 's:/.*::'
}

src_configure() {
	local plugins=""

	# list all plugins, then pull DISABLED_PLUGINS with the ones we don't need
	plugins="$(python plugin_pack.py -d dist_dirs)"
	einfo "List of all possible plugins:"
	einfo "${plugins}"

	eval DISABLED_PLUGINS="\$${PN//[^a-z]/_}_DISABLED_PLUGINS"
	# disable known broken plugins
	DISABLED_PLUGINS+=" schedule findip"
	use gtk || DISABLED_PLUGINS+=" $(list_plugins_dep pidgin)"
	use ncurses || DISABLED_PLUGINS+=" $(list_plugins_dep finch)"
	use spell || DISABLED_PLUGINS+=" $(list_plugins_dep gtkspell)"
	use talkfilters || DISABLED_PLUGINS+=" $(list_plugins_dep talkfiltersbin)"

	for plug in ${DISABLED_PLUGINS}; do
		plugins="${plugins//${plug}}"
	done

	plugins="$(echo ${plugins} | sed 's:[ \t]\+:,:g;s:,$::;s:^,::')"

	econf \
		--with-plugins="${plugins}" \
		$(use_enable debug)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS ChangeLog NEWS README VERSION || die
}

pkg_preinst() {
	elog "Note: if you want to disable some plugins in pack, define"
	elog "${PN//[^a-z]/_}_DISABLED_PLUGINS with a list of plugins to"
	elog "skip during install (for list see einfo in build output)."
}