[gentoo-commits] repo/gentoo:master commit in: media-sound/ardour/

[Miroslav Šulc]

commit:     d941a57f9a26a39743ad4f610cf5cbb6364ca057
Author:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
AuthorDate: Sat Sep 12 10:20:02 2020 +0000
Commit:     Miroslav Šulc <fordfrog <AT> gentoo <DOT> org>
CommitDate: Sat Sep 12 10:20:14 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d941a57f

media-sound/ardour: bump to 6.3

Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: Miroslav Šulc <fordfrog <AT> gentoo.org>

 media-sound/ardour/Manifest          |   1 +
 media-sound/ardour/ardour-6.3.ebuild | 147 +++++++++++++++++++++++++++++++++++
 2 files changed, 148 insertions(+)

diff --git a/media-sound/ardour/Manifest b/media-sound/ardour/Manifest
index 4a3220d8015..c97770ccc71 100644
--- a/media-sound/ardour/Manifest
+++ b/media-sound/ardour/Manifest
@@ -1 +1,2 @@
 DIST Ardour-6.2.0.tar.bz2 11042230 BLAKE2B 7039b0ea7a8550d5372ce795bc978f3d6129828cc6e93d98ce8ba74c6fab3db0e4343142d75e9684f9dffdaebf1ee634f8ab0165f510eb658d32d890f6417b63 SHA512 d4c20968738ec2fef382fc1109f1b17560863c4eb0f7cf5c42b79e9a610916e57e6c01985a2ca2a66b8647e99c10bd98c16e05eb81a7811e73e482f7af11e4a8
+DIST Ardour-6.3.0.tar.bz2 11863993 BLAKE2B 6b50d0e4b1effc8893cf555098f51458920db6c26a2db8f3c75a5eed56a4d8dafa1565717da2a75577f3068cbce4777f502eaf96f275ed3fd042c6388b842487 SHA512 ce1a6f1b92adb2df0c8863ead9b5f3d8c62a810b224262bda75bca4c09b11826266794260c63bb40ec8d75fbba6fb746a0dff4526311ab1035a3a8ebf0de2dd0

diff --git a/media-sound/ardour/ardour-6.3.ebuild b/media-sound/ardour/ardour-6.3.ebuild
new file mode 100644
index 00000000000..6bd303b0e46
--- /dev/null
+++ b/media-sound/ardour/ardour-6.3.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+PYTHON_REQ_USE='threads(+)'
+PLOCALES="cs de el en_GB es eu fr it ja nn pl pt pt_PT ru sv zh"
+inherit eutils toolchain-funcs flag-o-matic l10n python-any-r1 waf-utils
+
+DESCRIPTION="Digital Audio Workstation"
+HOMEPAGE="http://ardour.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.ardour.org/ardour/ardour.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/Ardour-${PV}.0.tar.bz2"
+	S="${WORKDIR}/Ardour-${PV}.0"
+fi
+
+LICENSE="GPL-2"
+SLOT="6"
+IUSE="altivec doc jack nls phonehome cpu_flags_x86_sse cpu_flags_x86_mmx cpu_flags_x86_3dnow"
+
+RDEPEND="
+	>=dev-cpp/glibmm-2.32.0
+	>=dev-cpp/gtkmm-2.16:2.4
+	>=dev-cpp/libgnomecanvasmm-2.26:2.6
+	dev-libs/boost:=
+	>=dev-libs/glib-2.10.1:2
+	dev-libs/libsigc++:2
+	>=dev-libs/libxml2-2.6:2
+	dev-libs/libxslt
+	>=gnome-base/libgnomecanvas-2
+	media-libs/alsa-lib
+	media-libs/aubio
+	media-libs/flac
+	media-libs/freetype:2
+	media-libs/libart_lgpl
+	media-libs/liblo
+	>=media-libs/liblrdf-0.4.0-r20
+	>=media-libs/libsamplerate-0.1
+	>=media-libs/libsndfile-1.0.18
+	>=media-libs/libsoundtouch-1.6.0
+	media-libs/raptor:2
+	>=media-libs/rubberband-1.6.0
+	>=media-libs/taglib-1.7
+	media-libs/vamp-plugin-sdk
+	net-misc/curl
+	sys-libs/readline:0=
+	sci-libs/fftw:3.0[threads]
+	virtual/libusb:1
+	x11-libs/cairo
+	>=x11-libs/gtk+-2.8.1:2
+	x11-libs/pango
+	jack? ( virtual/jack )
+	media-libs/lilv
+	media-libs/sratom
+	dev-libs/sord
+	>=media-libs/suil-0.6.10
+	>=media-libs/lv2-1.4.0"
+#	!bundled-libs? ( media-sound/fluidsynth ) at leat libltc is missing to be able to unbundle...
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	jack? ( virtual/jack )
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )"
+
+pkg_pretend() {
+	[[ $(tc-getLD) == *gold* ]] && (has_version sci-libs/fftw[openmp] || has_version sci-libs/fftw[threads]) && \
+		ewarn "Linking with gold linker might produce broken executable, see bug #733972"
+}
+
+pkg_setup() {
+	if has_version \>=dev-libs/libsigc++-2.6 ; then
+		append-cxxflags -std=c++11
+	fi
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed 's/'full-optimization\'\ :\ \\[.*'/'full-optimization\'\ :\ \'\','/' -i "${S}"/wscript || die
+	MARCH=$(get-flag march)
+	OPTFLAGS=""
+	if use cpu_flags_x86_sse; then
+		if [[ ${MARCH} == "i686" ]] || [[ ${MARCH} == "i486" ]]; then
+			elog "You enabled sse but use an march that does not support sse!"
+			elog "We add -msse to the flags now, but please consider switching your march in make.conf!"
+		fi
+		OPTFLAGS="sse"
+	fi
+	if use cpu_flags_x86_mmx; then
+		if [[ ${MARCH} == "i486" ]]; then
+		    elog "You enabled mmx with i486 set as march! You have been warned!"
+		fi
+		OPTFLAGS="${OPTFLAGS} mmx"
+	fi
+	if use cpu_flags_x86_3dnow; then
+		OPTFLAGS="${OPTFLAGS} 3dnow"
+	fi
+	sed 's/flag_line\ =\ o.*/flag_line\ =\ \": '"${OPTFLAGS}"' just some place holders\"/' \
+		-i "${S}"/wscript || die
+	sed 's/cpu\ ==\ .*/cpu\ ==\ "LeaveMarchAsIs":/' -i "${S}"/wscript || die
+	append-flags "-lboost_system"
+	python_fix_shebang "${S}"/wscript
+	python_fix_shebang "${S}"/waf
+	my_lcmsg() {
+		rm -f {gtk2_ardour,gtk2_ardour/appdata,libs/ardour,libs/gtkmm2ext}/po/${1}.po
+	}
+	l10n_for_each_disabled_locale_do my_lcmsg
+}
+
+src_configure() {
+	tc-export CC CXX
+	mkdir -p "${D}"
+	waf-utils_src_configure \
+		--destdir="${D}" \
+		--configdir=/etc \
+		--optimize \
+		$(usex doc "--docs" '') \
+		$({ use altivec || use cpu_flags_x86_sse; } && echo "--fpu-optimization" || echo "--no-fpu-optimization") \
+		$(usex jack "--with-backends=alsa,jack" "--with-backends=alsa  --libjack=weak") \
+		$(usex phonehome "--phone-home" "--no-phone-home") \
+		$(usex nls "--nls" "--no-nls")
+#not possible right now		--use-external-libs
+}
+src_compile() {
+	waf-utils_src_compile
+	use nls && waf-utils_src_compile i18n
+}
+src_install() {
+	waf-utils_src_install
+	mv ${PN}.1 ${PN}${SLOT}.1
+	doman ${PN}${SLOT}.1
+	newicon "${S}/gtk2_ardour/resources/Ardour-icon_48px.png" ${PN}${SLOT}.png
+	make_desktop_entry ardour6 ardour6 ardour6 AudioVideo
+}
+
+pkg_postinst() {
+	elog "Please do _not_ report problems with the package to ${PN} upstream."
+	elog "If you think you've found a bug, check the upstream binary package"
+	elog "before you report anything to upstream."
+}