[gentoo-commits] gentoo-x86 commit in net-proxy/ziproxy: ChangeLog ziproxy-2.3.0.ebuild

[Stefan Briesenick (sbriesen)]

sbriesen    07/10/05 23:08:24

  Modified:             ChangeLog
  Added:                ziproxy-2.3.0.ebuild
  Log:
  version bump.
  (Portage version: 2.1.3.11)

Revision  Changes    Path
1.11                 net-proxy/ziproxy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	17 Jun 2007 16:22:12 -0000	1.10
+++ ChangeLog	5 Oct 2007 23:08:23 -0000	1.11
@@ -1,6 +1,13 @@
 # ChangeLog for net-proxy/ziproxy
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v 1.10 2007/06/17 16:22:12 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ChangeLog,v 1.11 2007/10/05 23:08:23 sbriesen Exp $
+
+*ziproxy-2.3.0 (05 Oct 2007)
+
+  05 Oct 2007; Stefan Briesenick <sbriesen@g.o>
+  +files/ziproxy-2.3.0.diff, +files/ziproxy-2.3.confd,
+  +files/ziproxy-2.3.initd, +ziproxy-2.3.0.ebuild:
+  version bump.
 
   17 Jun 2007; Alin Năstac <mrness@g.o> -files/ziproxy-2.1.confd,
   -files/ziproxy-2.1.initd, -ziproxy-2.1.1.ebuild:



1.1                  net-proxy/ziproxy/ziproxy-2.3.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ziproxy-2.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/ziproxy/ziproxy-2.3.0.ebuild?rev=1.1&content-type=text/plain

Index: ziproxy-2.3.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/ziproxy/ziproxy-2.3.0.ebuild,v 1.1 2007/10/05 23:08:23 sbriesen Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit eutils

DESCRIPTION="A forwarding, non-caching, compressing web proxy server"
HOMEPAGE="http://ziproxy.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="jpeg2k xinetd"

DEPEND="dev-libs/confuse
	media-libs/giflib
	media-libs/libpng
	media-libs/jpeg
	sys-libs/zlib
	jpeg2k? ( media-libs/jasper )
	xinetd? ( virtual/inetd )"

pkg_setup() {
	enewgroup ziproxy
	enewuser ziproxy -1 -1 -1 ziproxy
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	# fix some compile warnings
	epatch "${FILESDIR}/${P}.diff"

	# fix sample config file
	sed -i -e "s:/usr/local/ziproxy/\(ziproxy.passwd\):/etc/\1:g" \
		-e "s:/var/ziproxy/:/var/lib/ziproxy/:g" etc/ziproxy.conf

	# fix sample xinetd config
	sed -i -e "s:/usr/bin/:/usr/sbin/:g" \
		-e "s:\(.*port.*\):\1\n\ttype\t\t\t= UNLISTED:g" \
		-e "s:root:ziproxy:g" etc/xinetd.d/ziproxy
}

src_compile() {
	local myconf="--enable-shared-confuse --with-cfgfile=/etc/ziproxy.conf" # --enable-testprogs
	use jpeg2k && myconf="${myconf} --with-jasper"  # use_with doesn't work
	econf ${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"

	dodir /usr/sbin
	mv -f "${D}usr/bin/ziproxy" "${D}usr/sbin/ziproxy"

	newbin stats.awk ${PN}_stats.awk
	dobin src/tools/ziproxy_genhtml_stats.sh

	newinitd "${FILESDIR}/${PN}-${PV%.*}.initd" ${PN}
	newconfd "${FILESDIR}/${PN}-${PV%.*}.confd" ${PN}

	dodoc ChangeLog CREDITS README README.tools
	use jpeg2k && dodoc JPEG2000.txt

	insinto /etc
	doins etc/ziproxy.conf

	insinto /var/lib/ziproxy/error
	doins var/ziproxy/error/*.html

	if use xinetd; then
		insinto /etc/xinetd.d
		doins etc/xinetd.d/ziproxy
	fi

	diropts -m0750 -o ziproxy -g ziproxy
	keepdir /var/log/ziproxy
}



-- 
gentoo-commits@g.o mailing list