[gentoo-commits] repo/gentoo:master commit in: app-emulation/containers-storage/

[Zac Medico]

commit:     b8f2e61216e441b77e44fb62fed7d885b876a419
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Tue May 28 23:44:23 2019 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Wed May 29 00:28:35 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b8f2e612

app-emulation/libpod: version bump to 1.3.2

Package-Manager: Portage-2.3.67, Repoman-2.3.13
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-emulation/containers-storage/Manifest          |   2 +
 .../containers-storage-1.12.7.ebuild               | 110 +++++++++++++++++++++
 2 files changed, 112 insertions(+)

diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index e79f8888fe0..9a4450ee62a 100644
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1,2 +1,4 @@
 DIST containers-storage-0_pre20180730.tar.gz 1410155 BLAKE2B 24595693e9f5706130dd5e9bf38d11b2b267a64924cb854ad2d9db8c0a3d7c47fec5a00fa100be67ceaf35ea1a08fada7314d5fbe114fe7508f54e8bfc4f64b4 SHA512 25c5c3c16bb9f0da4e590cf658e56cc2ce1dbc81751f984b426b5e09a95ee816632b0267c8f3028254e88fcd39f5d087f0357862b34379180b33ff38d7028453
+DIST containers-storage-1.12.7.tar.gz 1562420 BLAKE2B 84b8f5a329aa191eb07bfab9e4b547e1a48cf5ff30b389f4b8f5aea702e5536cd420aeffb93cc0d15dcd33f3f0d1779f19fdfe2363b027ba3bb8e4776f411a78 SHA512 c0dc5aa32c3d439427ccd1721dd9d0b3119cd15b1cf65dc8079714a0df38e961084d090bb9cedd98a0e33c4d530ce898d885447974a86e024ec721d4f2900f34
 DIST github.com-pquerna-ffjson-af8b230fcd2007c7095168ca8ab94c68b60840c6.tar.gz 103474 BLAKE2B 66b456484cec51106e328a6d2c58a8597c1208956fca0c9f0ea45108b8d0942561882004a1ed5b90daa21509c9e0bc090dc9beed89b5a161f52ee8cf58e5d48f SHA512 243d8aed943dbadf3b127e07ad29a830ecded24aa80bb3bcc101db90ba8f3bfa03832e9d1f452e94b3eaccd683a044d0687a168e7e41979eb470442e689659c9
+DIST github.com-pquerna-ffjson-e517b90714f7c0eabe6d2e570a5886ae077d6db6.tar.gz 103470 BLAKE2B 81f0f6ea6648997cb61723d09d456802e60a3d1eb35134c4bbc8af5943b955b1402fe2b3f8d0d4d2d0293ab256a9be66d53262d5f79ca00bf8c18ded39dc44f4 SHA512 fadca5a7bd0c0578b23281720a08c505054f3497daeee8efa36b5acafa4118feb4b8a96c4acb4c279d72ebcd50846307cfbb846a355b62f350c961f9102c93a6

diff --git a/app-emulation/containers-storage/containers-storage-1.12.7.ebuild b/app-emulation/containers-storage/containers-storage-1.12.7.ebuild
new file mode 100644
index 00000000000..312d2cda060
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.12.7.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGO_VENDOR=(
+	"github.com/pquerna/ffjson e517b90714f7c0eabe6d2e570a5886ae077d6db6"
+)
+
+inherit golang-vcs-snapshot
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="btrfs +device-mapper ostree test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
+	${EGO_VENDOR_URI}"
+RDEPEND="
+	btrfs? ( sys-fs/btrfs-progs )
+	device-mapper? ( sys-fs/lvm2:= )
+	ostree? (
+		dev-libs/glib:=
+		dev-util/ostree:=
+	)"
+DEPEND="${RDEPEND}
+	dev-go/go-md2man
+	test? (
+		sys-fs/btrfs-progs
+		sys-fs/lvm2
+		sys-apps/util-linux
+	)"
+RESTRICT="test? ( userpriv ) !test? ( test )"
+
+src_unpack() {
+	golang-vcs-snapshot_src_unpack
+}
+
+src_prepare() {
+	default
+
+	[[ -f ${S}/src/${EGO_PN}/hack/btrfs_tag.sh ]] || die
+	use btrfs || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_btrfs" > \
+		"${S}/src/${EGO_PN}/hack/btrfs_tag.sh" || die; }
+
+	[[ -f ${S}/src/${EGO_PN}/hack/libdm_tag.sh ]] || die
+	use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+		"${S}/src/${EGO_PN}/hack/libdm_tag.sh" || die; }
+
+	[[ -f ${S}/src/${EGO_PN}/hack/ostree_tag.sh ]] || die
+	use ostree || { echo -e "#!/bin/sh\ntrue" > \
+		"${S}/src/${EGO_PN}/hack/ostree_tag.sh" || die; }
+
+	sed -e 's:TestChrootUntarPath(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/chrootarchive/archive_test.go" || die
+	sed -e 's:TestTarUntar(:_\0:' \
+		-e 's:TestTarWithOptionsChownOptsAlwaysOverridesIdPair(:_\0:' \
+		-e 's:TestTarWithOptions(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-e 's:TestTarWithBlockCharFifo(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_unix_test.go" || die
+	sed -e 's:TestTarUntarWithXattr(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/archive_test.go" || die
+	sed -e 's:TestApplyLayer(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/changes_test.go" || die
+	sed -e 's:TestApplyLayerInvalidFilenames(:_\0:' \
+		-e 's:TestApplyLayerInvalidHardlink(:_\0:' \
+		-e 's:TestApplyLayerInvalidSymlink(:_\0:' \
+		-e 's:TestApplyLayerWhiteouts(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/diff_test.go" || die
+	sed -e 's:TestCopyCaseE(:_\0:' \
+		-e 's:TestCopyCaseEFSym(:_\0:' \
+		-e 's:TestCopyCaseG(:_\0:' \
+		-e 's:TestCopyCaseGFSym(:_\0:' \
+		-e 's:TestCopyCaseH(:_\0:' \
+		-e 's:TestCopyCaseHFSym(:_\0:' \
+		-e 's:TestCopyCaseJ(:_\0:' \
+		-e 's:TestCopyCaseJFSym(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/archive/copy_unix_test.go" || die
+	sed -e 's:TestMount(:_\0:' \
+		-i "${S}/src/${EGO_PN}/pkg/mount/mounter_linux_test.go" || die
+}
+
+src_compile() {
+	export -n GOCACHE XDG_CACHE_HOME #678856
+	mkdir -p "${S}/src/github.com/pquerna" || die
+	ln -s "${S}/src/${EGO_PN}/vendor/github.com/pquerna/ffjson" "${WORKDIR}/${P}/src/github.com/pquerna/ffjson" || die
+	mkdir -p "${S}/bin" || die
+	cd "${S}/bin" || die
+	GOPATH="${S}" GOBIN="${S}/bin" \
+		go build -v -work -x ${EGO_BUILD_FLAGS} "${S}/src/github.com/pquerna/ffjson/ffjson.go" || die
+	GOPATH="${S}" GOBIN="${S}/bin" PATH="${S}/bin:${PATH}" \
+		emake -C "${S}/src/${EGO_PN}" containers-storage docs
+}
+
+src_install() {
+	dobin "${S}/src/${EGO_PN}/${PN}"
+	while read -r -d ''; do
+		mv "${REPLY}" "${REPLY%.1}" || die
+	done < <(find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]].1' -print0)
+	find "${S}/src/${EGO_PN}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+	GOPATH="${S}" unshare -m emake -C "${S}/src/${EGO_PN}" FLAGS="-v -work -x" local-test-unit || die
+}