[gentoo-commits] gentoo-x86 commit in app-text/djview: djview-4.7.ebuild metadata.xml ChangeLog

[Peter Volkov (pva)]

pva         11/04/30 20:24:04

  Added:                djview-4.7.ebuild metadata.xml ChangeLog
  Log:
  New name for djview4. Version bump. Fixes bug #357817 thank pavel sanda for report.
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  app-text/djview/djview-4.7.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/djview-4.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/djview-4.7.ebuild?rev=1.1&content-type=text/plain

Index: djview-4.7.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/djview/djview-4.7.ebuild,v 1.1 2011/04/30 20:24:04 pva Exp $

EAPI="4"

inherit eutils autotools versionator toolchain-funcs multilib nsplugins fdo-mime flag-o-matic

MY_P=${PN}-$(replace_version_separator 2 '-')

DESCRIPTION="Portable DjVu viewer using Qt4"
HOMEPAGE="http://djvu.sourceforge.net/djview4.html"
SRC_URI="mirror://sourceforge/djvu/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
IUSE="debug nsplugin"

RDEPEND="
	>=app-text/djvu-3.5.22-r1
	x11-libs/qt-gui:4
	!!app-text/djview4"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nsplugin? ( dev-libs/glib:2 )"

S=${WORKDIR}/${PN}-$(get_version_component_range 1-2)

src_prepare() {
	# Force XEmbed instead of Xt-based mainloop (disable Xt autodep)
	sed -e 's:\(ac_xt=\)yes:\1no:' -i configure* || die
	sed 's/AC_CXX_OPTIMIZE/OPTS=;AC_SUBST(OPTS)/' -i configure.ac || die #263688
	rm aclocal.m4 config/{libtool.m4,install-sh,ltmain.sh,lt*.m4}
	AT_M4DIR="config" eautoreconf
}

src_configure() {
	# See config/acinclude.m4
	use debug || append-cppflags "-DNDEBUG"

	# QTDIR is needed because of kde3
	QTDIR=/usr \
	econf \
		--with-x \
		$(use_enable nsplugin nsdejavu) \
		--disable-desktopfiles
}

src_compile() {
	emake CC=$(tc-getCC) CXX=$(tc-getCXX)
}

src_install() {
	emake DESTDIR="${D}" \
		plugindir=/usr/$(get_libdir)/${PLUGINS_DIR} \
			install

	dodoc README NEWS

	cd desktopfiles
	insinto /usr/share/icons/hicolor/32x32/apps
	newins hi32-djview4.png djvulibre-djview4.png
	insinto /usr/share/icons/hicolor/64x64/apps
	newins hi64-djview4.png djvulibre-djview4.png
	insinto /usr/share/icons/hicolor/scalable/apps
	newins djview.svg djvulibre-djview4.svg
	domenu djvulibre-djview4.desktop
}

pkg_postinst() {
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	fdo-mime_desktop_database_update
}



1.1                  app-text/djview/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>tex</herd>
<maintainer>
	<email>pva@g.o</email>
	<name>Peter Volkov</name>
</maintainer>
</pkgmetadata>



1.1                  app-text/djview/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/djview/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for app-text/djview
# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/app-text/djview/ChangeLog,v 1.1 2011/04/30 20:24:04 pva Exp $

*djview-4.7 (30 Apr 2011)

  30 Apr 2011; Peter Volkov <pva@g.o> +djview-4.7.ebuild, +metadata.xml:
  New name for djview4. Version bump. Fixes bug #357817 thank pavel sanda for
  report.