[gentoo-commits] gentoo-x86 commit in media-libs/libraw: ChangeLog libraw-0.16.0_beta1.ebuild

[Tim Harder (radhermit)]

radhermit    13/11/23 23:09:09

  Modified:             ChangeLog
  Added:                libraw-0.16.0_beta1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

Revision  Changes    Path
1.71                 media-libs/libraw/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	8 Nov 2013 09:42:43 -0000	1.70
+++ ChangeLog	23 Nov 2013 23:09:09 -0000	1.71
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libraw
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.70 2013/11/08 09:42:43 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/ChangeLog,v 1.71 2013/11/23 23:09:09 radhermit Exp $
+
+*libraw-0.16.0_beta1 (23 Nov 2013)
+
+  23 Nov 2013; Tim Harder <radhermit@g.o> +libraw-0.16.0_beta1.ebuild:
+  Version bump.
 
 *libraw-0.16.0_alpha3 (08 Nov 2013)
 



1.1                  media-libs/libraw/libraw-0.16.0_beta1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/libraw-0.16.0_beta1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/libraw/libraw-0.16.0_beta1.ebuild?rev=1.1&content-type=text/plain

Index: libraw-0.16.0_beta1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libraw/libraw-0.16.0_beta1.ebuild,v 1.1 2013/11/23 23:09:09 radhermit Exp $

EAPI=5

inherit cmake-multilib toolchain-funcs

MY_PN=LibRaw
MY_PV=${PV/_b/-B}
MY_P=${MY_PN}-${MY_PV}

DESCRIPTION="LibRaw is a library for reading RAW files obtained from digital photo cameras"
HOMEPAGE="http://www.libraw.org/"
SRC_URI="http://www.libraw.org/data/${MY_P}.tar.gz
	demosaic? (
		http://www.libraw.org/data/LibRaw-demosaic-pack-GPL2-${MY_PV}.tar.gz
		http://www.libraw.org/data/LibRaw-demosaic-pack-GPL3-${MY_PV}.tar.gz
	)"

# Libraw also has it's own license, which is a pdf file and
# can be obtained from here:
# http://www.libraw.org/data/LICENSE.LibRaw.pdf
LICENSE="LGPL-2.1 CDDL GPL-2 GPL-3"
SLOT="0/10" # subslot = libraw soname version
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="demosaic examples jpeg jpeg2k +lcms openmp"

RDEPEND="jpeg? ( virtual/jpeg:0[${MULTILIB_USEDEP}] )
	jpeg2k? ( media-libs/jasper[${MULTILIB_USEDEP}] )
	lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

S=${WORKDIR}/${MY_P}

DOCS=( Changelog.txt README )

PATCHES=(
	"${FILESDIR}"/${PN}-0.16.0_alpha2-docs.patch
	"${FILESDIR}"/${PN}-0.16.0_alpha2-automagic-jasper.patch
	"${FILESDIR}"/${PN}-0.16.0_alpha2-libdir.patch
	"${FILESDIR}"/${PN}-0.16.0_alpha2-lcms2-first.patch
	"${FILESDIR}"/${PN}-0.16.0_alpha2-custom-demosaic-paths.patch
)

pkg_pretend() {
	if use openmp ; then
		tc-has-openmp || die "Please switch to an openmp compatible compiler"
	fi
}

src_configure() {
	local mycmakeargs=(
		$(cmake-utils_use_enable openmp OPENMP)
		$(cmake-utils_use_enable jpeg JPEG)
		$(cmake-utils_use_enable jpeg2k JASPER)
		$(cmake-utils_use_enable lcms LCMS)
		$(cmake-utils_use_enable examples EXAMPLES)
		$(cmake-utils_use_enable demosaic DEMOSAIC_PACK_GPL2)
		$(cmake-utils_use_enable demosaic DEMOSAIC_PACK_GPL3)
		-DDEMOSAIC_PACK_GPL2_PATH="${WORKDIR}/${MY_PN}-demosaic-pack-GPL2-${MY_PV}"
		-DDEMOSAIC_PACK_GPL3_PATH="${WORKDIR}/${MY_PN}-demosaic-pack-GPL3-${MY_PV}"
	)
	cmake-multilib_src_configure
}