[gentoo-commits] repo/gentoo:master commit in: app-i18n/librime/

[Mike Gilbert]

commit:     f221cc9e5e4151e1095d1416ee5a1cfe66226db9
Author:     Arfrever Frehtes Taifersar Arahesis <Arfrever <AT> Apache <DOT> Org>
AuthorDate: Sun Dec 27 00:00:00 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Mon Dec 28 00:01:20 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f221cc9e

app-i18n/librime: Version bump (1.6.0).

Closes: https://bugs.gentoo.org/761999
Signed-off-by: Arfrever Frehtes Taifersar Arahesis <Arfrever <AT> Apache.Org>
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 app-i18n/librime/Manifest             |  1 +
 app-i18n/librime/librime-1.6.0.ebuild | 69 +++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/app-i18n/librime/Manifest b/app-i18n/librime/Manifest
index 540a26bb8fe..cc0a9ca5672 100644
--- a/app-i18n/librime/Manifest
+++ b/app-i18n/librime/Manifest
@@ -1 +1,2 @@
 DIST librime-1.5.3.tar.gz 2847083 BLAKE2B 4ffb2c5ddaf52f9c9227fa4ea019ef2965e61139f678798c08ef37dc52b863763651b63ed820caad0de1b06f48ab5c1a7a2682653340d2ae7f5f9eec3cec80b2 SHA512 4d7f6ec43bd5728f59f0b3581bcd8a46128651430b6873017d80659942b8f6aa1a2f25f439ba8fba461fe22acbf701c2da7a786104a2e4852a70a89cdc0452d3
+DIST librime-1.6.0.tar.gz 2856645 BLAKE2B de6d843a5028f6b0308c3432ada7dd00c08a71e73fe799b157fd71a4054c757a00d3b0fdc7743d94d6e87b03f256e822ee29c16c86f96f5d24c7d864266c4f78 SHA512 4aeace0f1628293d4b607483ab976841093a1ff03df8bf63d545715af00254d1f0b1bdcd120795ea688d152287069881e0740372f40e2174a14ae6f53b7f950b

diff --git a/app-i18n/librime/librime-1.6.0.ebuild b/app-i18n/librime/librime-1.6.0.ebuild
new file mode 100644
index 00000000000..674c8ae665e
--- /dev/null
+++ b/app-i18n/librime/librime-1.6.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2012-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit cmake
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/rime/librime"
+	EGIT_SUBMODULES=()
+fi
+
+DESCRIPTION="RIME (Rime Input Method Engine) core library"
+HOMEPAGE="https://rime.im/ https://github.com/rime/librime"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/rime/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="BSD"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="dev-libs/capnproto:0"
+RDEPEND="app-i18n/opencc:0=
+	>=dev-cpp/glog-0.3.5:0=
+	dev-cpp/yaml-cpp:0=
+	dev-libs/boost:0=[threads]
+	dev-libs/capnproto:0=
+	dev-libs/leveldb:0=
+	dev-libs/marisa:0="
+DEPEND="${RDEPEND}
+	dev-libs/darts
+	dev-libs/utfcpp
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )"
+
+DOCS=(CHANGELOG.md README.md)
+
+src_prepare() {
+	# Use headers of dev-libs/darts, dev-libs/utfcpp and x11-base/xorg-proto.
+	sed -e "/\${PROJECT_SOURCE_DIR}\/thirdparty/d" -i CMakeLists.txt || die
+	rm -r thirdparty || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local -x CXXFLAGS="${CXXFLAGS} -I${ESYSROOT}/usr/include/utf8cpp"
+
+	if use debug; then
+		CXXFLAGS+=" -DDCHECK_ALWAYS_ON"
+	else
+		CXXFLAGS+=" -DNDEBUG"
+	fi
+
+	local mycmakeargs=(
+		-DBOOST_USE_CXX11=ON
+		-DBUILD_TEST=$(usex test ON OFF)
+		-DCMAKE_DISABLE_FIND_PACKAGE_Gflags=ON
+	)
+
+	cmake_src_configure
+}