[gentoo-commits] gentoo-x86 commit in www-apache/mod_security: mod_security-2.5.13.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    10/12/01 21:58:50

  Modified:             ChangeLog
  Added:                mod_security-2.5.13.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha6/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 www-apache/mod_security/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	24 Oct 2010 17:45:04 -0000	1.46
+++ ChangeLog	1 Dec 2010 21:58:50 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for www-apache/mod_security
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v 1.46 2010/10/24 17:45:04 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/ChangeLog,v 1.47 2010/12/01 21:58:50 flameeyes Exp $
+
+*mod_security-2.5.13 (01 Dec 2010)
+
+  01 Dec 2010; Diego E. Pettenò <flameeyes@g.o>
+  +mod_security-2.5.13.ebuild:
+  Version bump.
 
   24 Oct 2010; Raúl Porcel <armin76@g.o>
   mod_security-2.5.12-r1.ebuild:



1.1                  www-apache/mod_security/mod_security-2.5.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/mod_security-2.5.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apache/mod_security/mod_security-2.5.13.ebuild?rev=1.1&content-type=text/plain

Index: mod_security-2.5.13.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/mod_security/mod_security-2.5.13.ebuild,v 1.1 2010/12/01 21:58:50 flameeyes Exp $

EAPI=2

inherit apache-module autotools

MY_P=${P/mod_security-/modsecurity-apache_}
MY_P=${MY_P/_rc/-rc}

DESCRIPTION="Web application firewall and Intrusion Detection System for Apache."
HOMEPAGE="http://www.modsecurity.org/"
SRC_URI="http://www.modsecurity.org/download/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~sparc ~x86"
IUSE="lua"

DEPEND="dev-libs/libxml2
	lua? ( >=dev-lang/lua-5.1 )
	www-servers/apache[apache2_modules_unique_id]"
RDEPEND="${DEPEND}"
PDEPEND="www-apache/modsecurity-crs"

S="${WORKDIR}/${MY_P}"

APACHE2_MOD_FILE="apache2/.libs/${PN}2.so"
APACHE2_MOD_CONF="2.5.10/99_mod_security"
APACHE2_MOD_DEFINE="SECURITY"

need_apache2

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.5.10-as-needed.patch

	cd apache2
	eautoreconf
}

src_configure() {
	cd apache2

	econf --with-apxs="${APXS}" \
		--without-curl \
		$(use_with lua) \
		|| die "econf failed"
}

src_compile() {
	cd apache2

	APXS_FLAGS=
	for flag in ${CFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wc,${flag}"
	done

	# Yes we need to prefix it _twice_
	for flag in ${LDFLAGS}; do
		APXS_FLAGS="${APXS_FLAGS} -Wl,${flag}"
	done

	emake \
		APXS_CFLAGS="${CFLAGS}" \
		APXS_LDFLAGS="${LDFLAGS}" \
		APXS_EXTRA_CFLAGS="${APXS_FLAGS}" \
		|| die "emake failed"
}

src_test() {
	cd apache2
	emake test || die
}

src_install() {
	apache-module_src_install

	# install documentation
	dodoc CHANGES || die
	dohtml -r doc/* || die

	keepdir /var/cache/mod_security || die
	fowners apache:apache /var/cache/mod_security || die
	fperms 0770 /var/cache/mod_security || die
}