[gentoo-commits] repo/gentoo:master commit in: dev-libs/libtraceevent/

[Yixun Lan]

commit:     feb1894a3c53aa647378caabee28c8afb08764b0
Author:     Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Fri Sep  2 13:45:28 2022 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Fri Sep  2 13:58:32 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=feb1894a

dev-libs/libtraceevent: add 1.6.2

Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 dev-libs/libtraceevent/Manifest                   |  1 +
 dev-libs/libtraceevent/libtraceevent-1.6.2.ebuild | 50 +++++++++++++++++++++++
 2 files changed, 51 insertions(+)

diff --git a/dev-libs/libtraceevent/Manifest b/dev-libs/libtraceevent/Manifest
index 47be91c684f0..b8035aeb65a8 100644
--- a/dev-libs/libtraceevent/Manifest
+++ b/dev-libs/libtraceevent/Manifest
@@ -1 +1,2 @@
 DIST libtraceevent-1.5.2.tar.gz 135283 BLAKE2B e4202fc3c9b09d20bed375bc1833a4f49b63cf484e63ecf3cc5f1f3950a1de7607464e6c2ae194085e78978e5f480a7ae392a4cde739c3a244367eaf1000f70d SHA512 3804a84d2a4771335ba14a7383f977d641e6437f055837c2faece811b8ef931cfa9d38082bef48d96092aeae8cdcb543222a3042b2c11c41749dddbbb4813d94
+DIST libtraceevent-1.6.2.tar.gz 135857 BLAKE2B c5384d9bb8dc5977cfb412c22d9692ed757f94dcd01b6a93e8368cd3368bf2731c0c4eff764fd81b4627925e0fd370acd509710b538842708836b5d0ce777003 SHA512 8e951f66c339de2bc78c7c7f347f9283553ae62adc9e2bb96de1ed0aaadf91d59b2e93785c5030b0dd6d946488dc5e688d504eba54d674454c808c320127cfbf

diff --git a/dev-libs/libtraceevent/libtraceevent-1.6.2.ebuild b/dev-libs/libtraceevent/libtraceevent-1.6.2.ebuild
new file mode 100644
index 000000000000..b9bb4041b4e1
--- /dev/null
+++ b/dev-libs/libtraceevent/libtraceevent-1.6.2.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Linux kernel trace event library"
+HOMEPAGE="https://git.kernel.org/pub/scm/libs/libtrace/libtraceevent.git/"
+
+if [[ ${PV} =~ [9]{4,} ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/libs/libtrace/libtraceevent.git/"
+	inherit git-r3
+else
+	SRC_URI="https://git.kernel.org/pub/scm/libs/libtrace/libtraceevent.git/snapshot/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc"
+
+RDEPEND="
+	!<dev-util/trace-cmd-3.0
+"
+BDEPEND="
+	doc? ( app-text/xmlto app-text/asciidoc )
+"
+
+src_configure() {
+	EMAKE_FLAGS=(
+		"prefix=${EPREFIX}/usr"
+		"libdir=${EPREFIX}/usr/$(get_libdir)"
+		"CC=$(tc-getCC)"
+		"AR=$(tc-getAR)"
+		VERBOSE=1
+	)
+}
+
+src_compile() {
+	emake "${EMAKE_FLAGS[@]}"
+	use doc && emake doc
+}
+
+src_install() {
+	emake "${EMAKE_FLAGS[@]}" DESTDIR="${ED}" install
+	# can't prevent installation of the static lib with parameters
+	rm "${ED}/usr/$(get_libdir)/libtraceevent.a" || die
+	use doc && emake "${EMAKE_FLAGS[@]}" DESTDIR="${ED}" install-doc
+}