[gentoo-commits] repo/proj/guru:dev commit in: gui-libs/gtksourceview/

[Anna Vyalkova]

commit:     f120036470fea3f6b36a83d6be6fd1175aa50dc6
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Fri Feb 18 21:30:36 2022 +0000
Commit:     Anna Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
CommitDate: Sun Feb 20 19:01:47 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=f1200364

gui-libs/gtksourceview: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 gui-libs/gtksourceview/Manifest                   |  1 +
 gui-libs/gtksourceview/gtksourceview-5.2.0.ebuild | 64 +++++++++++++++++++++++
 gui-libs/gtksourceview/metadata.xml               | 20 +++++++
 3 files changed, 85 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
new file mode 100644
index 000000000..0716554aa
--- /dev/null
+++ b/gui-libs/gtksourceview/Manifest
@@ -0,0 +1 @@
+DIST gtksourceview-5.2.0.tar.xz 1206200 BLAKE2B e681c3c1e1c275c237ac77b907b8f75af66b5724eb15a9d926b47b20aa2bb3a2895cca674ffcafbb9f58bb40ac78d4145e87759b00c73f6953501b1134d4858a SHA512 0d71b0340b11b3aadfff662abbaa8606cda696c256855201e559b144b124d6e7c87aee5ea1407928f549b0a5e8480c669403fe73ad76520c2214635a1a31bf52

diff --git a/gui-libs/gtksourceview/gtksourceview-5.2.0.ebuild b/gui-libs/gtksourceview/gtksourceview-5.2.0.ebuild
new file mode 100644
index 000000000..78194f89f
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.2.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.52"
+inherit gnome.org meson vala virtualx
+
+DESCRIPTION="GTK 4 syntax highlighting widget"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gtksourceview"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+IUSE="gtk-doc +introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/libpcre2:=
+	dev-libs/libxml2:2
+	gui-libs/gtk:4
+	media-libs/fontconfig
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	introspection? ( dev-libs/gobject-introspection:= )
+
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3
+	)
+	vala? ( $(vala_depend) )
+"
+
+DOCS=( AUTHORS HACKING NEWS README.{md,win32} )
+
+src_prepare() {
+	use vala && vala_src_prepare
+	default
+
+	# deselect failing test
+	sed "/test-regex/d" -i testsuite/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dsysprof=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}

diff --git a/gui-libs/gtksourceview/metadata.xml b/gui-libs/gtksourceview/metadata.xml
new file mode 100644
index 000000000..2e04ea776
--- /dev/null
+++ b/gui-libs/gtksourceview/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+<maintainer type="person">
+	<email>cyber+gentoo@×××××.in</email>
+	<name>Anna</name>
+</maintainer>
+<upstream>
+	<doc>https://gnome.pages.gitlab.gnome.org/gtksourceview/gtksourceview5/</doc>
+	<changelog>https://gitlab.gnome.org/GNOME/gtksourceview/-/raw/master/NEWS</changelog>
+	<bugs-to>https://gitlab.gnome.org/GNOME/gtksourceview/-/issues</bugs-to>
+</upstream>
+<longdescription>
+GtkSourceView is a GNOME library that extends GtkTextView, the standard GTK+
+widget for multiline text editing. GtkSourceView adds support for syntax
+highlighting, undo/redo, file loading and saving, search and replace, a
+completion system, printing, displaying line numbers, and other features typical
+of a source code editor.
+</longdescription>
+</pkgmetadata>