[gentoo-commits] repo/gentoo:master commit in: media-gfx/openmesh/

[Andreas Sturmlechner]

commit:     d43fb8547092b8eccc9bff3dc808a94ec8d4b38e
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Jun 30 22:23:08 2018 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Jul  1 00:03:38 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d43fb854

media-gfx/openmesh: 7.1 version bump

Package-Manager: Portage-2.3.41, Repoman-2.3.9

 media-gfx/openmesh/Manifest            |  1 +
 media-gfx/openmesh/openmesh-7.1.ebuild | 65 ++++++++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)

diff --git a/media-gfx/openmesh/Manifest b/media-gfx/openmesh/Manifest
index cd07906d10c..a3be678b328 100644
--- a/media-gfx/openmesh/Manifest
+++ b/media-gfx/openmesh/Manifest
@@ -1 +1,2 @@
 DIST OpenMesh-4.1.tar.bz2 24728164 BLAKE2B 6be9876fccc8dbf53b6dddbaac09a3f241b2cffbcd98473f0f7caca23b634bdb0a0a8af808a178531c61e5d533597a4fd467b8b2928d9947a7f126990a4ee42a SHA512 064a4d5cb467589869baf4a302e6c620bd84de874b24019252b97ef863b59e83f2fe23ea45e4a5162a7765847da19f75f563f084cf2b3ae77c7e704b4c859b71
+DIST OpenMesh-7.1.tar.bz2 22855582 BLAKE2B 778b3a40c2e476cdb2f50b5b4a90f8b6ae7852f166087426ff1db25c829cb4172cd7ed14db1a22229f7b4447e7ebeb0d6116647d929b7dab43d565192a8ac48e SHA512 bca0f937e08fe512efb436f5b96b83a1ff7945640e18fb1bb083956f04609560e29b1c1f7e058840791df77df6859fdd20ff6f49d80b908e8c1c5542b8615e6d

diff --git a/media-gfx/openmesh/openmesh-7.1.ebuild b/media-gfx/openmesh/openmesh-7.1.ebuild
new file mode 100644
index 00000000000..9cc6fc78dcc
--- /dev/null
+++ b/media-gfx/openmesh/openmesh-7.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+MY_PN="OpenMesh"
+MY_PV="${PV/_rc/-RC}"
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+DESCRIPTION="A generic data structure to represent and manipulate polygonal meshes"
+HOMEPAGE="https://www.openmesh.org/"
+SRC_URI="https://openmesh.org/media/Releases/${MY_PV/-RC/RC}/${MY_PN}-${MY_PV}.tar.bz2"
+
+LICENSE="BSD"
+SLOT="4"
+KEYWORDS="~amd64 ~ia64 ~x86"
+IUSE="qt5 static-libs test"
+
+RDEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtopengl:5
+		dev-qt/qtwidgets:5
+		media-libs/freeglut
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Fix libdir and remove rpath.
+	sed -i \
+		-e "s|\(set (ACG_PROJECT_LIBDIR \"\).*|\1$(get_libdir)/\")|" \
+		-e "s|\(BUILD_WITH_INSTALL_RPATH \)1|\1 0|" \
+		-e "s|\(SKIP_BUILD_RPATH\) 0|\1 1|" \
+		-e '/^ *INSTALL_RPATH/d' \
+		cmake/ACGCommon.cmake || die
+
+	if ! use static-libs; then
+		sed -i "s|\(SHARED\)ANDSTATIC|\1|" \
+			src/${MY_PN}/{Core,Tools}/CMakeLists.txt || die
+		sed -i '/OpenMeshCoreStatic/d' \
+			src/${MY_PN}/Tools/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_APPS=$(usex qt5)
+		-DOPENMESH_BUILD_UNIT_TESTS=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	LD_LIBRARY_PATH=${LD_LIBRARY_PATH}:${BUILD_DIR}/Build/$(get_libdir) ctest --verbose
+}