[gentoo-commits] repo/gentoo:master commit in: x11-misc/redshift/

[Sebastian Pipping]

commit:     a8afc8263b9ee22ecf1fd1494cc7b7388a612739
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 24 23:22:19 2019 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Sun Nov 24 23:23:20 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8afc826

x11-misc/redshift: AppArmor + python_optimize

Closes: https://bugs.gentoo.org/698732
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-2.3.78, Repoman-2.3.16

 x11-misc/redshift/redshift-1.12-r3.ebuild | 88 +++++++++++++++++++++++++++++++
 1 file changed, 88 insertions(+)

diff --git a/x11-misc/redshift/redshift-1.12-r3.ebuild b/x11-misc/redshift/redshift-1.12-r3.ebuild
new file mode 100644
index 00000000000..a7399ed031e
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12-r3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit systemd autotools eutils gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ayatana geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	ayatana? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	econf \
+		--disable-silent-rules \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--enable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+	fi
+
+	python_foreach_impl python_optimize
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}