[gentoo-commits] gentoo-x86 commit in gnome-extra/gnome-power-manager: metadata.xml ChangeLog gnome-power-manager-2.32.0-r1.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/05/08 14:24:12

  Modified:             metadata.xml ChangeLog
  Added:                gnome-power-manager-2.32.0-r1.ebuild
  Log:
  Make applet support optional, bug #354399.
  
  (Portage version: 2.2.0_alpha30/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  gnome-extra/gnome-power-manager/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	24 Oct 2010 20:07:48 -0000	1.5
+++ metadata.xml	8 May 2011 14:24:12 -0000	1.6
@@ -6,5 +6,8 @@
 		Power Manager daemon for the GNOME desktop environment that makes it
 		easy to manage your laptop or desktop system.
 	</longdescription>
+	<use>
+		<flag name='applet'>Build battery monitor applet</flag>
+	</use>
 </pkgmetadata>
 



1.154                gnome-extra/gnome-power-manager/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.154&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?rev=1.154&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog?r1=1.153&r2=1.154

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v
retrieving revision 1.153
retrieving revision 1.154
diff -u -r1.153 -r1.154
--- ChangeLog	22 Mar 2011 19:26:20 -0000	1.153
+++ ChangeLog	8 May 2011 14:24:12 -0000	1.154
@@ -1,6 +1,12 @@
 # ChangeLog for gnome-extra/gnome-power-manager
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.153 2011/03/22 19:26:20 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/ChangeLog,v 1.154 2011/05/08 14:24:12 eva Exp $
+
+*gnome-power-manager-2.32.0-r1 (08 May 2011)
+
+  08 May 2011; Gilles Dartiguelongue <eva@g.o>
+  +gnome-power-manager-2.32.0-r1.ebuild, metadata.xml:
+  Make applet support optional, bug #354399.
 
   22 Mar 2011; Brent Baude <ranger@g.o>
   gnome-power-manager-2.32.0.ebuild:



1.1                  gnome-extra/gnome-power-manager/gnome-power-manager-2.32.0-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.32.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.32.0-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-power-manager-2.32.0-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gnome-power-manager/gnome-power-manager-2.32.0-r1.ebuild,v 1.1 2011/05/08 14:24:12 eva Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit autotools eutils gnome2 virtualx

DESCRIPTION="Gnome Power Manager"
HOMEPAGE="http://www.gnome.org/projects/gnome-power-manager/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="+applet doc policykit test"

# FIXME: Interactive testsuite (upstream ? I'm so...pessimistic)
RESTRICT="test"

COMMON_DEPEND=">=dev-libs/glib-2.13.0:2
	>=x11-libs/gtk+-2.17.7:2
	>=gnome-base/gnome-keyring-0.6.0
	>=dev-libs/dbus-glib-0.71
	>=x11-libs/libnotify-0.4.3
	>=x11-libs/libwnck-2.10.0:1
	>=x11-libs/cairo-1
	>=gnome-base/gconf-2.10:2[policykit?]
	>=media-libs/libcanberra-0.10[gtk]
	>=sys-power/upower-0.9.1
	>=dev-libs/libunique-1.1:1
	>=x11-apps/xrandr-1.3
	>=x11-proto/xproto-7.0.15
	x11-libs/libX11
	x11-libs/libXext
	applet? (
		|| ( gnome-base/gnome-panel[bonobo] <gnome-base/gnome-panel-2.32 )
	)
"
RDEPEND="${COMMON_DEPEND}
	>=sys-auth/consolekit-0.4[policykit?]
	policykit? ( gnome-extra/polkit-gnome )"
DEPEND="${COMMON_DEPEND}
	x11-proto/randrproto

	sys-devel/gettext
	app-text/scrollkeeper
	app-text/docbook-xml-dtd:4.3
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.35
	>=app-text/gnome-doc-utils-0.3.2
	doc? (
		app-text/xmlto
		app-text/docbook-sgml-utils
		app-text/docbook-xml-dtd:4.4
		app-text/docbook-sgml-dtd:4.1
		app-text/docbook-xml-dtd:4.1.2 )"

# docbook-sgml-utils and docbook-sgml-dtd-4.1 used for creating man pages
# (files under ${S}/man).
# docbook-xml-dtd-4.4 and -4.1.2 are used by the xml files under ${S}/docs.

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_enable applet applets)
		$(use_enable doc docbook-docs)
		$(use_enable policykit gconf-defaults)
		$(use_enable test tests)
		--enable-compile-warnings=minimum"
	DOCS="AUTHORS ChangeLog NEWS README TODO"
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-libnotify-0.7.patch

	gnome2_src_prepare

	# Fix intltoolize broken file, see upstream #577133
	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
		|| die "sed libtoolize failed"

	# Drop debugger CFLAGS from configure
	sed -e 's:^CPPFLAGS="$CPPFLAGS -g"$::g' \
		-i configure.ac configure || die "debugger sed failed"

	# glibc splits this out, whereas other libc's do not tend to
	if use elibc_glibc; then
		sed -e 's/-lresolv//' \
			-i configure.ac configure || die "resolv sed failed"
	fi

	# FIXME: This is required to prevent maintainer mode after "debugger sed"
	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf

	# This needs to be after eautoreconf to prevent problems like bug #356277
	if ! use doc; then
		# Remove the docbook2man rules here since it's not handled by a proper
		# parameter in configure.in.
		sed -e 's:@HAVE_DOCBOOK2MAN_TRUE@.*::' -i man/Makefile.in \
			|| die "docbook sed failed"
	fi
}

src_test() {
	unset DBUS_SESSION_BUS_ADDRESS
	dbus-launch Xemake check || die "Test phase failed"
}