[gentoo-commits] gentoo-x86 commit in media-libs/mlt: ChangeLog mlt-0.5.0.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    10/02/22 11:05:17

  Modified:             ChangeLog
  Added:                mlt-0.5.0.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc63/cvs/Linux x86_64)

Revision  Changes    Path
1.56                 media-libs/mlt/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mlt/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mlt/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mlt/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/mlt/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	28 Dec 2009 16:50:22 -0000	1.55
+++ ChangeLog	22 Feb 2010 11:05:16 -0000	1.56
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/mlt
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/mlt/ChangeLog,v 1.55 2009/12/28 16:50:22 ssuominen Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/mlt/ChangeLog,v 1.56 2010/02/22 11:05:16 ssuominen Exp $
+
+*mlt-0.5.0 (22 Feb 2010)
+
+  22 Feb 2010; Samuli Suominen <ssuominen@g.o> +mlt-0.5.0.ebuild:
+  Version bump.
 
   28 Dec 2009; Samuli Suominen <ssuominen@g.o> mlt-0.4.6.ebuild,
   mlt-0.4.6-r1.ebuild:



1.1                  media-libs/mlt/mlt-0.5.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mlt/mlt-0.5.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mlt/mlt-0.5.0.ebuild?rev=1.1&content-type=text/plain

Index: mlt-0.5.0.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/mlt/mlt-0.5.0.ebuild,v 1.1 2010/02/22 11:05:16 ssuominen Exp $

EAPI="2"

inherit eutils toolchain-funcs multilib python

DESCRIPTION="An open source multimedia framework, designed and developed for television broadcasting"
HOMEPAGE="http://mlt.sourceforge.net/"
SRC_URI="mirror://sourceforge/mlt/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="compressed-lumas dv debug ffmpeg frei0r gtk jack kde libsamplerate melt
mmx qt4 quicktime sdl sse sse2 vorbis xine xml lua python ruby" # java perl php tcl

RDEPEND="ffmpeg? ( >=media-video/ffmpeg-0.5 )
	dv? ( >=media-libs/libdv-0.104 )
	xml? ( >=dev-libs/libxml2-2.5 )
	vorbis? ( >=media-libs/libvorbis-1.1.2 )
	sdl? ( >=media-libs/libsdl-1.2.10
		 >=media-libs/sdl-image-1.2.4 )
	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
	jack? ( media-sound/jack-audio-connection-kit
		media-libs/ladspa-sdk
		>=dev-libs/libxml2-2.5 )
	frei0r? ( media-plugins/frei0r-plugins )
	gtk? ( x11-libs/gtk+:2
		x11-libs/pango )
	quicktime? ( media-libs/libquicktime )
	xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
	qt4? ( x11-libs/qt-gui:4 )
	!media-libs/mlt++
	lua? ( >=dev-lang/lua-5.1.4-r4 )
	python? ( dev-lang/python )
	ruby? ( dev-lang/ruby )
	"
#	sox? ( media-sound/sox )
#	java? ( >=virtual/jre-1.5 )
#	perl? ( dev-lang/perl )
#	php? ( dev-lang/php )
#	tcl? ( dev-lang/tcl )

SWIG_DEPEND=">=dev-lang/swig-1.3.38"
DEPEND="${RDEPEND}
	compressed-lumas? ( media-gfx/imagemagick )
	lua? ( ${SWIG_DEPEND} dev-util/pkgconfig )
	python? ( ${SWIG_DEPEND} )
	ruby? ( ${SWIG_DEPEND} )
	"
#	java? ( ${SWIG_DEPEND} >=virtual/jdk-1.5 )
#	perl? ( ${SWIG_DEPEND} )
#	php? ( ${SWIG_DEPEND} )
#	tcl? ( ${SWIG_DEPEND} )

src_configure() {
	tc-export CC CXX

	local myconf="--enable-gpl
		--enable-motion-est
		$(use_enable debug)
		$(use_enable dv)
		$(use_enable sse)
		$(use_enable sse2)
		$(use_enable gtk gtk2)
		$(use_enable vorbis)
		$(use_enable sdl)
		$(use_enable jack jackrack)
		$(use_enable ffmpeg avformat)
		$(use_enable frei0r)
		$(use_enable melt)
		$(use_enable libsamplerate resample)
		$(use_enable xml)
		$(use_enable xine)
		$(use_enable kde kdenlive)
		$(use_enable qt4 qimage)
		--disable-sox"
		#$(use_enable sox)  FIXME

	use ffmpeg && myconf="${myconf} --avformat-swscale"

	(use quicktime && use dv) ||  myconf="${myconf} --disable-kino"

	use compressed-lumas && myconf="${myconf} --luma-compress"

	( use x86 || use amd64 ) && \
		myconf="${myconf} $(use_enable mmx)" ||
		myconf="${myconf} --disable-mmx"

	use melt || sed -i -e "s;src/melt;;" Makefile

	# TODO: add swig language bindings
	# see also http://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover

	local swig_lang
	# TODO: java perl php tcl
	for i in lua python ruby ; do
		use $i && swig_lang="${swig_lang} $i"
	done
	[ -z "${swig_lang}" ] && swig_lang="none"

	econf ${myconf} --swig-languages="${swig_lang}"
	sed -i -e s/^OPT/#OPT/ "${S}/config.mak"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS README docs/{TODO,*.txt}

	dodir /usr/share/${PN}
	insinto /usr/share/${PN}
	doins -r demo

	docinto swig

	# Install SWIG bindings
	if use lua; then
		cd "${S}"/src/swig/lua
		exeinto $(pkg-config --variable INSTALL_CMOD lua)
		doexe mlt.so
		dodoc play.lua
	fi

	if use python; then
		python_version
		cd "${S}"/src/swig/python
		insinto /usr/$(get_libdir)/python${PYVER}/site-packages
		doins mlt.py
		exeinto /usr/$(get_libdir)/python${PYVER}/site-packages
		doexe _mlt.so
		dodoc play.py
	fi

	if use ruby; then
		cd "${S}"/src/swig/ruby
		exeinto $(/usr/bin/ruby -r rbconfig -e 'print Config::CONFIG["sitearchdir"]')
		doexe mlt.so
		dodoc play.rb thumbs.rb
	fi
	# TODO: java perl php tcl
}