[gentoo-commits] repo/gentoo:master commit in: sys-fs/lessfs/

[Pacho Ramos]

commit:     9b33692ee4ef7200b8fc8aac14997859677f184b
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 12 10:18:48 2019 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sat Jan 12 10:18:48 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9b33692e

sys-fs/lessfs: Fix deps and homepage

Closes: https://bugs.gentoo.org/671806
Closes: https://bugs.gentoo.org/673648
Package-Manager: Portage-2.3.53, Repoman-2.3.12
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 sys-fs/lessfs/lessfs-1.7.0-r1.ebuild | 55 ++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/sys-fs/lessfs/lessfs-1.7.0-r1.ebuild b/sys-fs/lessfs/lessfs-1.7.0-r1.ebuild
new file mode 100644
index 00000000000..f0b3e0a95f0
--- /dev/null
+++ b/sys-fs/lessfs/lessfs-1.7.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit readme.gentoo-r1
+
+MY_PV="${PV/_/-}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="A high performance inline data deduplicating filesystem"
+HOMEPAGE="https://sourceforge.net/projects/lessfs/"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/${MY_P}/${MY_P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="berkdb crypt debug filelog memtrace lzo snappy"
+
+RDEPEND="
+	berkdb? ( sys-libs/db:* )
+	crypt? ( dev-libs/openssl:0= )
+	lzo? ( dev-libs/lzo )
+	snappy? ( app-arch/snappy )
+	>=dev-db/tokyocabinet-1.4.42
+	app-crypt/mhash
+	>=sys-fs/fuse-2.8.0:0=
+"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+DOC_CONTENTS="Default configuration file: /etc/${PN}.cfg.
+	If your host is a client consult the following configuration
+	file: /usr/share/doc/${PF}/${PN}.cfg-slave.*"
+
+src_configure() {
+	econf \
+		$(use_enable debug) $(use_enable debug lckdebug) \
+		$(use_enable filelog) $(use_with crypt crypto) \
+		$(use_with lzo) $(use_enable memtrace) \
+		$(use_with berkdb berkeleydb) \
+		$(use_with snappy)
+}
+
+src_install () {
+	default
+	insinto /etc
+	newins examples/lessfs.cfg-master ${PN}.cfg
+	dodoc examples/lessfs.* etc/lessfs.*
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}