[gentoo-commits] repo/gentoo:master commit in: sys-apps/acl/

[Mike Gilbert]

commit:     1aed846710e5368ac390530b31e6854fa02a8489
Author:     David Michael <fedora.dm0 <AT> gmail <DOT> com>
AuthorDate: Thu Sep  3 12:40:33 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Mon Sep  7 20:44:00 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1aed8467

sys-apps/acl: EAPI 7

Closes: https://bugs.gentoo.org/739302
Package-Manager: Portage-3.0.4, Repoman-2.3.23
Signed-off-by: David Michael <fedora.dm0 <AT> gmail.com>
Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 sys-apps/acl/acl-2.2.53-r1.ebuild | 55 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/sys-apps/acl/acl-2.2.53-r1.ebuild b/sys-apps/acl/acl-2.2.53-r1.ebuild
new file mode 100644
index 00000000000..4965f72787c
--- /dev/null
+++ b/sys-apps/acl/acl-2.2.53-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic libtool toolchain-funcs multilib-minimal usr-ldscript
+
+DESCRIPTION="access control list utilities, libraries and headers"
+HOMEPAGE="https://savannah.nongnu.org/projects/acl"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls static-libs"
+
+RDEPEND="
+	>=sys-apps/attr-2.4.47-r1[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	# filter out -flto flags as they break getfacl/setfacl binaries
+	# (bug #667372)
+	filter-flags -flto*
+}
+
+src_prepare() {
+	default
+	elibtoolize #580792
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/bin
+		$(use_enable static-libs static)
+		--libexecdir="${EPREFIX}"/usr/$(get_libdir)
+		$(use_enable nls)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	default
+
+	# move shared libs to /
+	gen_usr_ldscript -a acl
+}
+
+multilib_src_install_all() {
+	if ! use static-libs ; then
+		find "${ED}" -type f -name "*.la" -delete || die
+	fi
+}