[gentoo-commits] gentoo-x86 commit in sys-apps/util-linux: util-linux-2.20.ebuild ChangeLog util-linux-9999.ebuild

[Mike Frysinger (vapier)]

vapier      11/08/29 21:25:15

  Modified:             ChangeLog util-linux-9999.ebuild
  Added:                util-linux-2.20.ebuild
  Log:
  Version bump which fixes #373381 by Chris Richards.  Add USE=static-libs support #378269 by Agostino Sarubbo.  Sync changes between live git and stable release ebuilds.  Block older sysvinits since we now install the mountpoint util ourselves.
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.348                sys-apps/util-linux/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.348&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/ChangeLog?rev=1.348&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/ChangeLog?r1=1.347&r2=1.348

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v
retrieving revision 1.347
retrieving revision 1.348
diff -u -r1.347 -r1.348
--- ChangeLog	29 Jul 2011 07:42:14 -0000	1.347
+++ ChangeLog	29 Aug 2011 21:25:15 -0000	1.348
@@ -1,6 +1,15 @@
 # ChangeLog for sys-apps/util-linux
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.347 2011/07/29 07:42:14 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.348 2011/08/29 21:25:15 vapier Exp $
+
+*util-linux-2.20 (29 Aug 2011)
+
+  29 Aug 2011; Mike Frysinger <vapier@g.o> +util-linux-2.20.ebuild,
+  util-linux-9999.ebuild:
+  Version bump which fixes #373381 by Chris Richards. Add USE=static-libs
+  support #378269 by Agostino Sarubbo. Sync changes between live git and stable
+  release ebuilds. Block older sysvinits since we now install the mountpoint
+  util ourselves.
 
   29 Jul 2011; Zac Medico <zmedico@g.o> util-linux-2.19.1-r1.ebuild,
   util-linux-9999.ebuild:



1.22                 sys-apps/util-linux/util-linux-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild?r1=1.21&r2=1.22

Index: util-linux-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- util-linux-9999.ebuild	29 Jul 2011 07:42:14 -0000	1.21
+++ util-linux-9999.ebuild	29 Aug 2011 21:25:15 -0000	1.22
@@ -1,8 +1,8 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild,v 1.21 2011/07/29 07:42:14 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-9999.ebuild,v 1.22 2011/08/29 21:25:15 vapier Exp $
 
-EAPI="2"
+EAPI="3"
 
 EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
 inherit eutils toolchain-funcs libtool flag-o-matic
@@ -18,16 +18,18 @@
 	SRC_URI=""
 	#KEYWORDS=""
 else
-	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.bz2"
+	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.bz2
+		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-2.19.1-20110510.diff.bz2 )"
 	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-linux"
 fi
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="+cramfs crypt ncurses nls old-linux perl selinux slang uclibc unicode"
+IUSE="+cramfs crypt loop-aes ncurses nls old-linux perl selinux slang static-libs uclibc unicode"
 
 RDEPEND="!sys-process/schedutils
 	!sys-apps/setarch
+	!<sys-apps/sysvinit-2.88-r3
 	!<sys-libs/e2fsprogs-libs-1.41.8
 	!<sys-fs/e2fsprogs-1.41.8
 	cramfs? ( sys-libs/zlib )
@@ -44,6 +46,8 @@
 		po/update-potfiles
 		autopoint --force
 		eautoreconf
+	else
+		use loop-aes && epatch "${WORKDIR}"/util-linux-*.diff
 	fi
 	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
 	elibtoolize
@@ -72,7 +76,6 @@
 		$(use_enable cramfs) \
 		$(use_enable old-linux elvtune) \
 		--with-ncurses=$(usex ncurses $(usex unicode auto yes) no) \
-		--disable-init \
 		--disable-kill \
 		--disable-last \
 		--disable-mesg \
@@ -87,6 +90,7 @@
 		--without-pam \
 		$(use_with selinux) \
 		$(use_with slang) \
+		$(use_enable static-libs static) \
 		$(tc-has-tls || echo --disable-tls)
 }
 
@@ -95,14 +99,14 @@
 	dodoc AUTHORS NEWS README* TODO docs/*
 
 	if ! use perl ; then #284093
-		rm "${D}"/usr/bin/chkdupexe || die
-		rm "${D}"/usr/share/man/man1/chkdupexe.1 || die
+		rm "${ED}"/usr/bin/chkdupexe || die
+		rm "${ED}"/usr/share/man/man1/chkdupexe.1 || die
 	fi
 
 	# need the libs in /
 	gen_usr_ldscript -a blkid uuid
 	# e2fsprogs-libs didnt install .la files, and .pc work fine
-	rm -f "${D}"/usr/$(get_libdir)/*.la
+	rm -f "${ED}"/usr/$(get_libdir)/*.la
 
 	if use crypt ; then
 		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die



1.1                  sys-apps/util-linux/util-linux-2.20.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/util-linux-2.20.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/util-linux/util-linux-2.20.ebuild?rev=1.1&content-type=text/plain

Index: util-linux-2.20.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.20.ebuild,v 1.1 2011/08/29 21:25:15 vapier Exp $

EAPI="3"

EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
inherit eutils toolchain-funcs libtool flag-o-matic
[[ ${PV} == "9999" ]] && inherit git autotools

MY_PV=${PV/_/-}
MY_P=${PN}-${MY_PV}
S=${WORKDIR}/${MY_P}

DESCRIPTION="Various useful Linux utilities"
HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux/"
if [[ ${PV} == "9999" ]] ; then
	SRC_URI=""
	#KEYWORDS=""
else
	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.bz2
		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-2.19.1-20110510.diff.bz2 )"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-linux"
fi

LICENSE="GPL-2"
SLOT="0"
IUSE="+cramfs crypt loop-aes ncurses nls old-linux perl selinux slang static-libs uclibc unicode"

RDEPEND="!sys-process/schedutils
	!sys-apps/setarch
	!<sys-apps/sysvinit-2.88-r3
	!<sys-libs/e2fsprogs-libs-1.41.8
	!<sys-fs/e2fsprogs-1.41.8
	cramfs? ( sys-libs/zlib )
	ncurses? ( >=sys-libs/ncurses-5.2-r2 )
	perl? ( dev-lang/perl )
	selinux? ( sys-libs/libselinux )
	slang? ( sys-libs/slang )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/os-headers"

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		po/update-potfiles
		autopoint --force
		eautoreconf
	else
		use loop-aes && epatch "${WORKDIR}"/util-linux-*.diff
	fi
	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
	elibtoolize
}

lfs_fallocate_test() {
	# Make sure we can use fallocate with LFS #300307
	cat <<-EOF > "${T}"/fallocate.c
	#define _GNU_SOURCE
	#include <fcntl.h>
	main() { return fallocate(0, 0, 0, 0); }
	EOF
	append-lfs-flags
	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} "${T}"/fallocate.c -o /dev/null >/dev/null 2>&1 \
		|| export ac_cv_func_fallocate=no
	rm -f "${T}"/fallocate.c
}

usex() { use $1 && echo ${2:-yes} || echo ${3:-no} ; }
src_configure() {
	lfs_fallocate_test
	econf \
		--enable-fs-paths-extra=/usr/sbin \
		$(use_enable nls) \
		--enable-agetty \
		$(use_enable cramfs) \
		$(use_enable old-linux elvtune) \
		--with-ncurses=$(usex ncurses $(usex unicode auto yes) no) \
		--disable-kill \
		--disable-last \
		--disable-mesg \
		--enable-partx \
		--enable-raw \
		--enable-rename \
		--disable-reset \
		--disable-login-utils \
		--enable-schedutils \
		--disable-wall \
		--enable-write \
		--without-pam \
		$(use_with selinux) \
		$(use_with slang) \
		$(use_enable static-libs static) \
		$(tc-has-tls || echo --disable-tls)
}

src_install() {
	emake install DESTDIR="${D}" || die "install failed"
	dodoc AUTHORS NEWS README* TODO docs/*

	if ! use perl ; then #284093
		rm "${ED}"/usr/bin/chkdupexe || die
		rm "${ED}"/usr/share/man/man1/chkdupexe.1 || die
	fi

	# need the libs in /
	gen_usr_ldscript -a blkid uuid
	# e2fsprogs-libs didnt install .la files, and .pc work fine
	rm -f "${ED}"/usr/$(get_libdir)/*.la

	if use crypt ; then
		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
	fi
}