[gentoo-commits] gentoo-x86 commit in net-mail/libpst: libpst-0.6.55.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     12/08/27 09:31:59

  Modified:             ChangeLog
  Added:                libpst-0.6.55.ebuild
  Log:
  Bump
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.34                 net-mail/libpst/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/ChangeLog?r1=1.33&r2=1.34

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog	28 Jun 2012 10:40:11 -0000	1.33
+++ ChangeLog	27 Aug 2012 09:31:59 -0000	1.34
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/libpst
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v 1.33 2012/06/28 10:40:11 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/ChangeLog,v 1.34 2012/08/27 09:31:59 patrick Exp $
+
+*libpst-0.6.55 (27 Aug 2012)
+
+  27 Aug 2012; Patrick Lauer <patrick@g.o> +libpst-0.6.55.ebuild:
+  Bump
 
   28 Jun 2012; Agostino Sarubbo <ago@g.o> libpst-0.6.54-r1.ebuild:
   Stable for amd64, wrt bug #420885
@@ -148,4 +153,3 @@
   05 Mar 2004; Patrick Kursawe <phosphan@g.o> libpst-0.3.4.ebuild,
   metadata.xml:
   Initial import
-



1.1                  net-mail/libpst/libpst-0.6.55.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/libpst-0.6.55.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/libpst/libpst-0.6.55.ebuild?rev=1.1&content-type=text/plain

Index: libpst-0.6.55.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/libpst/libpst-0.6.55.ebuild,v 1.1 2012/08/27 09:31:59 patrick Exp $

EAPI=4
PYTHON_DEPEND="python? 2"

inherit autotools eutils python

DESCRIPTION="Tools and library for reading Outlook files (.pst format)"
HOMEPAGE="http://www.five-ten-sg.com/libpst/"
SRC_URI="http://www.five-ten-sg.com/${PN}/packages/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug dii doc python static-libs"

RDEPEND="dii? ( media-gfx/imagemagick[png] )"
DEPEND="${RDEPEND}
	virtual/libiconv
	virtual/pkgconfig
	dii? ( media-libs/gd[png] )
	python? ( >=dev-libs/boost-1.48[python] )"

pkg_setup() {
	if use python; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# don't build the static python library
	epatch "${FILESDIR}"/${PN}-0.6.52-no-static-python-lib.patch

	# fix pkgconfig file for static linking
	epatch "${FILESDIR}"/${PN}-0.6.53-pkgconfig-static.patch

	# conditionally install the extra documentation
	use doc || { sed -i -e "/SUBDIRS/s: html::" Makefile.am || die; }

	# don't install duplicate docs
	sed -i -e "/^html_DATA =/d" Makefile.am || die

	eautoreconf
}

src_configure() {
	econf \
		--enable-libpst-shared \
		$(use_enable debug pst-debug) \
		$(use_enable dii) \
		$(use_enable python) \
		$(use_enable static-libs static) \
		$(use python && echo --with-boost-python=boost_python-${PYTHON_ABI})
}

src_install() {
	default
	prune_libtool_files --all
}