[gentoo-commits] gentoo-x86 commit in net-im/err: metadata.xml ChangeLog err-1.7.1.ebuild err-1.6.1.ebuild err-1.3.1-r1.ebuild err-1.5.1-r1.ebuild

[Sergey Popov (pinkbyte)]

pinkbyte    13/10/05 16:24:15

  Modified:             metadata.xml ChangeLog
  Added:                err-1.7.1.ebuild
  Removed:              err-1.6.1.ebuild err-1.3.1-r1.ebuild
                        err-1.5.1-r1.ebuild
  Log:
  Version bump: EAPI 5, migrate to distutils-r1, optional dependencies for IRC backend. Drop old versions
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

Revision  Changes    Path
1.5                  net-im/err/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/err/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	3 Apr 2013 10:35:34 -0000	1.4
+++ metadata.xml	5 Oct 2013 16:24:15 -0000	1.5
@@ -6,6 +6,7 @@
 		<name>Sergey Popov</name>
 	</maintainer>
 	<use>
+		<flag name="irc">Pull optional dependencies, needed for IRC backend</flag>
 		<flag name="plugins">Enable support for installing plugins with <pkg>dev-vcs/git</pkg></flag>
 	</use>
 	<upstream>



1.14                 net-im/err/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-im/err/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	17 Apr 2013 07:24:39 -0000	1.13
+++ ChangeLog	5 Oct 2013 16:24:15 -0000	1.14
@@ -1,6 +1,13 @@
 # ChangeLog for net-im/err
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-im/err/ChangeLog,v 1.13 2013/04/17 07:24:39 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-im/err/ChangeLog,v 1.14 2013/10/05 16:24:15 pinkbyte Exp $
+
+*err-1.7.1 (05 Oct 2013)
+
+  05 Oct 2013; Sergey Popov <pinkbyte@g.o> -err-1.3.1-r1.ebuild,
+  -err-1.5.1-r1.ebuild, -err-1.6.1.ebuild, +err-1.7.1.ebuild, metadata.xml:
+  Version bump: EAPI 5, migrate to distutils-r1, optional dependencies for IRC
+  backend. Drop old versions
 
   17 Apr 2013; Sergey Popov <pinkbyte@g.o> err-1.3.1-r1.ebuild,
   err-1.5.1-r1.ebuild, err-1.6.1.ebuild:



1.1                  net-im/err/err-1.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/err-1.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-im/err/err-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: err-1.7.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-im/err/err-1.7.1.ebuild,v 1.1 2013/10/05 16:24:15 pinkbyte Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 )
inherit distutils-r1 eutils user

DESCRIPTION="Plugin based XMPP chatbot designed to be easily deployable, extensible and maintainable"
HOMEPAGE="http://gbin.github.com/err/"

SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
LICENSE="GPL-3"
SLOT="0"
IUSE="irc qt4 +plugins"

DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
RDEPEND="dev-python/dnspython[${PYTHON_USEDEP}]
	dev-python/flask[${PYTHON_USEDEP}]
	dev-python/jinja[${PYTHON_USEDEP}]
	dev-python/pyfire[${PYTHON_USEDEP}]
	dev-python/python-daemon[${PYTHON_USEDEP}]
	dev-python/xmpppy
	dev-python/yapsy[${PYTHON_USEDEP}]
	irc? (
		dev-python/pyopenssl[${PYTHON_USEDEP}]
		dev-python/twisted-core[${PYTHON_USEDEP}]
		dev-python/twisted-words[${PYTHON_USEDEP}]
	)
	qt4? ( dev-python/pyside[${PYTHON_USEDEP},X,webkit] )
	plugins? ( dev-vcs/git )"

# Testsuite is broken since 1.6.3
RESTRICT="test"

# NOTES:
# 1. It has bundled libs - for example exrex(see 'errbot/bundled' subfolder)
# 2. Need to add PYTHON_USEDEP to remaining dev-python/ deps
# 3. Support for BOT_SENTRY option is missing, cause
#    we do not have apropriate packages in portage yet
# 4. Internal web server is broken(dunno why :-()

pkg_setup() {
	ebegin "Creating err group and user"
	enewgroup 'err'
	enewuser 'err' -1 -1 -1 'err'
	eend ${?}
}

python_prepare_all() {
	# Remove configparser and config from requirements as they are NOT needed
	sed -i \
		-e "/install_requires/s/'configparser', //" \
		-e "/install_requires/s/, 'config'//" \
		setup.py || die

	# Tests are broken and should not be installed
	rm -r tests || die

	distutils-r1_python_prepare_all
}

python_install_all() {
	distutils-r1_python_install_all

	newinitd "${FILESDIR}"/errd.initd errd
	newconfd "${FILESDIR}"/errd.confd errd

	dodir /etc/${PN}
	dodir /var/lib/${PN}
	keepdir /var/log/${PN}
	fowners -R err:err /var/lib/${PN}
	fowners -R err:err /var/log/${PN}

	insinto /etc/${PN}
	newins errbot/config-template.py config.py
}

python_install() {
	distutils-r1_python_install

	# Upstream requires images to be in site-packages directory,
	# but does not install them at all!
	if use qt4; then
		local python_moduleroot=errbot
		python_domodule errbot/*.svg
	fi
}