[gentoo-commits] gentoo-x86 commit in app-misc/g15daemon: ChangeLog g15daemon-1.9.5.3-r1.ebuild

[Tony Vroon (chainsaw)]

chainsaw    08/09/08 11:44:03

  Modified:             ChangeLog
  Added:                g15daemon-1.9.5.3-r1.ebuild
  Log:
  Hotplug support by Tais M. Hansen <tais.hansen@×××.dk>, closes bug #236422.
  (Portage version: 2.2_rc8/cvs/Linux 2.6.27-rc5-00131-g5f17cfc-dirty x86_64)

Revision  Changes    Path
1.22                 app-misc/g15daemon/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/ChangeLog?r1=1.21&r2=1.22

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog	29 May 2008 15:41:32 -0000	1.21
+++ ChangeLog	8 Sep 2008 11:44:02 -0000	1.22
@@ -1,6 +1,13 @@
 # ChangeLog for app-misc/g15daemon
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v 1.21 2008/05/29 15:41:32 hawking Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/ChangeLog,v 1.22 2008/09/08 11:44:02 chainsaw Exp $
+
+*g15daemon-1.9.5.3-r1 (08 Sep 2008)
+
+  08 Sep 2008; <chainsaw@g.o> +files/99-g15daemon.rules,
+  +files/g15daemon-hotplug, +g15daemon-1.9.5.3-r1.ebuild:
+  Hotplug support by Tais M. Hansen <tais.hansen@×××.dk>, closes bug
+  #236422.
 
   29 May 2008; Ali Polatel <hawking@g.o> g15daemon-1.2.6a-r1.ebuild,
   g15daemon-1.2.7.ebuild, g15daemon-1.2.7-r1.ebuild,



1.1                  app-misc/g15daemon/g15daemon-1.9.5.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.5.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.5.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: g15daemon-1.9.5.3-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/g15daemon/g15daemon-1.9.5.3-r1.ebuild,v 1.1 2008/09/08 11:44:02 chainsaw Exp $

inherit eutils linux-info perl-module python multilib

DESCRIPTION="G15daemon takes control of the G15 keyboard, through the linux kernel uinput device driver"
HOMEPAGE="http://g15daemon.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="perl python"

DEPEND="dev-libs/libusb
	>=dev-libs/libg15-1.2.4
	>=dev-libs/libg15render-1.2
	perl? ( >=dev-perl/Inline-0.4 )
	python? ( dev-lang/python )"

RDEPEND="${DEPEND}
	perl? ( dev-perl/GDGraph )"

uinput_check() {
	ebegin "Checking for uinput support"
	linux_chkconfig_present INPUT_UINPUT
	eend $?

	if [[ $? -ne 0 ]] ; then
		eerror "To use g15daemon, you need to compile your kernel with uinput support."
		eerror "Please enable uinput support in your kernel config, found at:"
		eerror
		eerror "Device Drivers -> Input Device ... -> Miscellaneous devices -> User level driver support."
		eerror
		eerror "Once enabled, you should have the /dev/input/uinput device."
		eerror "g15daemon will not work without the uinput device."
		die "INPUT_UINPUT support not detected!"
	fi
}

pkg_setup() {
	linux-info_pkg_setup
	uinput_check
}

src_unpack() {
	unpack ${A}
	if use perl; then
		unpack "./${P}/lang-bindings/perl-G15Daemon-0.2.tar.gz"
	fi
	if use python; then
		unpack "./${P}/lang-bindings/pyg15daemon-0.0.tar.bz2"
	fi
}

src_compile() {
	econf || die "configure failed"

	emake || die "make failed"

	if use perl; then
		cd "${WORKDIR}/G15Daemon-0.2"
		perl-module_src_compile
	fi
}

src_install() {
	emake DESTDIR="${D}" \
		docdir=/usr/share/doc/${PF} install || die "make install failed"

	# remove odd docs installed my make
	rm "${D}/usr/share/doc/${PF}/"{LICENSE,README.usage}

	insinto /usr/share/${PN}/contrib
	doins contrib/xmodmaprc
	doins contrib/xmodmap.sh
	if use perl; then
		doins contrib/testbindings.pl
	fi

	newconfd "${FILESDIR}/${PN}-1.2.7.confd" ${PN}
	newinitd "${FILESDIR}/${PN}-1.2.7-r2.initd" ${PN}
	dobin "${FILESDIR}/g15daemon-hotplug"
	insinto /etc/udev/rules.d
	doins "${FILESDIR}/99-g15daemon.rules"

	if use perl; then
		ebegin "Installing Perl Bindings (G15Daemon.pm)"
		cd "${WORKDIR}/G15Daemon-0.2"
		docinto perl
		perl-module_src_install
	fi

	if use python; then
		ebegin "Installing Python Bindings (g15daemon.py)"
		cd "${WORKDIR}/pyg15daemon"
		python_version

		insinto /usr/$(get_libdir)/python${PYVER}/site-packages/g15daemon
		doins g15daemon.py

		docinto python
		dodoc AUTHORS
	fi

	prepalldocs
}

pkg_postinst() {
	if use python; then
		python_version
		python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/g15daemon
		echo ""
	fi

	elog "To use g15daemon, you need to add g15daemon to the default runlevel."
	elog "This can be done with:"
	elog "# /sbin/rc-update add g15daemon default"
	elog "You can edit some g15daemon options at /etc/conf.d/g15daemon"
	elog ""
	elog "To have all new keys working in X11, you'll need create a "
	elog "specific xmodmap in your home directory or edit the existent one."
	elog ""
	elog "Create the xmodmap:"
	elog "cp /usr/share/g15daemon/contrib/xmodmaprc ~/.Xmodmap"
	elog ""
	elog "Adding keycodes to an existing xmodmap:"
	elog "cat /usr/share/g15daemon/contrib/xmodmaprc >> ~/.Xmodmap"
}

pkg_postrm() {
	if use python; then
		python_mod_cleanup "/usr/$(get_libdir)/python*/site-packages/g15daemon"
	fi
}