[gentoo-commits] gentoo-x86 commit in app-arch/libarchive: ChangeLog libarchive-2.4.0.ebuild libarchive-2.3.4.ebuild libarchive-2.2.5.ebuild libarchive-2.3.3.ebuild

[Diego Petteno (flameeyes)]

flameeyes    07/11/04 17:54:42

  Modified:             ChangeLog
  Added:                libarchive-2.4.0.ebuild
  Removed:              libarchive-2.3.4.ebuild libarchive-2.2.5.ebuild
                        libarchive-2.3.3.ebuild
  Log:
  Version bump, and cleanup of old ebuilds.
  (Portage version: 2.1.3.17)

Revision  Changes    Path
1.6                  app-arch/libarchive/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	29 Oct 2007 17:23:03 -0000	1.5
+++ ChangeLog	4 Nov 2007 17:54:42 -0000	1.6
@@ -1,6 +1,13 @@
 # ChangeLog for app-arch/libarchive
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.5 2007/10/29 17:23:03 uberlord Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/ChangeLog,v 1.6 2007/11/04 17:54:42 flameeyes Exp $
+
+*libarchive-2.4.0 (04 Nov 2007)
+
+  04 Nov 2007; Diego Pettenò <flameeyes@g.o>
+  -libarchive-2.2.5.ebuild, -libarchive-2.3.3.ebuild,
+  -libarchive-2.3.4.ebuild, +libarchive-2.4.0.ebuild:
+  Version bump, and cleanup of old ebuilds.
 
 *libarchive-2.3.5 (29 Oct 2007)
 



1.1                  app-arch/libarchive/libarchive-2.4.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-arch/libarchive/libarchive-2.4.0.ebuild?rev=1.1&content-type=text/plain

Index: libarchive-2.4.0.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/libarchive/libarchive-2.4.0.ebuild,v 1.1 2007/11/04 17:54:42 flameeyes Exp $

inherit eutils autotools toolchain-funcs flag-o-matic

MY_P=${P/_beta/b}

DESCRIPTION="BSD tar command"
HOMEPAGE="http://people.freebsd.org/~kientzle/libarchive/"
SRC_URI="http://people.freebsd.org/~kientzle/libarchive/src/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="build static acl xattr kernel_linux"

RDEPEND="!dev-libs/libarchive
	kernel_linux? (
		acl? ( sys-apps/acl )
		xattr? ( sys-apps/attr )
	)
	!static? ( !build? (
		app-arch/bzip2
		sys-libs/zlib ) )"
DEPEND="${RDEPEND}
	kernel_linux? ( sys-fs/e2fsprogs
		virtual/os-headers )"

S="${WORKDIR}/${MY_P}"

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/${PN}-2.1.5-acl.patch

	eautoreconf
	epunt_cxx
}

src_compile() {
	local myconf=

	if use static || use build ; then
		myconf="${myconf} --enable-static-bsdtar"
	else
		myconf="${myconf} --disable-static-bsdtar"
	fi

	# Upstream doesn't seem to care to fix the problems
	# and I don't want to continue running after them.
	#append-flags -fno-strict-aliasing

	econf \
		--bindir=/bin \
		--enable-bsdcpio \
		$(use_enable acl) \
		$(use_enable xattr) \
		${myconf} || die "econf failed"
	emake || die "emake failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	# Create tar symlink for FreeBSD
	if [[ ${CHOST} == *-freebsd* ]]; then
		dosym bsdtar /bin/tar
		dosym bsdtar.1 /usr/share/man/man1/tar.1
		# We may wish to switch to symlink bsdcpio to cpio too one day
	fi

	dodoc README NEWS

	if use build; then
		rm -rf "${D}"/usr
		rm -rf "${D}"/lib/*.so*
		return 0
	fi

	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*.so* "${D}"/$(get_libdir)
	gen_usr_ldscript libarchive.so
}



-- 
gentoo-commits@g.o mailing list