[gentoo-commits] gentoo-x86 commit in media-tv/ivtv: ChangeLog ivtv-1.1.0-r1.ebuild ivtv-1.1.0.ebuild

[Doug Goldstein (cardoe)]

cardoe      08/07/03 16:22:25

  Modified:             ChangeLog
  Added:                ivtv-1.1.0-r1.ebuild
  Removed:              ivtv-1.1.0.ebuild
  Log:
  fix the includes for the linux/ivtv.h header
  (Portage version: 2.2_rc1/cvs/Linux 2.6.25-gentoo-r5 x86_64)

Revision  Changes    Path
1.106                media-tv/ivtv/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-tv/ivtv/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-tv/ivtv/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-tv/ivtv/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-tv/ivtv/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	30 Jun 2008 19:38:41 -0000	1.105
+++ ChangeLog	3 Jul 2008 16:22:24 -0000	1.106
@@ -1,6 +1,13 @@
 # ChangeLog for media-tv/ivtv
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-tv/ivtv/ChangeLog,v 1.105 2008/06/30 19:38:41 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-tv/ivtv/ChangeLog,v 1.106 2008/07/03 16:22:24 cardoe Exp $
+
+*ivtv-1.1.0-r1 (03 Jul 2008)
+
+  03 Jul 2008; Doug Goldstein <cardoe@g.o>
+  +files/ivtv-1.1.0-headers.patch, -ivtv-1.1.0.ebuild,
+  +ivtv-1.1.0-r1.ebuild:
+  fix the includes for the linux/ivtv.h header
 
   30 Jun 2008; Doug Goldstein <cardoe@g.o>
   +files/ivtv-1.2.0-v4l2-dbg-include.patch, ivtv-1.2.0.ebuild:



1.1                  media-tv/ivtv/ivtv-1.1.0-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-tv/ivtv/ivtv-1.1.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-tv/ivtv/ivtv-1.1.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: ivtv-1.1.0-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-tv/ivtv/ivtv-1.1.0-r1.ebuild,v 1.1 2008/07/03 16:22:24 cardoe Exp $

inherit eutils linux-mod

DESCRIPTION="ivtv driver for Hauppauge PVR PCI cards"
HOMEPAGE="http://www.ivtvdriver.org"
SRC_URI="http://dl.ivtvdriver.org/ivtv/archive/1.1.x/${P}.tar.gz"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="perl"
RDEPEND=">=sys-fs/udev-103"
DEPEND="app-arch/unzip"
PDEPEND="=media-tv/pvr-firmware-20070217
	perl? (
		dev-perl/Video-Frequencies
		dev-perl/Video-ivtv
		dev-perl/Config-IniFiles
		virtual/perl-Getopt-Long
		dev-perl/perl-tk )"

pkg_setup() {

	MODULE_NAMES="saa717x(extra:${S}/i2c-drivers)"
	BUILD_TARGETS="all"
	CONFIG_CHECK="EXPERIMENTAL KMOD HAS_IOMEM FW_LOADER I2C I2C_ALGOBIT
		VIDEO_DEV VIDEO_CAPTURE_DRIVERS VIDEO_V4L1 VIDEO_V4L2
		!VIDEO_HELPER_CHIPS_AUTO VIDEO_IVTV"

	if ! ( kernel_is 2 6 24 ); then
		eerror "Each IVTV driver branch will only work with a specific"
		eerror "linux kernel branch."
		eerror ""
		eerror "You will need to either:"
		eerror "a) emerge a different kernel"
		eerror "b) emerge a different ivtv driver"
		eerror ""
		eerror "See http://ivtvdriver.org/ for more information"
		die "This only works on 2.6.24 kernels"
	fi

	ewarn ""
	ewarn "Make sure that your I2C and V4L kernel drivers are loaded as"
	ewarn "modules, and not compiled into the kernel, or IVTV will not"
	ewarn "work."
	ewarn ""

	linux-mod_pkg_setup

	BUILD_PARAMS="KDIR=${KV_DIR}"
}

src_unpack() {
	unpack ${A}

	cd ${S}

	epatch "${FILESDIR}"/${P}-headers.patch
}

src_compile() {
	linux-mod_src_compile || die "failed to build driver"

	cd "${S}/utils"
	emake INCDIR="${KV_DIR}/include" || die "failed to build utils "
}

src_install() {
	cd "${S}/utils"
	make DESTDIR="${D}" PREFIX="/usr" install || die "failed to install utils"
	use perl && dobin perl/*.pl

	cd "${S}"
	dodoc README* doc/* ChangeLog*
	use perl && dodoc utils/perl/README.ptune

	linux-mod_src_install || die "failed to install modules"
}

pkg_postinst() {

	linux-mod_pkg_postinst

	elog ""
	elog "This version of the IVTV driver supports the following hardware:"
	elog "Hauppauge WinTV PVR-250"
	elog "Hauppauge WinTV PVR-350"
	elog "Hauppauge WinTV PVR-150"
	elog "Hauppauge WinTV PVR-500"
	elog "AVerMedia M179"
	elog "Yuan MPG600/Kuroutoshikou iTVC16-STVLP"
	elog "Yuan MPG160/Kuroutoshikou iTVC15-STVLP"
	elog "Yuan PG600/DiamondMM PVR-550 (CX Falcon 2)"
	elog "Adaptec AVC-2410"
	elog "Adaptec AVC-2010"
	elog "Nagase Transgear 5000TV"
	elog "AOpen VA2000MAX-STN6"
	elog "Yuan MPG600GR/Kuroutoshikou CX23416GYC-STVLP"
	elog "I/O Data GV-MVP/RX"
	elog "I/O Data GV-MVP/RX2E"
	elog "Gotview PCI DVD (preliminary support only)"
	elog "Gotview PCI DVD2 Deluxe"
	elog "Yuan MPC622"
	elog ""
	ewarn ""
	ewarn "IMPORTANT: In case of problems first read this page:"
	ewarn "http://www.ivtvdriver.org/index.php/Troubleshooting"
	ewarn ""
	ewarn "If any of these conditions match your setup, you may want to look at the"
	ewarn "README in /usr/share/doc/${PF}/"
	ewarn ""
	ewarn " - Using MythTV, a PVR-350 and the ivtvfb module"
	ewarn " - Using the ivtv X driver and the ivtvfb module"
	ewarn " - You want to manually build ivtv against v4l-dvb"
	ewarn ""
	ewarn "Also, the ivtv package comes with lots of documentation regarding setup,"
	ewarn "proper use and debugging utilities."
	ewarn "They are also located in /usr/share/doc/${PF}/"
	ewarn ""
	ewarn "For more information, see the IVTV driver homepage at:"
	ewarn "http://www.ivtvdriver.org/"
}



-- 
gentoo-commits@l.g.o mailing list