1 |
commit: 6c2068a42a19f0d7c1367b4741d26d2fbd645f94 |
2 |
Author: Sam James <sam <AT> gentoo <DOT> org> |
3 |
AuthorDate: Fri Sep 30 02:57:10 2022 +0000 |
4 |
Commit: Sam James <sam <AT> gentoo <DOT> org> |
5 |
CommitDate: Fri Sep 30 02:57:54 2022 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6c2068a4 |
7 |
|
8 |
net-fs/samba: add 4.15.10 |
9 |
|
10 |
Signed-off-by: Sam James <sam <AT> gentoo.org> |
11 |
|
12 |
net-fs/samba/Manifest | 1 + |
13 |
net-fs/samba/samba-4.15.10.ebuild | 333 ++++++++++++++++++++++++++++++++++++++ |
14 |
2 files changed, 334 insertions(+) |
15 |
|
16 |
diff --git a/net-fs/samba/Manifest b/net-fs/samba/Manifest |
17 |
index 5d4928840127..ecaa179e0587 100644 |
18 |
--- a/net-fs/samba/Manifest |
19 |
+++ b/net-fs/samba/Manifest |
20 |
@@ -1,5 +1,6 @@ |
21 |
DIST samba-4.14.13.tar.gz 19161242 BLAKE2B 068d17872536edcc0de400ee925723a9a55022dd43fd5309562cf65a92d992011f9963b4009170405394b724eafab4760c689d571884b164a63661a99b42ec4c SHA512 477a94a2b9d9eeff21055c7601f3539e9ff01ab536320c303ac9a6578d5e7f09f46e7f4f5a971594e11ad19fe9a566f209d201cc32b78c164b885c1c4d591b9b |
22 |
DIST samba-4.14.14.tar.gz 19174363 BLAKE2B 5714ab40bc22d2692c81502fd6b05e222099818ebb3b7f26a91a89c78a6a2bfd8044b81f053a958b41ec156bb5a55e245af70a28eb315cc51292857f34858730 SHA512 77b9a51e8d542e4535eacf25b653dc21732f4608505507690d3ac3e8f8657c09e4f8b9c5bb9a24381d8e5316d712a914b021bb18dc4c464ee9a00755f6f7956f |
23 |
+DIST samba-4.15.10.tar.gz 19333317 BLAKE2B 20b414d51f915cfdcd50a10dd9d315d3be23a43d35051aa6ff8cdc3c07f430d96d933765a96882db0350792e740a4a4a18963cb7e8baa198c606180b9da273c3 SHA512 68e0096df9e348fdf389a11433391cd85606f075e9402ce64f2228daf126d794caf0050463eb2245933551b299735b25d5d5036c4ac78aba3e23c2fc2dce9ef6 |
24 |
DIST samba-4.15.7.tar.gz 19290930 BLAKE2B 4a295f79d38212d4c6917ed61a22e4204b5ea3d5e26f30b65d1e7e81842e92405870dd40fd4d05ec1126a532bdb1ddea300848387a4c64370ba5c2c1354ee8e5 SHA512 beffb09b5bcd62991398d39c7a8aec5fed0c51d550e2f0fb42b2e0a09094f4c6a8f29adf708c4969db12329f5c7343d2debd04315107b79bef59e99a4a7e4ce4 |
25 |
DIST samba-4.15.9.tar.gz 19324742 BLAKE2B 36cca5ac1b449339f2ce420d4f29f25151bcd536556bfc571db6422a95e9c5daed98b9a71387babbfc61d43e5ff183a1b69255dbec966f80a1cb8fe0ad40f636 SHA512 2ee5d66f5a7c1ff5b27c959be6310335eb6484476c1eadb3b8ca1bc84fb2260487136c1318539e1dc459b81bca66f268fd979f6a816ff5f905bd605a99685004 |
26 |
DIST samba-4.16.4.tar.gz 30605121 BLAKE2B e685511a76770272cabd1292f36d2b005e2d21212e4782cdf4fd05039f7667b35501873cffa9a53547d523805b2a91ffeba0881aaee905304968c42efef22dfa SHA512 9754275ace30755b75f747e201f8ad4550a823c8606e550c0ce6b3ccbaf048dd895bf2c21127271298304be7f80de9b6451091c4949ebe267ee1cf3ab497cd85 |
27 |
|
28 |
diff --git a/net-fs/samba/samba-4.15.10.ebuild b/net-fs/samba/samba-4.15.10.ebuild |
29 |
new file mode 100644 |
30 |
index 000000000000..6042a3515c40 |
31 |
--- /dev/null |
32 |
+++ b/net-fs/samba/samba-4.15.10.ebuild |
33 |
@@ -0,0 +1,333 @@ |
34 |
+# Copyright 1999-2022 Gentoo Authors |
35 |
+# Distributed under the terms of the GNU General Public License v2 |
36 |
+ |
37 |
+EAPI=7 |
38 |
+ |
39 |
+PYTHON_COMPAT=( python3_{8..10} ) |
40 |
+PYTHON_REQ_USE="threads(+),xml(+)" |
41 |
+inherit python-single-r1 waf-utils multilib-minimal linux-info systemd pam tmpfiles |
42 |
+ |
43 |
+DESCRIPTION="Samba Suite Version 4" |
44 |
+HOMEPAGE="https://samba.org/" |
45 |
+ |
46 |
+MY_PV="${PV/_rc/rc}" |
47 |
+MY_P="${PN}-${MY_PV}" |
48 |
+if [[ ${PV} = *_rc* ]]; then |
49 |
+ SRC_URI="mirror://samba/rc/${MY_P}.tar.gz" |
50 |
+else |
51 |
+ SRC_URI="mirror://samba/stable/${MY_P}.tar.gz" |
52 |
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86" |
53 |
+fi |
54 |
+S="${WORKDIR}/${MY_P}" |
55 |
+ |
56 |
+LICENSE="GPL-3" |
57 |
+SLOT="0" |
58 |
+IUSE="acl addc ads ceph client cluster cpu_flags_x86_aes cups debug fam |
59 |
+glusterfs gpg iprint json ldap llvm-libunwind pam profiling-data python quota +regedit selinux |
60 |
+snapper spotlight syslog system-heimdal +system-mitkrb5 systemd test unwind winbind |
61 |
+zeroconf" |
62 |
+ |
63 |
+REQUIRED_USE="${PYTHON_REQUIRED_USE} |
64 |
+ addc? ( python json winbind ) |
65 |
+ ads? ( acl ldap python winbind ) |
66 |
+ cluster? ( ads ) |
67 |
+ gpg? ( addc ) |
68 |
+ spotlight? ( json ) |
69 |
+ test? ( python ) |
70 |
+ !ads? ( !addc ) |
71 |
+ ?? ( system-heimdal system-mitkrb5 ) |
72 |
+" |
73 |
+ |
74 |
+# the test suite is messed, it uses system-installed samba |
75 |
+# bits instead of what was built, tests things disabled via use |
76 |
+# flags, and generally just fails to work in a way ebuilds could |
77 |
+# rely on in its current state |
78 |
+RESTRICT="test" |
79 |
+ |
80 |
+MULTILIB_WRAPPED_HEADERS=( |
81 |
+ /usr/include/samba-4.0/policy.h |
82 |
+ /usr/include/samba-4.0/dcerpc_server.h |
83 |
+ /usr/include/samba-4.0/ctdb.h |
84 |
+ /usr/include/samba-4.0/ctdb_client.h |
85 |
+ /usr/include/samba-4.0/ctdb_protocol.h |
86 |
+ /usr/include/samba-4.0/ctdb_private.h |
87 |
+ /usr/include/samba-4.0/ctdb_typesafe_cb.h |
88 |
+ /usr/include/samba-4.0/ctdb_version.h |
89 |
+) |
90 |
+ |
91 |
+COMMON_DEPEND=" |
92 |
+ >=app-arch/libarchive-3.1.2[${MULTILIB_USEDEP}] |
93 |
+ dev-lang/perl:= |
94 |
+ dev-libs/icu:=[${MULTILIB_USEDEP}] |
95 |
+ dev-libs/libbsd[${MULTILIB_USEDEP}] |
96 |
+ dev-libs/libtasn1[${MULTILIB_USEDEP}] |
97 |
+ dev-libs/popt[${MULTILIB_USEDEP}] |
98 |
+ dev-perl/Parse-Yapp |
99 |
+ >=net-libs/gnutls-3.4.7[${MULTILIB_USEDEP}] |
100 |
+ >=sys-fs/e2fsprogs-1.46.4-r51[${MULTILIB_USEDEP}] |
101 |
+ >=sys-libs/ldb-2.4.4[ldap(+)?,${MULTILIB_USEDEP}] |
102 |
+ <sys-libs/ldb-2.5.0[ldap(+)?,${MULTILIB_USEDEP}] |
103 |
+ sys-libs/libcap[${MULTILIB_USEDEP}] |
104 |
+ sys-libs/liburing:=[${MULTILIB_USEDEP}] |
105 |
+ sys-libs/ncurses:0= |
106 |
+ sys-libs/readline:0= |
107 |
+ >=sys-libs/talloc-2.3.3[${MULTILIB_USEDEP}] |
108 |
+ >=sys-libs/tdb-1.4.4[${MULTILIB_USEDEP}] |
109 |
+ >=sys-libs/tevent-0.11.0[${MULTILIB_USEDEP}] |
110 |
+ sys-libs/zlib[${MULTILIB_USEDEP}] |
111 |
+ virtual/libcrypt:=[${MULTILIB_USEDEP}] |
112 |
+ virtual/libiconv |
113 |
+ $(python_gen_cond_dep " |
114 |
+ addc? ( |
115 |
+ dev-python/dnspython:=[\${PYTHON_USEDEP}] |
116 |
+ dev-python/markdown[\${PYTHON_USEDEP}] |
117 |
+ ) |
118 |
+ ads? ( |
119 |
+ dev-python/dnspython:=[\${PYTHON_USEDEP}] |
120 |
+ net-dns/bind-tools[gssapi] |
121 |
+ ) |
122 |
+ ") |
123 |
+ acl? ( virtual/acl ) |
124 |
+ ceph? ( sys-cluster/ceph ) |
125 |
+ cluster? ( net-libs/rpcsvc-proto ) |
126 |
+ cups? ( net-print/cups ) |
127 |
+ debug? ( dev-util/lttng-ust ) |
128 |
+ fam? ( virtual/fam ) |
129 |
+ gpg? ( app-crypt/gpgme:= ) |
130 |
+ json? ( dev-libs/jansson:= ) |
131 |
+ ldap? ( net-nds/openldap:=[${MULTILIB_USEDEP}] ) |
132 |
+ pam? ( sys-libs/pam ) |
133 |
+ python? ( |
134 |
+ sys-libs/ldb[python,${PYTHON_SINGLE_USEDEP}] |
135 |
+ sys-libs/talloc[python,${PYTHON_SINGLE_USEDEP}] |
136 |
+ sys-libs/tdb[python,${PYTHON_SINGLE_USEDEP}] |
137 |
+ sys-libs/tevent[python,${PYTHON_SINGLE_USEDEP}] |
138 |
+ ) |
139 |
+ snapper? ( sys-apps/dbus ) |
140 |
+ system-heimdal? ( >=app-crypt/heimdal-1.5[-ssl,${MULTILIB_USEDEP}] ) |
141 |
+ system-mitkrb5? ( >=app-crypt/mit-krb5-1.19[${MULTILIB_USEDEP}] ) |
142 |
+ systemd? ( sys-apps/systemd:0= ) |
143 |
+ unwind? ( |
144 |
+ llvm-libunwind? ( sys-libs/llvm-libunwind:= ) |
145 |
+ !llvm-libunwind? ( sys-libs/libunwind:= ) |
146 |
+ ) |
147 |
+ zeroconf? ( net-dns/avahi[dbus] ) |
148 |
+" |
149 |
+DEPEND="${COMMON_DEPEND} |
150 |
+ >=dev-util/cmocka-1.1.3[${MULTILIB_USEDEP}] |
151 |
+ net-libs/libtirpc[${MULTILIB_USEDEP}] |
152 |
+ || ( |
153 |
+ net-libs/rpcsvc-proto |
154 |
+ <sys-libs/glibc-2.26[rpc(+)] |
155 |
+ ) |
156 |
+ spotlight? ( dev-libs/glib ) |
157 |
+ test? ( |
158 |
+ $(python_gen_cond_dep "dev-python/subunit[\${PYTHON_USEDEP},${MULTILIB_USEDEP}]" ) |
159 |
+ !system-mitkrb5? ( |
160 |
+ >=net-dns/resolv_wrapper-1.1.4 |
161 |
+ >=net-libs/socket_wrapper-1.1.9 |
162 |
+ >=sys-libs/nss_wrapper-1.1.3 |
163 |
+ >=sys-libs/uid_wrapper-1.2.1 |
164 |
+ ) |
165 |
+ )" |
166 |
+RDEPEND="${COMMON_DEPEND} |
167 |
+ client? ( net-fs/cifs-utils[ads?] ) |
168 |
+ python? ( ${PYTHON_DEPS} ) |
169 |
+ selinux? ( sec-policy/selinux-samba ) |
170 |
+" |
171 |
+BDEPEND="${PYTHON_DEPS} |
172 |
+ app-text/docbook-xsl-stylesheets |
173 |
+ dev-libs/libxslt |
174 |
+ virtual/pkgconfig |
175 |
+" |
176 |
+ |
177 |
+PATCHES=( |
178 |
+ "${FILESDIR}/${PN}-4.4.0-pam.patch" |
179 |
+ "${FILESDIR}/ldb-2.5.2-skip-wav-tevent-check.patch" |
180 |
+ "${FILESDIR}/${PN}-4.15.9-libunwind-automagic.patch" |
181 |
+) |
182 |
+ |
183 |
+#CONFDIR="${FILESDIR}/$(get_version_component_range 1-2)" |
184 |
+CONFDIR="${FILESDIR}/4.4" |
185 |
+ |
186 |
+WAF_BINARY="${S}/buildtools/bin/waf" |
187 |
+ |
188 |
+SHAREDMODS="" |
189 |
+ |
190 |
+pkg_setup() { |
191 |
+ # Package fails to build with distcc |
192 |
+ export DISTCC_DISABLE=1 |
193 |
+ |
194 |
+ python-single-r1_pkg_setup |
195 |
+ |
196 |
+ SHAREDMODS="$(usex snapper '' '!')vfs_snapper" |
197 |
+ if use cluster ; then |
198 |
+ SHAREDMODS+=",idmap_rid,idmap_tdb2,idmap_ad" |
199 |
+ elif use ads ; then |
200 |
+ SHAREDMODS+=",idmap_ad" |
201 |
+ fi |
202 |
+} |
203 |
+ |
204 |
+src_prepare() { |
205 |
+ default |
206 |
+ |
207 |
+ # un-bundle dnspython |
208 |
+ sed -i -e '/"dns.resolver":/d' "${S}"/third_party/wscript || die |
209 |
+ |
210 |
+ # unbundle iso8601 unless tests are enabled |
211 |
+ if ! use test ; then |
212 |
+ sed -i -e '/"iso8601":/d' "${S}"/third_party/wscript || die |
213 |
+ fi |
214 |
+ |
215 |
+ ## ugly hackaround for bug #592502 |
216 |
+ #cp /usr/include/tevent_internal.h "${S}"/lib/tevent/ || die |
217 |
+ |
218 |
+ sed -e 's:<gpgme\.h>:<gpgme/gpgme.h>:' \ |
219 |
+ -i source4/dsdb/samdb/ldb_modules/password_hash.c \ |
220 |
+ || die |
221 |
+ |
222 |
+ # Friggin' WAF shit |
223 |
+ multilib_copy_sources |
224 |
+} |
225 |
+ |
226 |
+multilib_src_configure() { |
227 |
+ # when specifying libs for samba build you must append NONE to the end to |
228 |
+ # stop it automatically including things |
229 |
+ local bundled_libs="NONE" |
230 |
+ if ! use system-heimdal && ! use system-mitkrb5 ; then |
231 |
+ bundled_libs="heimbase,heimntlm,hdb,kdc,krb5,wind,gssapi,hcrypto,hx509,roken,asn1,com_err,NONE" |
232 |
+ fi |
233 |
+ |
234 |
+ local myconf=( |
235 |
+ --enable-fhs |
236 |
+ --sysconfdir="${EPREFIX}/etc" |
237 |
+ --localstatedir="${EPREFIX}/var" |
238 |
+ --with-modulesdir="${EPREFIX}/usr/$(get_libdir)/samba" |
239 |
+ --with-piddir="${EPREFIX}/run/${PN}" |
240 |
+ --bundled-libraries="${bundled_libs}" |
241 |
+ --builtin-libraries=NONE |
242 |
+ --disable-rpath |
243 |
+ --disable-rpath-install |
244 |
+ --nopyc |
245 |
+ --nopyo |
246 |
+ --without-winexe |
247 |
+ --accel-aes=$(usex cpu_flags_x86_aes intelaesni none) |
248 |
+ $(multilib_native_use_with acl acl-support) |
249 |
+ $(multilib_native_usex addc '' '--without-ad-dc') |
250 |
+ $(multilib_native_use_with ads) |
251 |
+ $(multilib_native_use_enable ceph cephfs) |
252 |
+ $(multilib_native_use_with cluster cluster-support) |
253 |
+ $(multilib_native_use_enable cups) |
254 |
+ --without-dmapi |
255 |
+ $(multilib_native_use_with fam) |
256 |
+ $(multilib_native_use_enable glusterfs) |
257 |
+ $(multilib_native_use_with gpg gpgme) |
258 |
+ $(multilib_native_use_with json) |
259 |
+ $(multilib_native_use_enable iprint) |
260 |
+ $(multilib_native_use_with pam) |
261 |
+ $(multilib_native_usex pam "--with-pammodulesdir=${EPREFIX}/$(get_libdir)/security" '') |
262 |
+ $(multilib_native_use_with quota quotas) |
263 |
+ $(multilib_native_use_with regedit) |
264 |
+ $(multilib_native_use_enable spotlight) |
265 |
+ $(multilib_native_use_with syslog) |
266 |
+ $(multilib_native_use_with systemd) |
267 |
+ --systemd-install-services |
268 |
+ --with-systemddir="$(systemd_get_systemunitdir)" |
269 |
+ $(multilib_native_use_with unwind libunwind) |
270 |
+ $(multilib_native_use_with winbind) |
271 |
+ $(multilib_native_usex python '' '--disable-python') |
272 |
+ $(multilib_native_use_enable zeroconf avahi) |
273 |
+ $(multilib_native_usex test '--enable-selftest' '') |
274 |
+ $(usex system-mitkrb5 "--with-system-mitkrb5 $(multilib_native_usex addc --with-experimental-mit-ad-dc '')" '') |
275 |
+ $(use_with debug lttng) |
276 |
+ $(use_with ldap) |
277 |
+ $(use_with profiling-data) |
278 |
+ # bug #683148 |
279 |
+ --jobs 1 |
280 |
+ ) |
281 |
+ |
282 |
+ if multilib_is_native_abi ; then |
283 |
+ myconf+=( --with-shared-modules=${SHAREDMODS} ) |
284 |
+ else |
285 |
+ myconf+=( --with-shared-modules=DEFAULT,!vfs_snapper ) |
286 |
+ fi |
287 |
+ |
288 |
+ PYTHONHASHSEED=1 CPPFLAGS="-I${ESYSROOT}/usr/include/et ${CPPFLAGS}" \ |
289 |
+ waf-utils_src_configure ${myconf[@]} |
290 |
+} |
291 |
+ |
292 |
+multilib_src_compile() { |
293 |
+ PYTHONHASHSEED=1 waf-utils_src_compile |
294 |
+} |
295 |
+ |
296 |
+multilib_src_install() { |
297 |
+ PYTHONHASHSEED=1 waf-utils_src_install |
298 |
+ |
299 |
+ # Make all .so files executable |
300 |
+ find "${ED}" -type f -name "*.so" -exec chmod +x {} + || die |
301 |
+ |
302 |
+ if multilib_is_native_abi ; then |
303 |
+ # install ldap schema for server (bug #491002) |
304 |
+ if use ldap ; then |
305 |
+ insinto /etc/openldap/schema |
306 |
+ doins examples/LDAP/samba.schema |
307 |
+ fi |
308 |
+ |
309 |
+ # create symlink for cups (bug #552310) |
310 |
+ if use cups ; then |
311 |
+ dosym ../../../bin/smbspool \ |
312 |
+ /usr/libexec/cups/backend/smb |
313 |
+ fi |
314 |
+ |
315 |
+ # install example config file |
316 |
+ insinto /etc/samba |
317 |
+ doins examples/smb.conf.default |
318 |
+ |
319 |
+ # Fix paths in example file (#603964) |
320 |
+ sed \ |
321 |
+ -e '/log file =/s@/usr/local/samba/var/@/var/log/samba/@' \ |
322 |
+ -e '/include =/s@/usr/local/samba/lib/@/etc/samba/@' \ |
323 |
+ -e '/path =/s@/usr/local/samba/lib/@/var/lib/samba/@' \ |
324 |
+ -e '/path =/s@/usr/local/samba/@/var/lib/samba/@' \ |
325 |
+ -e '/path =/s@/usr/spool/samba@/var/spool/samba@' \ |
326 |
+ -i "${ED}"/etc/samba/smb.conf.default || die |
327 |
+ |
328 |
+ # Install init script and conf.d file |
329 |
+ newinitd "${CONFDIR}/samba4.initd-r1" samba |
330 |
+ newconfd "${CONFDIR}/samba4.confd" samba |
331 |
+ |
332 |
+ dotmpfiles "${FILESDIR}"/samba.conf |
333 |
+ if ! use addc ; then |
334 |
+ rm "${D}/$(systemd_get_systemunitdir)/samba.service" \ |
335 |
+ || die |
336 |
+ fi |
337 |
+ |
338 |
+ # Preserve functionality for old gentoo-specific unit names |
339 |
+ dosym nmb.service "$(systemd_get_systemunitdir)/nmbd.service" |
340 |
+ dosym smb.service "$(systemd_get_systemunitdir)/smbd.service" |
341 |
+ dosym winbind.service "$(systemd_get_systemunitdir)/winbindd.service" |
342 |
+ fi |
343 |
+ |
344 |
+ if use pam && use winbind ; then |
345 |
+ newpamd "${CONFDIR}/system-auth-winbind.pam" system-auth-winbind |
346 |
+ # bugs #376853 and #590374 |
347 |
+ insinto /etc/security |
348 |
+ doins examples/pam_winbind/pam_winbind.conf |
349 |
+ fi |
350 |
+ |
351 |
+ keepdir /var/cache/samba |
352 |
+ keepdir /var/lib/ctdb |
353 |
+ keepdir /var/lib/samba/{bind-dns,private} |
354 |
+ keepdir /var/lock/samba |
355 |
+ keepdir /var/log/samba |
356 |
+} |
357 |
+ |
358 |
+multilib_src_test() { |
359 |
+ if multilib_is_native_abi ; then |
360 |
+ "${WAF_BINARY}" test || die "test failed" |
361 |
+ fi |
362 |
+} |
363 |
+ |
364 |
+pkg_postinst() { |
365 |
+ tmpfiles_process samba.conf |
366 |
+} |