[gentoo-commits] proj/sci:master commit in: dev-python/numba/

[Aisha Tammy]

commit:     cfb477681ef2ce2506acffc31b7ae151973e213e
Author:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
AuthorDate: Tue Dec  1 23:14:31 2020 +0000
Commit:     Aisha Tammy <gentoo <AT> aisha <DOT> cc>
CommitDate: Tue Dec  1 23:14:40 2020 +0000
URL:        https://gitweb.gentoo.org/proj/sci.git/commit/?id=cfb47768

dev-python/numba: version bump to 0.52.0

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Aisha Tammy <gentoo <AT> aisha.cc>

 dev-python/numba/numba-0.52.0.ebuild | 69 ++++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)

diff --git a/dev-python/numba/numba-0.52.0.ebuild b/dev-python/numba/numba-0.52.0.ebuild
new file mode 100644
index 000000000..5625e679f
--- /dev/null
+++ b/dev-python/numba/numba-0.52.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit eutils multiprocessing distutils-r1
+
+DESCRIPTION="NumPy aware dynamic Python compiler using LLVM"
+HOMEPAGE="https://numba.pydata.org/
+	https://github.com/numba"
+SRC_URI="https://github.com/numba/numba/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="openmp threads"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-python/llvmlite-0.35.0[${PYTHON_USEDEP}]
+	<dev-python/llvmlite-0.36.0
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	threads? ( dev-cpp/tbb )
+"
+DEPEND="${RDEPEND}"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+distutils_enable_tests unittest
+
+# doc system is another huge mess, skip it
+PATCHES=(
+	"${FILESDIR}/${P}-skip_tests.patch"
+)
+
+pkg_setup() {
+	if ! use openmp; then
+		export NUMBA_DISABLE_OPENMP=1
+	else
+		unset NUMBA_DISABLE_OPENMP
+	fi
+	if ! use threads; then
+		export NUMBA_DISABLE_TBB=1
+	else
+		unset NUMBA_DISABLE_TBB
+		export TBBROOT="${EPREFIX}/usr"
+	fi
+}
+
+# https://numba.pydata.org/numba-doc/latest/developer/contributing.html?highlight=test#running-tests
+python_test() {
+	distutils_install_for_testing
+	${EPYTHON} setup.py build_ext --inplace || die \
+		"${EPYTHON} failed to build_ext"
+	${EPYTHON} runtests.py -m $(makeopts_jobs) || die \
+		"${EPYTHON} failed unittests"
+}
+
+# https://numba.pydata.org/numba-doc/latest/user/installing.html
+python_install_all() {
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "compile cuda code" dev-util/nvidia-cuda-sdk
+}