[gentoo-commits] repo/gentoo:master commit in: dev-python/pdm-pep517/

[Arthur Zamarin]

commit:     3edfdeff094901ceaa8c2cc06fc8572a12bb6076
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun Jul  3 18:43:30 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun Jul  3 19:14:29 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3edfdeff

dev-python/pdm-pep517: add 1.0.1

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/pdm-pep517/Manifest                |  1 +
 dev-python/pdm-pep517/pdm-pep517-1.0.1.ebuild | 58 +++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index d21727cd3ee0..bb5e469f4856 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-pep517-0.12.7.gh.tar.gz 304959 BLAKE2B 0571a77803b999f88f38da843c5fcf126eeb538c6812c3e245be2fc14d6cd19929559985efba2d245bbf0efb00e412b2133fca6bbe9e63317e6b7311867e0072 SHA512 45da8ab31071a57062fac5b89abe7d912d787d647eda1b45fe3941c43687fe0fe5c8d11e539290035375e17eef808489000513e3128708fcefd851e792757b8f
 DIST pdm-pep517-1.0.0.gh.tar.gz 307117 BLAKE2B 6af1cbeb10bfcf040aaaaf60535d660c00ad84f0a186b508112e224df7eed417ce97ec1bdbf2764549172ecbededf4e9b17b6ae915b71599f04d09f2103c0a7c SHA512 cb8c02af8c4f00cf68e6379c2e93aa0ab7d30f4405debb62f7c46afc10596ab440128f1a7444fe6989d5eafb462bbbe0cfc83325bc1aba92268498a3d96332e8
+DIST pdm-pep517-1.0.1.gh.tar.gz 307357 BLAKE2B f833179b0ea011c4304625f08d3eca85b17163d4af6144f72e6faa2fe1091f9607f53ae051fca4e837009c3132ad6f06ae69cc5288ca8731ffb1ff2ef555d0d0 SHA512 7d90829a351e95f7b53f53d356a60cb170036059f5e6311df46989253b33f126f384a93cd6aa22c95b1ec7aa501e13773ccafabbb41e5237e84537b73dc43f58

diff --git a/dev-python/pdm-pep517/pdm-pep517-1.0.1.ebuild b/dev-python/pdm-pep517/pdm-pep517-1.0.1.ebuild
new file mode 100644
index 000000000000..65915f36678c
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-1.0.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@×××××××.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}