[gentoo-commits] gentoo-x86 commit in net-ftp/lftp: ChangeLog lftp-4.1.2.ebuild

[Jeroen Roovers (jer)]

jer         11/01/03 02:24:19

  Modified:             ChangeLog
  Added:                lftp-4.1.2.ebuild
  Log:
  Version bump. Switch to xz.
  
  (Portage version: 2.2.0_alpha11/cvs/Linux i686)

Revision  Changes    Path
1.286                net-ftp/lftp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.286&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?rev=1.286&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/ChangeLog?r1=1.285&r2=1.286

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v
retrieving revision 1.285
retrieving revision 1.286
diff -u -r1.285 -r1.286
--- ChangeLog	2 Jan 2011 17:11:25 -0000	1.285
+++ ChangeLog	3 Jan 2011 02:24:15 -0000	1.286
@@ -1,6 +1,11 @@
 # ChangeLog for net-ftp/lftp
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.285 2011/01/02 17:11:25 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/ChangeLog,v 1.286 2011/01/03 02:24:15 jer Exp $
+
+*lftp-4.1.2 (03 Jan 2011)
+
+  03 Jan 2011; Jeroen Roovers <jer@g.o> +lftp-4.1.2.ebuild:
+  Version bump. Switch to xz.
 
   02 Jan 2011; Markus Meier <maekke@g.o> lftp-4.1.1.ebuild:
   arm stable, bug #349801



1.1                  net-ftp/lftp/lftp-4.1.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-ftp/lftp/lftp-4.1.2.ebuild?rev=1.1&content-type=text/plain

Index: lftp-4.1.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-ftp/lftp/lftp-4.1.2.ebuild,v 1.1 2011/01/03 02:24:19 jer Exp $

EAPI="3"

inherit autotools eutils

DESCRIPTION="A sophisticated ftp/sftp/http/https/torrent client and file transfer program"
HOMEPAGE="http://lftp.yar.ru/"
SRC_URI="http://ftp.yars.free.net/pub/source/${PN}/${P}.tar.xz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="ssl gnutls socks5 nls"

RDEPEND="
	>=sys-libs/ncurses-5.1
	socks5? (
		>=net-proxy/dante-1.1.12
		virtual/pam )
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.3 )
		!gnutls? ( >=dev-libs/openssl-0.9.6 )
	)
	>=sys-libs/readline-5.1
"

DEPEND="
	${RDEPEND}
	app-arch/xz-utils
	nls? ( sys-devel/gettext )
	dev-lang/perl
	=sys-devel/libtool-2*
"
src_prepare() {
	epatch "${FILESDIR}/${PN}-4.0.2.91-lafile.patch"
	epatch "${FILESDIR}/${PN}-4.0.3-autoconf-2.64.patch"
	eautoreconf
}

src_configure() {
	local myconf="$(use_enable nls) --enable-packager-mode"

	if use ssl && use gnutls ; then
		myconf="${myconf} --without-openssl"
	elif use ssl && ! use gnutls ; then
		myconf="${myconf} --without-gnutls --with-openssl=/usr"
	else
		myconf="${myconf} --without-gnutls --without-openssl"
	fi

	use socks5 && myconf="${myconf} --with-socksdante=/usr" \
		|| myconf="${myconf} --without-socksdante"

	econf \
		--sysconfdir=/etc/lftp \
		--with-modules \
		${myconf} || die "econf failed"
}

src_install() {
	emake install DESTDIR="${D}" || die

	dodoc BUGS ChangeLog FAQ FEATURES MIRRORS \
			NEWS README* THANKS TODO
}