[gentoo-commits] gentoo-x86 commit in media-sound/chuck: ChangeLog chuck-1.2.1.1.ebuild

[Cedric Krier (cedk)]

cedk        08/03/29 22:35:11

  Modified:             ChangeLog
  Added:                chuck-1.2.1.1.ebuild
  Log:
  Version bump
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.6                  media-sound/chuck/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/chuck/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/chuck/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/chuck/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/chuck/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	23 Aug 2007 22:01:34 -0000	1.5
+++ ChangeLog	29 Mar 2008 22:35:11 -0000	1.6
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/chuck
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/chuck/ChangeLog,v 1.5 2007/08/23 22:01:34 cedk Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/chuck/ChangeLog,v 1.6 2008/03/29 22:35:11 cedk Exp $
+
+*chuck-1.2.1.1 (29 Mar 2008)
+
+  29 Mar 2008; Cédric Krier <cedk@g.o>
+  +files/chuck-1.2.1.1-hid-smc.patch, +chuck-1.2.1.1.ebuild:
+  Version bump
 
 *chuck-1.2.1.0 (23 Aug 2007)
 



1.1                  media-sound/chuck/chuck-1.2.1.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/chuck/chuck-1.2.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/chuck/chuck-1.2.1.1.ebuild?rev=1.1&content-type=text/plain

Index: chuck-1.2.1.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/chuck/chuck-1.2.1.1.ebuild,v 1.1 2008/03/29 22:35:11 cedk Exp $

inherit toolchain-funcs flag-o-matic eutils

DESCRIPTION="Strongly-timed, Concurrent, and On-the-fly
Audio Programming Language"
HOMEPAGE="http://chuck.cs.princeton.edu/release/"
SRC_URI="http://chuck.cs.princeton.edu/release/files/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="oss jack alsa examples"

RDEPEND="jack? ( media-sound/jack-audio-connection-kit )
	alsa? ( >=media-libs/alsa-lib-0.9 )
	media-libs/libsndfile"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex"

pkg_setup() {
	local cnt=0
	use jack && cnt="$((${cnt} + 1))"
	use alsa && cnt="$((${cnt} + 1))"
	use oss && cnt="$((${cnt} + 1))"
	if [[ "${cnt}" -eq 0 ]] ; then
		eerror "One of the following USE flags is needed: jack, alsa or oss"
		die "Please set one audio engine type"
	elif [[ "${cnt}" -ne 1 ]] ; then
		ewarn "You have set ${P} to use multiple audio engine."
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "$FILESDIR/${P}-hid-smc.patch"
}

src_compile() {
	local backend
	if use jack ; then
		backend="jack"
	elif use alsa ; then
		backend="alsa"
	elif use oss ; then
		backend="oss"
	fi
	einfo "Compiling against ${backend}"

	# when compile with athlon or athlon-xp flags
	# chuck crashes on removing a shred with a double free or corruption
	# it happens in Chuck_VM_Stack::shutdown() on the line
	#   SAFE_DELETE_ARRAY( stack );
	replace-cpu-flags athlon athlon-xp i686

	cd "${S}/src"
	emake -f "makefile.${backend}" CC=$(tc-getCC) CXX=$(tc-getCXX) || die "emake failed"
}

src_install() {
	dobin src/chuck

	dodoc AUTHORS DEVELOPER PROGRAMMER QUICKSTART README THANKS TODO VERSIONS
	docinto doc
	dodoc doc/*
	if use examples; then
		insinto /usr/share/doc/${P}/examples
		doins `find examples -type f`
		for dir in `find examples/* -type d`; do
			insinto /usr/share/doc/${P}/$dir
			doins $dir/*
		done
	fi
}



-- 
gentoo-commits@l.g.o mailing list