[gentoo-commits] gentoo-x86 commit in media-sound/qsynth: ChangeLog qsynth-0.3.5.ebuild

[Alexis Ballier (aballier)]

aballier    10/04/27 19:07:14

  Modified:             ChangeLog
  Added:                qsynth-0.3.5.ebuild
  Log:
  version bump
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 media-sound/qsynth/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qsynth/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qsynth/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qsynth/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	6 Oct 2009 17:12:34 -0000	1.48
+++ ChangeLog	27 Apr 2010 19:07:14 -0000	1.49
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/qsynth
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.48 2009/10/06 17:12:34 ayoy Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/ChangeLog,v 1.49 2010/04/27 19:07:14 aballier Exp $
+
+*qsynth-0.3.5 (27 Apr 2010)
+
+  27 Apr 2010; Alexis Ballier <aballier@g.o> +qsynth-0.3.5.ebuild:
+  version bump
 
   06 Oct 2009; Dominik Kapusta <ayoy@g.o> qsynth-0.3.4.ebuild:
   Removed alternative dependency on Qt metapackage



1.1                  media-sound/qsynth/qsynth-0.3.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qsynth/qsynth-0.3.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qsynth/qsynth-0.3.5.ebuild?rev=1.1&content-type=text/plain

Index: qsynth-0.3.5.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/qsynth/qsynth-0.3.5.ebuild,v 1.1 2010/04/27 19:07:14 aballier Exp $

EAPI=2

inherit qt4 eutils flag-o-matic

DESCRIPTION="A Qt application to control FluidSynth"
HOMEPAGE="http://qsynth.sourceforge.net/"
SRC_URI="mirror://sourceforge/qsynth/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
IUSE="debug jack alsa pulseaudio"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"

DEPEND="x11-libs/qt-core:4
	x11-libs/qt-gui:4
	>=media-sound/fluidsynth-1.0.7a[jack?,alsa?,pulseaudio?]
	!pulseaudio? ( !jack? ( !alsa? ( >=media-sound/fluidsynth-1.0.7a[oss] ) ) )"
RDEPEND="${DEPEND}"

src_configure() {
	# Stupidly, qsynth's configure does *not* use pkg-config to
	# discover the presence of Qt4, but uses fixed paths; as they
	# don't really work that well for our case, let's just use this
	# nasty hack and be done with it. *NOTE*: this hinders
	# cross-compile.
	append-flags -I/usr/include/qt4
	append-ldflags -L/usr/$(get_libdir)/qt4

	econf \
		$(use_enable debug) \
		|| die "econf failed"
	eqmake4 "${PN}.pro" -o "${PN}.mak"
}

src_compile() {
	lupdate  "${PN}.pro" || die
	emake || die
}

src_install () {
	emake DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS ChangeLog README TODO

	# The desktop file is invalid, and we also change the command
	# depending on useflags
	rm -rf "${D}/usr/share/applications/qsynth.desktop"

	local cmd
	if use jack; then
		cmd="qsynth"
	elif use pulseaudio; then
		cmd="qsynth -a pulseaudio"
	elif use alsa; then
		cmd="qsynth -a alsa"
	else
		cmd="qsynth -a oss"
	fi

	make_desktop_entry "${cmd}" Qsynth qsynth
}