[gentoo-commits] gentoo-x86 commit in net-analyzer/sancp: ChangeLog sancp-1.6.1-r4.ebuild sancp-1.6.1-r3.ebuild

[Jeroen Roovers (jer)]

jer         12/11/21 04:22:06

  Modified:             ChangeLog
  Added:                sancp-1.6.1-r4.ebuild
  Removed:              sancp-1.6.1-r3.ebuild
  Log:
  Add copyright info to conf.d script. Add GPL-2 to LICENSE (bug #425992). Move tc-export to src_prepare(). Fix DESCRIPTION. Remove pointless elog message.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.15                 net-analyzer/sancp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/sancp/ChangeLog?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/sancp/ChangeLog?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/sancp/ChangeLog?r1=1.14&r2=1.15

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/sancp/ChangeLog,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- ChangeLog	12 Jun 2012 02:59:01 -0000	1.14
+++ ChangeLog	21 Nov 2012 04:22:05 -0000	1.15
@@ -1,6 +1,13 @@
 # ChangeLog for net-analyzer/sancp
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sancp/ChangeLog,v 1.14 2012/06/12 02:59:01 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sancp/ChangeLog,v 1.15 2012/11/21 04:22:05 jer Exp $
+
+*sancp-1.6.1-r4 (21 Nov 2012)
+
+  21 Nov 2012; Jeroen Roovers <jer@g.o> -sancp-1.6.1-r3.ebuild,
+  +sancp-1.6.1-r4.ebuild, files/sancp.confd:
+  Add copyright info to conf.d script. Add GPL-2 to LICENSE (bug #425992). Move
+  tc-export to src_prepare(). Fix DESCRIPTION. Remove pointless elog message.
 
   12 Jun 2012; Zac Medico <zmedico@g.o> sancp-1.6.1-r3.ebuild:
   inherit user for enewgroup and enewuser



1.1                  net-analyzer/sancp/sancp-1.6.1-r4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/sancp/sancp-1.6.1-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/sancp/sancp-1.6.1-r4.ebuild?rev=1.1&content-type=text/plain

Index: sancp-1.6.1-r4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/sancp/sancp-1.6.1-r4.ebuild,v 1.1 2012/11/21 04:22:05 jer Exp $

EAPI=4

inherit eutils toolchain-funcs user

DESCRIPTION="collect statistical information regarding network traffic and collect it in pcap format"
HOMEPAGE="http://www.metre.net/sancp.html"
SRC_URI="
	http://www.metre.net/files/${P}.tar.gz
	http://sancp.sourceforge.net/${PN}-1.6.1.fix200511.a.patch
	http://sancp.sourceforge.net/${PN}-1.6.1.fix200511.b.patch
	http://sancp.sourceforge.net/${PN}-1.6.1.fix200601.c.patch
	http://sancp.sourceforge.net/${PN}-1.6.1.fix200606.d.patch
"

LICENSE="QPL GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="sguil"

RDEPEND="net-libs/libpcap"
DEPEND="${RDEPEND}"

pkg_setup() {
	enewgroup sancp
	enewuser sancp -1 -1 /dev/null sancp
}

src_prepare() {
	epatch "${DISTDIR}"/${PN}-1.6.1.fix200511.a.patch
	epatch "${DISTDIR}"/${PN}-1.6.1.fix200511.b.patch
	# bug 138337
	epatch "${DISTDIR}"/${PN}-1.6.1.fix200601.c.patch
	epatch "${DISTDIR}"/${PN}-1.6.1.fix200606.d.patch
	epatch "${FILESDIR}"/${P}-compiler.patch

	tc-export CXX CC
}

src_install() {
	keepdir /var/log/sancp/
	dodoc docs/CHANGES docs/fields.LIST docs/README docs/SETUP \
		"${FILESDIR}"/sguil_sancp.conf etc/sancp/sancp.conf

	insinto /etc/sancp
	if use sguil ; then
		newins "${FILESDIR}"/sguil_sancp.conf sancp.conf
	else
		doins etc/sancp/sancp.conf
	fi

	dobin sancp

	newinitd "${FILESDIR}"/sancp.rc1 sancp
	newconfd "${FILESDIR}"/sancp.confd sancp
	if use sguil ; then
		sed -i -e /^SANCP_OPTS/s:'sancp':"sguil":g \
			-e s:'-d $LOGDIR/today':"-d /var/lib/sguil/$(hostname)/sancp": \
			"${D}/etc/conf.d/sancp"
	fi

	fowners sancp:sancp /var/log/sancp
	fperms 0770 /var/log/sancp
}