[gentoo-commits] gentoo-x86 commit in net-analyzer/openvas-scanner: openvas-scanner-4.0.6.ebuild ChangeLog

[Justin Lecher (jlec)]

jlec        15/03/06 10:13:47

  Modified:             ChangeLog
  Added:                openvas-scanner-4.0.6.ebuild
  Log:
  Version Bump
  
  (Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.23                 net-analyzer/openvas-scanner/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	14 Feb 2015 19:01:43 -0000	1.22
+++ ChangeLog	6 Mar 2015 10:13:47 -0000	1.23
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/openvas-scanner
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.22 2015/02/14 19:01:43 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/ChangeLog,v 1.23 2015/03/06 10:13:47 jlec Exp $
+
+*openvas-scanner-4.0.6 (06 Mar 2015)
+
+  06 Mar 2015; Justin Lecher <jlec@g.o> +openvas-scanner-4.0.6.ebuild:
+  Version Bump
 
   14 Feb 2015; Justin Lecher <jlec@g.o> openvas-scanner-5.0_beta6.ebuild:
   Remove wrong USE constraints



1.1                  net-analyzer/openvas-scanner/openvas-scanner-4.0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.6.ebuild?rev=1.1&content-type=text/plain

Index: openvas-scanner-4.0.6.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/openvas-scanner/openvas-scanner-4.0.6.ebuild,v 1.1 2015/03/06 10:13:47 jlec Exp $

EAPI=5

inherit cmake-utils systemd

MY_PN=openvassd

DL_ID=1959

DESCRIPTION="A remote security scanner for Linux (OpenVAS-scanner)"
HOMEPAGE="http://www.openvas.org/"
SRC_URI="http://wald.intevation.org/frs/download.php/${DL_ID}/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE=""

RDEPEND="
	>=net-analyzer/openvas-libraries-7.0.9
	!net-analyzer/openvas-plugins
	!net-analyzer/openvas-server"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

PATCHES=(
	"${FILESDIR}"/${PN}-4.0.3-bsdsource.patch
	"${FILESDIR}"/${PN}-4.0.3-mkcertclient.patch
	"${FILESDIR}"/${PN}-4.0.3-rulesdir.patch
	"${FILESDIR}"/${PN}-4.0.3-run.patch
	)

src_prepare() {
	sed \
		-e '/^install.*OPENVAS_CACHE_DIR.*/d' \
		-i CMakeLists.txt || die
	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		"-DLOCALSTATEDIR=${EPREFIX}/var"
		"-DSYSCONFDIR=${EPREFIX}/etc"
	)
	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN}

	insinto /etc/openvas
	doins "${FILESDIR}"/${MY_PN}.conf "${FILESDIR}"/${MY_PN}-daemon.conf
	dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${PN}

	insinto /etc/logrotate.d
	doins "${FILESDIR}"/${MY_PN}.logrotate

	dodoc "${FILESDIR}"/openvas-nvt-sync-cron

	systemd_newtmpfilesd "${FILESDIR}"/${MY_PN}.tmpfiles.d ${MY_PN}.conf
	systemd_dounit "${FILESDIR}"/${MY_PN}.service
}