[gentoo-commits] gentoo-x86 commit in media-gfx/exiv2: ChangeLog exiv2-0.24.ebuild

[Andreas HAttel (dilfridge)]

dilfridge    14/06/04 21:22:13

  Modified:             ChangeLog
  Added:                exiv2-0.24.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

Revision  Changes    Path
1.121                media-gfx/exiv2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/exiv2/ChangeLog?rev=1.121&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/exiv2/ChangeLog?rev=1.121&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/exiv2/ChangeLog?r1=1.120&r2=1.121

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/exiv2/ChangeLog,v
retrieving revision 1.120
retrieving revision 1.121
diff -u -r1.120 -r1.121
--- ChangeLog	30 Apr 2014 14:28:29 -0000	1.120
+++ ChangeLog	4 Jun 2014 21:22:13 -0000	1.121
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/exiv2
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/ChangeLog,v 1.120 2014/04/30 14:28:29 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/ChangeLog,v 1.121 2014/06/04 21:22:13 dilfridge Exp $
+
+*exiv2-0.24 (04 Jun 2014)
+
+  04 Jun 2014; Andreas K. Huettel <dilfridge@g.o> +exiv2-0.24.ebuild,
+  +files/exiv2-0.24-python3.patch:
+  Version bump
 
   30 Apr 2014; Michał Górny <mgorny@g.o> exiv2-0.23-r2.ebuild:
   Fix multilib and Python support. Bug #474654.



1.1                  media-gfx/exiv2/exiv2-0.24.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/exiv2/exiv2-0.24.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/exiv2/exiv2-0.24.ebuild?rev=1.1&content-type=text/plain

Index: exiv2-0.24.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/exiv2/exiv2-0.24.ebuild,v 1.1 2014/06/04 21:22:13 dilfridge Exp $

EAPI=5
AUTOTOOLS_IN_SOURCE_BUILD=1
PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3,3_4} )

inherit eutils multilib toolchain-funcs python-any-r1 autotools-multilib

DESCRIPTION="EXIF and IPTC metadata C++ library and command line utility"
HOMEPAGE="http://www.exiv2.org/"
SRC_URI="http://www.exiv2.org/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0/13"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE_LINGUAS="de es fi fr pl ru sk"
IUSE="contrib doc examples nls xmp zlib static-libs $(printf 'linguas_%s ' ${IUSE_LINGUAS})"

RDEPEND="
	virtual/libiconv[${MULTILIB_USEDEP}]
	nls? ( virtual/libintl[${MULTILIB_USEDEP}] )
	xmp? ( dev-libs/expat[${MULTILIB_USEDEP}] )
	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
"

DEPEND="${RDEPEND}
	contrib? ( >=dev-libs/boost-1.44 )
	doc? (
		app-doc/doxygen
		dev-libs/libxslt
		virtual/pkgconfig
		media-gfx/graphviz
		${PYTHON_DEPS}
	)
	nls? ( sys-devel/gettext )
"

DOCS=( README doc/ChangeLog doc/cmd.txt )

pkg_setup() {
	use doc && python-any-r1_pkg_setup
}

src_prepare() {
	# convert docs to UTF-8
	local i
	for i in doc/cmd.txt; do
		einfo "Converting "${i}" to UTF-8"
		iconv -f LATIN1 -t UTF-8 "${i}" > "${i}~" && mv -f "${i}~" "${i}" || rm -f "${i}~"
	done

	if use doc; then
		einfo "Updating doxygen config"
		doxygen 2>&1 >/dev/null -u config/Doxyfile
	fi

	if use contrib; then
		epatch "${FILESDIR}/${PN}-0.23-boost-fs-contrib.patch"

		# create build environment for contrib
		ln -snf ../../src contrib/organize/exiv2
		sed -i -e 's:/usr/local/include/.*:/usr/include:g' \
			-e 's:/usr/local/lib/lib:-l:g' -e 's:-gcc..-mt-._..\.a::g' \
			contrib/organize/boost.mk || die
	fi

	epatch "${FILESDIR}/${PN}-0.24-python3.patch"

	# set locale to safe value for the sed commands (bug #382731)
	sed -i -r "s,(\s+)sed\s,\1LC_ALL="C" sed ,g" src/Makefile || die

	autotools-multilib_src_prepare
}

multilib_src_configure() {
	local myeconfargs=(
		$(use_enable nls)
		$(use_enable xmp)
		$(use_enable static-libs static)
	)

	# plain 'use_with' fails
	use zlib || myeconfargs+=( --without-zlib )

	# Bug #78720. amd64/gcc-3.4/-fvisibility* fail.
	if [[ ${ABI} == amd64 && $(gcc-major-version) -lt 4 ]]; then
		myeconfargs+=( --disable-visibility )
	fi

	autotools-utils_src_configure
}

multilib_src_compile() {
	emake

	if multilib_is_native_abi; then
		if use contrib; then
			emake -C contrib/organize \
				LDFLAGS="\$(BOOST_LIBS) -L../../src -lexiv2 ${LDFLAGS}" \
				CPPFLAGS="${CPPFLAGS} -I\$(BOOST_INC_DIR) -I. -DEXV_HAVE_STDINT_H"
		fi

		use doc && emake doc
	fi
}

multilib_src_install() {
	autotools-utils_src_install

	if multilib_is_native_abi; then
		if use contrib; then
			emake DESTDIR="${D}" -C contrib/organize install
		fi

		use doc && dohtml -r doc/html/.
	fi
}

multilib_src_install_all() {
	einstalldocs
	prune_libtool_files --all

	use xmp && dodoc doc/{COPYING-XMPSDK,README-XMP,cmdxmp.txt}
	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		docompress -x /usr/share/doc/${PF}/examples
		doins samples/*.cpp
	fi
}