[gentoo-commits] repo/gentoo:master commit in: gnome-extra/assogiate/

[Gilles Dartiguelongue]

commit:     6bcd3e096b3a2489162b40452b2fd812991f0084
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 23 23:15:01 2015 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Wed Dec 23 23:15:01 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6bcd3e09

gnome-extra/assogiate: depend on C++11 enabled packages and use it as std, bug #569142

Package-Manager: portage-2.2.26

 gnome-extra/assogiate/assogiate-0.2.1-r1.ebuild | 51 +++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

diff --git a/gnome-extra/assogiate/assogiate-0.2.1-r1.ebuild b/gnome-extra/assogiate/assogiate-0.2.1-r1.ebuild
new file mode 100644
index 0000000..900100e
--- /dev/null
+++ b/gnome-extra/assogiate/assogiate-0.2.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="yes"
+
+inherit autotools eutils flag-o-matic gnome2
+
+DESCRIPTION="assoGiate is an editor of the file types database for GNOME"
+HOMEPAGE="http://www.kdau.com/projects/assogiate"
+SRC_URI="http://www.kdau.com/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.8:2
+	>=dev-cpp/glibmm-2.46:2
+	>=dev-cpp/gtkmm-2.24.4-r3:2.4
+	>=dev-cpp/libxmlpp-2.40
+	>=dev-cpp/gnome-vfsmm-2.26.0-r1
+"
+DEPEND="${RDEPEND}
+	app-text/gnome-doc-utils
+	dev-util/intltool
+	virtual/pkgconfig
+"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+src_prepare() {
+	# Fix desktop file
+	epatch "${FILESDIR}"/${P}-desktop.patch
+
+	# Fix compilation, bug #374911
+	epatch "${FILESDIR}"/${P}-typedialog.patch
+
+	# Fix building with glib-2.32, bug #417765
+	epatch "${FILESDIR}"/${P}-glib-2.32.patch
+
+	# Fix building with gcc-4.7
+	epatch "${FILESDIR}"/${P}-gcc-4.7.patch
+
+	eautoreconf
+	gnome2_src_prepare
+
+	append-cxxflags -std=c++11
+}