[gentoo-commits] gentoo-x86 commit in dev-util/debhelper: ChangeLog debhelper-9.20120528.ebuild

[Jeroen Roovers (jer)]

jer         12/05/29 07:37:39

  Modified:             ChangeLog
  Added:                debhelper-9.20120528.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha108/cvs/Linux x86_64)

Revision  Changes    Path
1.48                 dev-util/debhelper/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?rev=1.48&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?rev=1.48&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/ChangeLog?r1=1.47&r2=1.48

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v
retrieving revision 1.47
retrieving revision 1.48
diff -u -r1.47 -r1.48
--- ChangeLog	26 May 2012 09:46:53 -0000	1.47
+++ ChangeLog	29 May 2012 07:37:39 -0000	1.48
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/debhelper
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.47 2012/05/26 09:46:53 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/ChangeLog,v 1.48 2012/05/29 07:37:39 jer Exp $
+
+*debhelper-9.20120528 (29 May 2012)
+
+  29 May 2012; Jeroen Roovers <jer@g.o> +debhelper-9.20120528.ebuild:
+  Version bump.
 
   26 May 2012; Markus Meier <maekke@g.o> debhelper-9.20120322.ebuild:
   arm stable, bug #415269



1.1                  dev-util/debhelper/debhelper-9.20120528.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/debhelper-9.20120528.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/debhelper/debhelper-9.20120528.ebuild?rev=1.1&content-type=text/plain

Index: debhelper-9.20120528.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/debhelper/debhelper-9.20120528.ebuild,v 1.1 2012/05/29 07:37:39 jer Exp $

EAPI=4
inherit eutils toolchain-funcs

DESCRIPTION="Collection of programs that can be used to automate common tasks in debian/rules"
HOMEPAGE="http://packages.qa.debian.org/d/debhelper.html http://kitenet.net/~joey/code/debhelper.html"
SRC_URI="mirror://debian/pool/main/d/${PN}/${P/-/_}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~s390 ~sh ~sparc ~x86"
IUSE="nls linguas_de linguas_es linguas_fr test"

RDEPEND="app-arch/dpkg
	dev-perl/TimeDate
	virtual/perl-Getopt-Long
	>=dev-lang/perl-5.10"

DEPEND="${RDEPEND}
	nls? ( >=app-text/po4a-0.24 )
	test? ( dev-perl/Test-Pod )"

S=${WORKDIR}/${PN}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-7.4.13-conditional-nls.patch
}

src_compile() {
	tc-export CC
	local USE_NLS=no LANGS=""

	use nls && USE_NLS=yes

	use linguas_de && LANGS="${LANGS} de"
	use linguas_es && LANGS="${LANGS} es"
	use linguas_fr && LANGS="${LANGS} fr"

	emake USE_NLS=${USE_NLS} LANGS="${LANGS}" build
}

src_install() {
	default
	dodoc doc/* debian/changelog
	docinto examples
	dodoc examples/*
	for manfile in *.1 *.7 ; do
		case ${manfile} in
			*.de.?)	use linguas_de \
					&& cp ${manfile} "${T}"/${manfile/.de/} \
					&& doman -i18n=de "${T}"/${manfile/.de/}
				;;
			*.es.?)	use linguas_es \
					&& cp ${manfile} "${T}"/${manfile/.es/} \
					&& doman -i18n=es "${T}"/${manfile/.es/}
				;;
			*.fr.?)	use linguas_fr \
					&& cp ${manfile} "${T}"/${manfile/.fr/} \
					&& doman -i18n=fr "${T}"/${manfile/.fr/}
				;;
			*)	doman ${manfile}
				;;
		esac
	done
}