[gentoo-commits] gentoo-x86 commit in net-libs/rb_libtorrent: ChangeLog rb_libtorrent-0.14.9.ebuild

[Raul Porcel (armin76)]

armin76     10/02/27 14:20:42

  Modified:             ChangeLog
  Added:                rb_libtorrent-0.14.9.ebuild
  Log:
  Version bump
  (Portage version: 2.1.7.16/cvs/Linux ia64)

Revision  Changes    Path
1.79                 net-libs/rb_libtorrent/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.79&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?rev=1.79&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/rb_libtorrent/ChangeLog?r1=1.78&r2=1.79

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v
retrieving revision 1.78
retrieving revision 1.79
diff -u -r1.78 -r1.79
--- ChangeLog	15 Jan 2010 23:33:53 -0000	1.78
+++ ChangeLog	27 Feb 2010 14:20:41 -0000	1.79
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/rb_libtorrent
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.78 2010/01/15 23:33:53 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/ChangeLog,v 1.79 2010/02/27 14:20:41 armin76 Exp $
+
+*rb_libtorrent-0.14.9 (27 Feb 2010)
+
+  27 Feb 2010; Raúl Porcel <armin76@g.o>
+  +rb_libtorrent-0.14.9.ebuild:
+  Version bump
 
 *rb_libtorrent-0.14.8-r2 (15 Jan 2010)
 



1.1                  net-libs/rb_libtorrent/rb_libtorrent-0.14.9.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.14.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.14.9.ebuild?rev=1.1&content-type=text/plain

Index: rb_libtorrent-0.14.9.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/rb_libtorrent/rb_libtorrent-0.14.9.ebuild,v 1.1 2010/02/27 14:20:41 armin76 Exp $

EAPI="2"
inherit autotools eutils flag-o-matic versionator

MY_P=${P/rb_/}
MY_P=${MY_P/torrent/torrent-rasterbar}
S=${WORKDIR}/${MY_P}

DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
HOMEPAGE="http://www.rasterbar.com/products/libtorrent/"
SRC_URI="http://libtorrent.googlecode.com/files/${MY_P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd"
IUSE="debug doc examples python test"
RESTRICT="test"

DEPEND="|| ( >=dev-libs/boost-1.35
		( ~dev-libs/boost-1.34.1 dev-cpp/asio ) )
	python? ( >=dev-libs/boost-1.35.0-r5[python] dev-lang/python:2.6[threads] )
	sys-libs/zlib"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/0.14.6-configure-ldflags-fix.patch  #290756
	epatch "${FILESDIR}"/${PN}-0.14.8-as-needed-fix.patch            #276873
	epatch "${FILESDIR}"/${PN}-0.14.8-boost-detect.patch             #295474
	eautoreconf
}

src_configure() {
	append-ldflags -pthread

	# use multi-threading versions of boost libs
	local BOOST_LIBS="--with-boost-system=boost_system-mt \
		--with-boost-asio=boost_system-mt \
		--with-boost-filesystem=boost_filesystem-mt \
		--with-boost-thread=boost_thread-mt \
		--with-boost-regex=boost_regex-mt \
		--with-boost-python=boost_python-mt \
		--with-boost-program_options=boost_program_options-mt"

	# detect boost version and location, bug 295474
	BOOST_PKG="$(best_version ">=dev-libs/boost-1.34.1")"
	BOOST_VER="$(get_version_component_range 1-2 "${BOOST_PKG/*boost-/}")"
	BOOST_VER="$(replace_all_version_separators _ "${BOOST_VER}")"
	BOOST_INC="/usr/include/boost-${BOOST_VER}"
	BOOST_LIB="/usr/$(get_libdir)/boost-${BOOST_VER}"

	local LOGGING
	use debug && LOGGING="--with-logging=verbose"

	econf $(use_enable debug) \
		$(use_enable test tests) \
		$(use_enable examples) \
		$(use_enable python python-binding) \
		--with-zlib=system \
		--with-asio=system \
		${LOGGING} \
		--with-boost=${BOOST_INC} \
		--with-boost-libdir=${BOOST_LIB} \
		${BOOST_LIBS}
}

src_install() {
	emake DESTDIR="${D}" install || die 'emake install failed'
	dodoc ChangeLog AUTHORS NEWS README || die 'dodoc failed'
	if use doc ; then
		dohtml docs/* || die "Could not install HTML documentation"
	fi
}