[gentoo-commits] gentoo-x86 commit in net-wireless/blueman: blueman-1.23_p20140717-r1.ebuild blueman-9999.ebuild ChangeLog blueman-1.23_p20140717.ebuild

[Michal Gorny (mgorny)]

mgorny      14/08/01 08:03:45

  Modified:             blueman-9999.ebuild ChangeLog
  Added:                blueman-1.23_p20140717-r1.ebuild
  Removed:              blueman-1.23_p20140717.ebuild
  Log:
  Update deps from configure.ac. Switch to python-single-r1. Add missing ||die.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

Revision  Changes    Path
1.3                  net-wireless/blueman/blueman-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild?r1=1.2&r2=1.3

Index: blueman-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- blueman-9999.ebuild	12 May 2014 14:22:17 -0000	1.2
+++ blueman-9999.ebuild	1 Aug 2014 08:03:45 -0000	1.3
@@ -1,12 +1,11 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild,v 1.2 2014/05/12 14:22:17 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-9999.ebuild,v 1.3 2014/08/01 08:03:45 mgorny Exp $
 
 EAPI="5"
 
-PYTHON_DEPEND="2:2.7"
-
-inherit eutils python gnome2-utils autotools
+PYTHON_COMPAT=( python2_7 )
+inherit eutils python-single-r1 gnome2-utils autotools
 
 DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
 HOMEPAGE="http://blueman-project.org/"
@@ -24,24 +23,25 @@
 SLOT="0"
 IUSE="gconf sendto network nls policykit pulseaudio"
 
-CDEPEND="dev-libs/glib:2
-	x11-libs/gtk+:3
-	x11-libs/startup-notification
-	dev-python/pygobject:2
-	>=net-wireless/bluez-4.61
-	x11-libs/libnotify"
+CDEPEND="dev-libs/glib:2=
+	x11-libs/gtk+:3=
+	x11-libs/startup-notification:=
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	|| (
+		dev-python/pygobject:2
+		dev-python/pygobject:3
+	)
+	>=net-wireless/bluez-4.61:=
+	${PYTHON_DEPS}"
 DEPEND="${CDEPEND}
 	nls? ( dev-util/intltool sys-devel/gettext )
 	virtual/pkgconfig
-	>=dev-python/pyrex-0.9.8"
+	dev-python/cython[${PYTHON_USEDEP}]"
 RDEPEND="${CDEPEND}
 	>=app-mobilephone/obex-data-server-0.4.4
 	sys-apps/dbus
-	dev-python/pygtk
-	dev-python/notify-python
-	dev-python/dbus-python
 	x11-themes/hicolor-icon-theme
-	gconf? ( dev-python/gconf-python )
+	gconf? ( dev-python/gconf-python[${PYTHON_USEDEP}] )
 	sendto? ( gnome-base/nautilus )
 	network? ( || ( net-dns/dnsmasq
 		=net-misc/dhcp-3*
@@ -49,15 +49,9 @@
 	policykit? ( sys-auth/polkit )
 	pulseaudio? ( media-sound/pulseaudio )"
 
-pkg_setup() {
-	python_set_active_version 2.7
-	python_pkg_setup
-}
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 src_prepare() {
-	# disable pyc compiling
-	ln -sf $(type -P true) py-compile
-
 	sed -i \
 		-e '/^Encoding/d' \
 		data/blueman-manager.desktop.in || die "sed failed"
@@ -80,16 +74,15 @@
 src_install() {
 	default
 
-	python_convert_shebangs 2.7 "${D}"/usr/bin/blueman-* "${D}/usr/libexec/blueman-mechanism"
-
-	rm "${D}"/$(python_get_sitedir)/*.la
-	use sendto && rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la
+	python_fix_shebang "${D}"
 
-	use gconf || rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py
-	use policykit || rm -rf "${D}"/usr/share/polkit-1
-	use pulseaudio || rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py,plugins/applet/Pulse*.py}
+	rm "${D}"/$(python_get_sitedir)/*.la || die
+	use sendto && { rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la || die; }
 
-	python_need_rebuild
+	# Note: Python 3 support would need __pycache__ file removal too
+	use gconf || { rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py* || die; }
+	use policykit || { rm -rf "${D}"/usr/share/polkit-1 || die; }
+	use pulseaudio || { rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py*,plugins/manager/Pulse*.py*} || die; }
 }
 
 pkg_preinst() {
@@ -97,11 +90,9 @@
 }
 
 pkg_postinst() {
-	python_mod_optimize ${PN}
 	gnome2_icon_cache_update
 }
 
 pkg_postrm() {
-	python_mod_cleanup ${PN}
 	gnome2_icon_cache_update
 }



1.21                 net-wireless/blueman/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	1 Aug 2014 02:52:09 -0000	1.20
+++ ChangeLog	1 Aug 2014 08:03:45 -0000	1.21
@@ -1,6 +1,13 @@
 # ChangeLog for net-wireless/blueman
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.20 2014/08/01 02:52:09 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/ChangeLog,v 1.21 2014/08/01 08:03:45 mgorny Exp $
+
+*blueman-1.23_p20140717-r1 (01 Aug 2014)
+
+  01 Aug 2014; Michał Górny <mgorny@g.o>
+  +blueman-1.23_p20140717-r1.ebuild, -blueman-1.23_p20140717.ebuild,
+  blueman-9999.ebuild:
+  Update deps from configure.ac. Switch to python-single-r1. Add missing ||die.
 
 *blueman-1.23_p20140717 (01 Aug 2014)
 



1.1                  net-wireless/blueman/blueman-1.23_p20140717-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/blueman-1.23_p20140717-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/blueman/blueman-1.23_p20140717-r1.ebuild?rev=1.1&content-type=text/plain

Index: blueman-1.23_p20140717-r1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/blueman/blueman-1.23_p20140717-r1.ebuild,v 1.1 2014/08/01 08:03:45 mgorny Exp $

EAPI="5"

PYTHON_COMPAT=( python2_7 )
inherit eutils python-single-r1 gnome2-utils autotools

DESCRIPTION="GTK+ Bluetooth Manager, designed to be simple and intuitive for everyday bluetooth tasks."
HOMEPAGE="http://blueman-project.org/"

if [[ ${PV} == "9999" ]] ; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/${PN}-project/${PN}.git"
	KEYWORDS=""
else
	#SRC_URI="http://download.tuxfamily.org/${PN}/${P}.tar.gz"
	SRC_URI="https://dev.gentoo.org/~zerochaos/distfiles/${P}.tar.xz"
	KEYWORDS="~amd64 ~ppc ~x86"
fi

LICENSE="GPL-3"
SLOT="0"
IUSE="gconf sendto network nls policykit pulseaudio"

CDEPEND="dev-libs/glib:2=
	x11-libs/gtk+:3=
	x11-libs/startup-notification:=
	dev-python/dbus-python[${PYTHON_USEDEP}]
	|| (
		dev-python/pygobject:2
		dev-python/pygobject:3
	)
	>=net-wireless/bluez-4.61:=
	${PYTHON_DEPS}"
DEPEND="${CDEPEND}
	nls? ( dev-util/intltool sys-devel/gettext )
	virtual/pkgconfig
	dev-python/cython[${PYTHON_USEDEP}]"
RDEPEND="${CDEPEND}
	>=app-mobilephone/obex-data-server-0.4.4
	sys-apps/dbus
	x11-themes/hicolor-icon-theme
	gconf? ( dev-python/gconf-python[${PYTHON_USEDEP}] )
	sendto? ( gnome-base/nautilus )
	network? ( || ( net-dns/dnsmasq
		=net-misc/dhcp-3*
		>=net-misc/networkmanager-0.8 ) )
	policykit? ( sys-auth/polkit )
	pulseaudio? ( media-sound/pulseaudio )"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

src_prepare() {
	sed -i \
		-e '/^Encoding/d' \
		data/blueman-manager.desktop.in || die "sed failed"

	epatch \
		"${FILESDIR}/${PN}-9999-plugins-conf-file.patch" \
		"${FILESDIR}/${PN}-9999-set-codeset-for-gettext-to-UTF-8-always.patch"
	eautoreconf
}

src_configure() {
	econf \
		--disable-static \
		$(use_enable policykit polkit) \
		$(use_enable sendto) \
		--disable-hal \
		$(use_enable nls)
}

src_install() {
	default

	python_fix_shebang "${D}"

	rm "${D}"/$(python_get_sitedir)/*.la || die
	use sendto && { rm "${D}"/usr/lib*/nautilus-sendto/plugins/*.la || die; }

	# Note: Python 3 support would need __pycache__ file removal too
	use gconf || { rm "${D}"/$(python_get_sitedir)/${PN}/plugins/config/Gconf.py* || die; }
	use policykit || { rm -rf "${D}"/usr/share/polkit-1 || die; }
	use pulseaudio || { rm "${D}"/$(python_get_sitedir)/${PN}/{main/Pulse*.py*,plugins/manager/Pulse*.py*} || die; }
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}