[gentoo-commits] repo/gentoo:master commit in: dev-python/bpython/

[Andrey Grozin]

commit:     ffc428e971ef22c54efef7d2d792c5d6faae8252
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Thu Apr  4 13:20:32 2019 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Thu Apr  4 13:21:11 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ffc428e9

dev-python/bpython: bump to 0.18

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Andrey Grozin <grozin <AT> gentoo.org>

 dev-python/bpython/Manifest            |  1 +
 dev-python/bpython/bpython-0.18.ebuild | 57 ++++++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/dev-python/bpython/Manifest b/dev-python/bpython/Manifest
index 7746ce02c60..befb2be97ec 100644
--- a/dev-python/bpython/Manifest
+++ b/dev-python/bpython/Manifest
@@ -1 +1,2 @@
 DIST bpython-0.17.1.tar.gz 213638 BLAKE2B 42530a38f8cf714a0415957a46374b83ad14dfab89a76317507763c2f83b3dbc8f71c7cc967ec353fabd38b6631130d34df99c0d53f3728fa2390d4a6f64b25d SHA512 5b5e861646df90510db75520dff9533b71501d35b7af1d152adf2c929b171fa6a2b1c0a6b7eda0311f9315703db161c6a78698a6cd434e5321464d6d1c033e4e
+DIST bpython-0.18.tar.gz 213321 BLAKE2B 476c18fbec1d4ef3c5e206e7586b0e982656160474b64ceaecf5b49f560115af0e51d964553aad25bc765f7b431bc4f062581f9f30c0cb2e8da51cdbf2bca5ca SHA512 760143c286e686d4b8d706e38f3b2d2e7c865f960fa8d828ec08a7d0dd198bfa09686ab3c4b27ea365400d60c45b69a3c03ee726879a8825cc91af2a75d28dab

diff --git a/dev-python/bpython/bpython-0.18.ebuild b/dev-python/bpython/bpython-0.18.ebuild
new file mode 100644
index 00000000000..f93dc731b5a
--- /dev/null
+++ b/dev-python/bpython/bpython-0.18.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
+HOMEPAGE="https://www.bpython-interpreter.org/ https://github.com/bpython/bpython https://pypi.org/project/bpython/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/curtsies-0.2.11[${PYTHON_USEDEP}]
+	dev-python/greenlet[${PYTHON_USEDEP}]
+	dev-python/jedi[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	dev-python/urwid[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( AUTHORS CHANGELOG sample.theme light.theme )
+
+# Req'd for clean build by each impl
+DISTUTILS_IN_SOURCE_BUILD=1
+
+RESTRICT="test" #659110
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c doc/sphinx/source/ \
+			doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
+	fi
+}
+
+python_test() {
+	pushd build/lib > /dev/null
+	"${PYTHON}" -m unittest discover || die
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
+	distutils-r1_python_install_all
+}