[gentoo-commits] repo/gentoo:master commit in: dev-perl/Curses/

[Kent Fredric]

commit:     60cce5e8560ceb6196275bef62c12aabe6b2b453
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  2 19:17:41 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Thu Jul  2 19:22:06 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=60cce5e8

dev-perl/Curses: -r bump for EAPI7 + CFLAGS love + fixes

- EAPI7
- Move env exports out of pkg_setup as they're not useful in binpkg's
- Simplify src_configure logic to not need function calls, employing
  more 'usex' instead of weirder conditional code.
- Ensure CFLAGS passed through to make/compiler

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 dev-perl/Curses/Curses-1.360.0-r1.ebuild | 47 ++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-perl/Curses/Curses-1.360.0-r1.ebuild b/dev-perl/Curses/Curses-1.360.0-r1.ebuild
new file mode 100644
index 00000000000..684145194e6
--- /dev/null
+++ b/dev-perl/Curses/Curses-1.360.0-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=GIRAFFED
+DIST_VERSION=1.36
+DIST_EXAMPLES=("demo" "demo2" "demo.form" "demo.menu" "demo.panel" "gdc")
+inherit perl-module
+
+DESCRIPTION="Curses interface modules for Perl"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~sparc-solaris ~x86-solaris"
+IUSE="+unicode test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=sys-libs/ncurses-5:0=[unicode?]
+	virtual/perl-Data-Dumper
+"
+DEPEND="
+	>=sys-libs/ncurses-5:0=[unicode?]
+"
+BDEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	test? ( virtual/perl-Test-Simple )
+"
+
+src_configure() {
+	myconf="${myconf} FORMS PANELS MENUS"
+	mydoc=HISTORY
+	export CURSES_LIBTYPE="$(usex unicode ncursesw ncurses)"
+	local nc_tool="${CURSES_LIBTYPE}$(has_version 'sys-libs/ncurses:0/6' && echo 6 || echo 5)-config"
+	export CURSES_LDFLAGS=$( ${nc_tool} --libs )
+	export CURSES_CFLAGS=$( ${nc_tool} --cflags )
+	perl-module_src_configure
+	if ! use unicode ; then
+		sed -i 's:<form.h>:"/usr/include/form.h":' "${S}"/c-config.h || die
+	fi
+}
+src_compile() {
+	mymake=(
+		"OPTIMIZE=${CFLAGS}"
+	)
+	perl-module_src_compile
+}