[gentoo-commits] gentoo-x86 commit in games-board/xboard: ChangeLog xboard-4.4.3.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/04/25 23:30:46

  Modified:             ChangeLog
  Added:                xboard-4.4.3.ebuild
  Log:
  version bump
  (Portage version: 2.1.8.3/cvs/Linux i686)

Revision  Changes    Path
1.30                 games-board/xboard/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-board/xboard/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-board/xboard/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-board/xboard/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	4 Apr 2010 13:35:58 -0000	1.29
+++ ChangeLog	25 Apr 2010 23:30:46 -0000	1.30
@@ -1,6 +1,12 @@
 # ChangeLog for games-board/xboard
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v 1.29 2010/04/04 13:35:58 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/ChangeLog,v 1.30 2010/04/25 23:30:46 mr_bones_ Exp $
+
+*xboard-4.4.3 (25 Apr 2010)
+
+  25 Apr 2010; Michael Sterrett <mr_bones_@g.o> +xboard-4.4.3.ebuild,
+  +files/xboard-4.4.3-gentoo.patch:
+  version bump
 
   04 Apr 2010; Markos Chandras <hwoarang@g.o> xboard-4.4.1.ebuild:
   Revert my previous commit as this app fails to run properly



1.1                  games-board/xboard/xboard-4.4.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-board/xboard/xboard-4.4.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-board/xboard/xboard-4.4.3.ebuild?rev=1.1&content-type=text/plain

Index: xboard-4.4.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-board/xboard/xboard-4.4.3.ebuild,v 1.1 2010/04/25 23:30:46 mr_bones_ Exp $

EAPI=2
inherit autotools eutils games

DESCRIPTION="GUI for gnuchess and for internet chess servers"
HOMEPAGE="http://www.gnu.org/software/xboard/"
SRC_URI="mirror://gnu/xboard/${P}.tar.gz
	mirror://gentoo/${PN}.png
	http://dev.gentoo.org/~wolf31o2/sources/dump/${PN}.png"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="Xaw3d +default-font zippy"
RESTRICT="test" #124112

RDEPEND="Xaw3d? ( x11-libs/Xaw3d )
	x11-libs/libXpm
	x11-libs/libXaw
	x11-libs/libSM
	x11-libs/libX11
	x11-libs/libXt
	x11-libs/libXmu
	x11-libs/libXext
	x11-libs/libICE
	default-font? ( media-fonts/font-adobe-100dpi )"
DEPEND="${RDEPEND}
	x11-proto/xproto"

src_unpack() {
	unpack ${P}.tar.gz
}

src_prepare() {
	epatch "${FILESDIR}"/${P}*
	sed -i \
		-e '/icons/s:\$(datadir):/usr/share:' \
		Makefile.am \
		|| die 'sed failed'
	eautoreconf
}

src_configure() {
	egamesconf \
		--disable-dependency-tracking \
		$(use_with Xaw3d) \
		$(use_enable zippy)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS COPYRIGHT ChangeLog NEWS README TODO ics-parsing.txt
	use zippy && dodoc zippy.README
	dohtml FAQ.html
	doicon "${DISTDIR}"/xboard.png
	make_desktop_entry ${PN} "Xboard (Chess)"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	elog "No chess engines are emerged by default! If you want a chess engine"
	elog "to play with, you can emerge gnuchess or crafty."
	elog "Read xboard FAQ for information."
	if ! use default-font ; then
		ewarn "Read the xboard(6) man page for specifying the font for xboard to use."
	fi
}