[gentoo-commits] gentoo-x86 commit in dev-java/avalon-logkit: ChangeLog avalon-logkit-1.2-r3.ebuild avalon-logkit-2.1-r2.ebuild

[Alistair Bush (ali_bush)]

ali_bush    07/11/20 05:23:04

  Modified:             ChangeLog
  Added:                avalon-logkit-1.2-r3.ebuild
                        avalon-logkit-2.1-r2.ebuild
  Log:
  Bumping to support javamail virtual.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.54                 dev-java/avalon-logkit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/ChangeLog?rev=1.54&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/ChangeLog?rev=1.54&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/ChangeLog?r1=1.53&r2=1.54

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/avalon-logkit/ChangeLog,v
retrieving revision 1.53
retrieving revision 1.54
diff -u -r1.53 -r1.54
--- ChangeLog	21 Aug 2007 19:29:50 -0000	1.53
+++ ChangeLog	20 Nov 2007 05:23:03 -0000	1.54
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/avalon-logkit
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/avalon-logkit/ChangeLog,v 1.53 2007/08/21 19:29:50 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/avalon-logkit/ChangeLog,v 1.54 2007/11/20 05:23:03 ali_bush Exp $
+
+*avalon-logkit-2.1-r2 (20 Nov 2007)
+*avalon-logkit-1.2-r3 (20 Nov 2007)
+
+  20 Nov 2007; <alistair@g.o> +avalon-logkit-1.2-r3.ebuild,
+  +avalon-logkit-2.1-r2.ebuild:
+  Bumping to support javamail virtual.
 
   21 Aug 2007; Christian Faulhammer <opfer@g.o>
   avalon-logkit-2.1-r1.ebuild:



1.1                  dev-java/avalon-logkit/avalon-logkit-1.2-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-1.2-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-1.2-r3.ebuild?rev=1.1&content-type=text/plain

Index: avalon-logkit-1.2-r3.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-1.2-r3.ebuild,v 1.1 2007/11/20 05:23:03 ali_bush Exp $

JAVA_PKG_IUSE="doc javamail jms source"
inherit java-pkg-2 java-ant-2

DESCRIPTION="An easy-to-use Java logging toolkit designed for secure, performance-oriented logging."
HOMEPAGE="http://avalon.apache.org/"
SRC_URI="mirror://apache/avalon/logkit/v${PV}/LogKit-${PV}-src.tar.gz"
COMMON_DEP="
	javamail? (
		dev-java/sun-jaf
		java-virtuals/javamail
	)
	jms? ( dev-java/sun-jms )"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"

# Doesn't like 1.6 changes to JDBC
DEPEND="|| (
		=virtual/jdk-1.5*
		=virtual/jdk-1.4*
	)
	${COMMON_DEP}"

LICENSE="Apache-1.1"
SLOT="1.2"
KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE=""

S="${WORKDIR}/LogKit-${PV}"

src_unpack() {
	unpack ${A}
	rm -rf "${S}/src/test/org"
	cd "${S}/lib"

	if use javamail; then
		java-pkg_jar-from sun-jaf
		java-pkg_jar-from --virtual javamail
	fi

	use jms && java-pkg_jar-from sun-jms

}

src_compile() {
	# not generating api docs because we would
	# need avalon-site otherwise
	eant jar
}

src_install() {
	java-pkg_dojar "${S}/build/lib/*.jar"
	use doc && dohtml -r docs/*
	use source && java-pkg_dosrc src/java/*
}



1.1                  dev-java/avalon-logkit/avalon-logkit-2.1-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-2.1-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-2.1-r2.ebuild?rev=1.1&content-type=text/plain

Index: avalon-logkit-2.1-r2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/avalon-logkit/avalon-logkit-2.1-r2.ebuild,v 1.1 2007/11/20 05:23:03 ali_bush Exp $

JAVA_PKG_IUSE="doc source test"
inherit java-pkg-2 java-ant-2

DESCRIPTION="Easy-to-use Java logging toolkit"
HOMEPAGE="http://avalon.apache.org/"
SRC_URI="mirror://apache/excalibur/excalibur-logkit/source/${P}-src.tar.gz"

KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
LICENSE="Apache-2.0"
SLOT="2.0"
IUSE=""

COMMON_DEP="
	dev-java/log4j
	dev-java/sun-jms
	java-virtuals/javamail
	=dev-java/servletapi-2.4*"

RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"
# Doesn't like 1.6 changes to JDBC
DEPEND="|| (
		=virtual/jdk-1.5*
		=virtual/jdk-1.4*
	)
	test? (
		=dev-java/junit-3*
		dev-java/ant-junit
	)
	${COMMON_DEP}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	java-ant_ignore-system-classes

	java-ant_xml-rewrite -f build.xml \
		-c -e available -a classpathref -v 'build.classpath' || die

	mkdir -p target/lib || die
	cd target/lib || die
	java-pkg_jar-from servletapi-2.4
	java-pkg_jar-from sun-jms
	java-pkg_jar-from --virtual javamail
	java-pkg_jar-from log4j
	java-pkg_filter-compiler jikes
}

src_test() {
	java-pkg_jar-from --into target/lib junit
	ANT_TASKS="ant-junit" eant test
}

src_install() {
	java-pkg_newjar target/${P}.jar
	use doc && java-pkg_dojavadoc dist/docs/api
	use source && java-pkg_dosrc src/java/*
}



-- 
gentoo-commits@g.o mailing list