[gentoo-commits] gentoo-x86 commit in sys-apps/util-linux: ChangeLog util-linux-2.16.1.ebuild

[Mike Frysinger (vapier)]

vapier      09/09/07 13:41:14

  Modified:             ChangeLog
  Added:                util-linux-2.16.1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc40/cvs/Linux x86_64)

Revision  Changes    Path
1.276                sys-apps/util-linux/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.276&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.276&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/ChangeLog?r1=1.275&r2=1.276

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v
retrieving revision 1.275
retrieving revision 1.276
diff -u -r1.275 -r1.276
--- ChangeLog	16 Aug 2009 18:33:27 -0000	1.275
+++ ChangeLog	7 Sep 2009 13:41:14 -0000	1.276
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.275 2009/08/16 18:33:27 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.276 2009/09/07 13:41:14 vapier Exp $
+
+*util-linux-2.16.1 (07 Sep 2009)
+
+  07 Sep 2009; Mike Frysinger <vapier@g.o> +util-linux-2.16.1.ebuild:
+  Version bump.
 
 *util-linux-2.16-r1 (16 Aug 2009)
 



1.1                  sys-apps/util-linux/util-linux-2.16.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/util-linux-2.16.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/util-linux/util-linux-2.16.1.ebuild?rev=1.1&content-type=text/plain

Index: util-linux-2.16.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.16.1.ebuild,v 1.1 2009/09/07 13:41:14 vapier Exp $

EAPI="2"

EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux-ng/util-linux-ng.git"
inherit eutils toolchain-funcs
[[ ${PV} == "9999" ]] && inherit git autotools

MY_PV=${PV/_/-}
MY_P=${PN}-ng-${MY_PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Various useful Linux utilities"
HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux-ng/"
if [[ ${PV} == "9999" ]] ; then
	SRC_URI=""
	KEYWORDS=""
else
	SRC_URI="mirror://kernel/linux/utils/util-linux-ng/v${PV:0:4}/${MY_P}.tar.bz2
		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.16-20090725.diff.bz2 )"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="crypt loop-aes nls old-linux selinux slang uclibc unicode"

RDEPEND="!sys-process/schedutils
	!sys-apps/setarch
	>=sys-libs/ncurses-5.2-r2
	!<sys-libs/e2fsprogs-libs-1.41.8
	!<sys-fs/e2fsprogs-1.41.8
	selinux? ( sys-libs/libselinux )
	slang? ( sys-libs/slang )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/os-headers"

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		autopoint --force
		eautoreconf
	else
		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-*.diff
	fi
	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
}

src_configure() {
	econf \
		$(use_enable nls) \
		--enable-agetty \
		--enable-cramfs \
		$(use_enable old-linux elvtune) \
		--disable-init \
		--disable-kill \
		--disable-last \
		--disable-mesg \
		--enable-partx \
		--enable-raw \
		--enable-rdev \
		--enable-rename \
		--disable-reset \
		--disable-login-utils \
		--enable-schedutils \
		--disable-wall \
		--enable-write \
		--without-pam \
		$(use unicode || echo --with-ncurses) \
		$(use_with selinux) \
		$(use_with slang)
}

src_install() {
	emake install DESTDIR="${D}" || die "install failed"
	dodoc AUTHORS NEWS README* TODO docs/*

	# need the libs in /
	gen_usr_ldscript -a blkid uuid
	# e2fsprogs-libs didnt install .la files, and .pc work fine
	rm -f "${D}"/usr/$(get_libdir)/*.la

	if use crypt ; then
		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
	fi
}