[gentoo-commits] gentoo-x86 commit in sci-biology/velvet: ChangeLog velvet-1.2.10.ebuild

[Justin Lecher (jlec)]

jlec        13/12/28 23:19:35

  Modified:             ChangeLog
  Added:                velvet-1.2.10.ebuild
  Log:
  sci-biology/velvet: Import Version BUmp from sci overlay, thanks mahn for the ebuild, #495094
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

Revision  Changes    Path
1.21                 sci-biology/velvet/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/velvet/ChangeLog?rev=1.21&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/velvet/ChangeLog?rev=1.21&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/velvet/ChangeLog?r1=1.20&r2=1.21

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-biology/velvet/ChangeLog,v
retrieving revision 1.20
retrieving revision 1.21
diff -u -r1.20 -r1.21
--- ChangeLog	12 Mar 2013 12:13:48 -0000	1.20
+++ ChangeLog	28 Dec 2013 23:19:35 -0000	1.21
@@ -1,6 +1,11 @@
 # ChangeLog for sci-biology/velvet
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-biology/velvet/ChangeLog,v 1.20 2013/03/12 12:13:48 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-biology/velvet/ChangeLog,v 1.21 2013/12/28 23:19:35 jlec Exp $
+
+*velvet-1.2.10 (28 Dec 2013)
+
+  28 Dec 2013; Justin Lecher <jlec@g.o> +velvet-1.2.10.ebuild:
+  Import Version BUmp from sci overlay, thanks mahn for the ebuild, #495094
 
   12 Mar 2013; Justin Lecher <jlec@g.o> metadata.xml:
   Drop Andrey as maintainer so that bugs get assigned to sci-biology directly



1.1                  sci-biology/velvet/velvet-1.2.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/velvet/velvet-1.2.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-biology/velvet/velvet-1.2.10.ebuild?rev=1.1&content-type=text/plain

Index: velvet-1.2.10.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-biology/velvet/velvet-1.2.10.ebuild,v 1.1 2013/12/28 23:19:35 jlec Exp $

EAPI=5

inherit eutils flag-o-matic toolchain-funcs

MY_P=${PN}_${PV}

DESCRIPTION="A sequence assembler for very short reads"
HOMEPAGE="http://www.ebi.ac.uk/~zerbino/velvet/"
SRC_URI="http://www.ebi.ac.uk/~zerbino/velvet/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc openmp"

RDEPEND=""
DEPEND="${RDEPEND}
	doc? ( virtual/latex-base )"

S="${WORKDIR}"/${MY_P}

src_prepare() {
	if ! use doc; then
		sed -i -e '/default :/ s/doc//' "${S}"/Makefile || die
	fi
	elog "Upstream recommendes using -O3 in CFLAGS"
	echo
	elog "To adjust the MAXKMERLENGTH or CATEGORIES parameters as described in the manual,"
	elog "please set the variables VELVET_MAXKMERLENGTH or VELVET_CATEGORIES in your"
	elog "environment or /etc/make.conf, then re-emerge the package. For example:"
	elog "  VELVET_MAXKMERLENGTH=NN emerge [options] velvet"
	MAKEOPTS+=" -j1"

	if [[ $(tc-getCC) =~ gcc ]]; then
		local eopenmp=-fopenmp
	elif [[ $(tc-getCC) =~ icc ]]; then
		local eopenmp=-openmp
	else
		elog "Cannot detect compiler type so not setting openmp support"
	fi
	append-flags -fPIC ${eopenmp}
	append-ldflags ${eopenmp}

	tc-export CC

	MAKE_XOPTS=(
		CC=$(tc-getCC)
		CFLAGS="${CFLAGS}"
		OPT="${CFLAGS}"
	)
	if [[ ${VELVET_MAXKMERLENGTH} != "" ]]; then MAKE_XOPTS+=( MAXKMERLENGTH=${VELVET_MAXKMERLENGTH} ); fi
	if [[ ${VELVET_CATEGORIES} != "" ]]; then MAKE_XOPTS+=( CATEGORIES=${VELVET_CATEGORIES} ); fi
}

src_compile() {
	emake "${MAKE_XOPTS[@]}"
	emake "${MAKE_XOPTS[@]}" color
}

src_test() {
	emake "${MAKE_XOPTS[@]}" test
}

src_install() {
	dobin velvet{g,h,g_de,h_de}
	insinto /usr/share/${PN}
	doins -r contrib
	dodoc Manual.pdf CREDITS.txt ChangeLog
}