[gentoo-commits] gentoo-x86 commit in app-emulation/spim: spim-7.4.ebuild ChangeLog

[Ricardo Mendoza (ricmm)]

ricmm       09/03/24 03:02:16

  Modified:             ChangeLog
  Added:                spim-7.4.ebuild
  Log:
  Version bump. Released 22-01-2009. Several fixes to the code.
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 app-emulation/spim/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/spim/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/spim/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/spim/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/spim/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	23 Mar 2009 13:08:21 -0000	1.46
+++ ChangeLog	24 Mar 2009 03:02:16 -0000	1.47
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/spim
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/spim/ChangeLog,v 1.46 2009/03/23 13:08:21 ricmm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/spim/ChangeLog,v 1.47 2009/03/24 03:02:16 ricmm Exp $
+
+*spim-7.4 (24 Mar 2009)
+
+  24 Mar 2009; <ricmm@g.o> +spim-7.4.ebuild:
+  Version bump. Released 22-01-2009. Several fixes to the code.
 
   23 Mar 2009; <ricmm@g.o> metadata.xml:
   Adding myself to metadata.



1.1                  app-emulation/spim/spim-7.4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/spim/spim-7.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/spim/spim-7.4.ebuild?rev=1.1&content-type=text/plain

Index: spim-7.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/spim/spim-7.4.ebuild,v 1.1 2009/03/24 03:02:16 ricmm Exp $

inherit eutils toolchain-funcs

DESCRIPTION="MIPS Simulator"
HOMEPAGE="http://www.cs.wisc.edu/~larus/spim.html"
SRC_URI="http://www.cs.wisc.edu/~larus/SPIM/${P}.tar.gz"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="X"
RESTRICT="strip"
RDEPEND="X? ( x11-libs/libXaw
		x11-libs/libXp )"
DEPEND="${RDEPEND}
	X? ( x11-misc/imake
		x11-proto/xproto )
	>=sys-apps/sed-4
	sys-devel/bison"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Fix documentation files
	cd "${S}/Documentation"
	mv spim.man spim.1
	mv xspim.man xspim.1
}

src_compile() {
	cd "${S}/spim"

	./Configure || die "Configure Failed!"

	sed -i \
		-e 's:@make:@$(MAKE):' \
		-e 's:\(BIN_DIR = \).*$:\1\$(DESTDIR)/usr/bin:' \
		-e 's:\(MAN_DIR = \).*$:\1\$(DESTDIR)/usr/share/man:' \
		-e 's:\(EXCEPTION_DIR = \).*$:\1$(DESTDIR)/var/lib/spim:' \
		-e 's:\(^\W*install.*\) exceptions.s \(.*$\):\1 \$(CPU_DIR)/exceptions.s \2:' \
		-e "s:^\W*install.* spim.man .*$::" \
		-e "s:tail -2:tail -n2:" \
		Makefile

	emake CC="$(tc-getCC)" || die

	if use X ; then
		cd "${S}/xspim"

		./Configure || die "Configure Failed!"

		xmkmf || die

		sed -i \
			-e 's:@make:@$(MAKE):' \
			-e "s:\(BIN_DIR = \).*$:\1/usr/bin:" \
			-e "s:\(MAN_DIR = \).*$:\1/usr/share/man:" \
			-e "s:\(EXCEPTION_DIR = \).*$:\1/var/lib/spim:" \
			Makefile

		emake CC="$(tc-getCC)" -j1 xspim || die
	fi
}

src_test() {
	cd "${S}/spim"
	make test || die "Failed to pass tests!"
}

src_install() {
	dodir /usr/bin
	dodir /usr/share/man
	dodir /var/lib/spim

	cd "${S}/spim"
	make install DESTDIR="${D}" || die "Unable to install spim"

	if use X ; then
		cd "${S}/xspim"
		make DESTDIR="${D}" install || die "Unable to install xspim"
	fi

	cd "${S}/Documentation"
	doman spim.1
	use X && doman xspim.1

	dohtml SPIM.html
	dodoc BLURB

	cd "${S}"
	dodoc README VERSION ChangeLog
}