[gentoo-commits] repo/gentoo:master commit in: media-gfx/eog/

[Matt Turner]

commit:     a7f50637e17d2f53e36e4197eafb64a2819e4822
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  6 21:22:30 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sun Aug  7 02:24:03 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a7f50637

media-gfx/eog: Version bump to 42.3

Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 media-gfx/eog/Manifest        |  1 +
 media-gfx/eog/eog-42.3.ebuild | 74 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/media-gfx/eog/Manifest b/media-gfx/eog/Manifest
index 5abe46afaa8b..1d6eae61e45b 100644
--- a/media-gfx/eog/Manifest
+++ b/media-gfx/eog/Manifest
@@ -1 +1,2 @@
 DIST eog-42.2.tar.xz 4445892 BLAKE2B 863ecf1efcf295ae0deb6a966b6e0009cf4966543548e258d73315810bb4c1ed8434fa022b8367d779243376d2ba6cbe10d5e44135cedd0e5ec520dcee4ceaaf SHA512 f2da81fe7040f7ffc63da03df4889add33d59ad8df637797d1094d95233f4ce891838dfe6f774f58de63c28a620807bc4097b3ab1f31afb7cc7c402f8501e69d
+DIST eog-42.3.tar.xz 4460968 BLAKE2B ce589ec50210870bf11d8737c0ca18dd7da308de59654639623f15984f9d62f36cb1b87854fa4f67b7885cb5802e576281fc91c6e2c86e9d285d9a952193a8cc SHA512 bc82830897c55769cd2cb0c0d428b9456465c0f4e793c597ea74b3c84d5c052f051b772413cb32754153714239a9815a09fe93daf928f13e16f8d997b1e58b45

diff --git a/media-gfx/eog/eog-42.3.ebuild b/media-gfx/eog/eog-42.3.ebuild
new file mode 100644
index 000000000000..fb9dfdc4d3cc
--- /dev/null
+++ b/media-gfx/eog/eog-42.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome https://gitlab.gnome.org/GNOME/eog"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-42_beta
+	>=x11-misc/shared-mime-info-0.20
+	>=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+	>=x11-libs/gtk+-3.24.15:3[introspection,X]
+	>=gui-libs/libhandy-1.5.0:1
+	sys-libs/zlib
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	lcms? ( media-libs/lcms:2 )
+	xmp? ( media-libs/exempi:2 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	svg? ( >=gnome-base/librsvg-2.44.0:2 )
+
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? (
+		dev-util/gi-docgen
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif libexif)
+		$(meson_use lcms cms)
+		$(meson_use xmp)
+		$(meson_use jpeg libjpeg)
+		$(meson_use svg librsvg)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dinstalled_tests=false
+		-Dlibportal=false # As of 40.3, all libportal usages are flatpak-specific
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}