[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: e2fsprogs-libs-1.41.12.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      10/07/03 02:12:07

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.41.12.ebuild
  Log:
  Version bump #326655 by Sebastian Koehler.
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.53                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	3 Jul 2010 02:10:57 -0000	1.52
+++ ChangeLog	3 Jul 2010 02:12:07 -0000	1.53
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.52 2010/07/03 02:10:57 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.53 2010/07/03 02:12:07 vapier Exp $
+
+*e2fsprogs-libs-1.41.12 (03 Jul 2010)
+
+  03 Jul 2010; Mike Frysinger <vapier@g.o>
+  +e2fsprogs-libs-1.41.12.ebuild:
+  Version bump #326655 by Sebastian Koehler.
 
   03 Jul 2010; Mike Frysinger <vapier@g.o>
   e2fsprogs-libs-1.41.11.ebuild:



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.12.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.12.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.12.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.41.12.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.12.ebuild,v 1.1 2010/07/03 02:12:07 vapier Exp $

EAPI="2"

inherit toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error and subsystem)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls elibc_glibc"

RDEPEND="elibc_glibc? ( >=sys-libs/glibc-2.6 )
	!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41.8"
DEPEND="nls? ( sys-devel/gettext )
	dev-util/pkgconfig
	sys-devel/bc"

src_prepare() {
	echo 'all %:' > doc/Makefile.in # don't bother with docs #305613
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	# we use blkid/uuid from util-linux now
	ac_cv_lib_uuid_uuid_generate=yes \
	ac_cv_lib_blkid_blkid_get_cache=yes \
	ac_cv_path_LDCONFIG=: \
	econf \
		--disable-libblkid \
		--disable-libuuid \
		--enable-${libtype}-shlibs \
		$(tc-has-tls || echo --disable-tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die
	gen_usr_ldscript -a com_err ss
}